Arduino Mega и ошибочные значения гироскопа

Можно использовать свой эскиз и получить информацию об ракурсах. Он не очень точен и смещается.

Я начал с вашего эскиза и улучшал его, пока не получил нужный ракурс. Функции Serial.println требуют времени и печатаются слишком часто. Чтобы измерить интервал между выборками, я использовал миллис.

Этот тест выполняется с помощью:

• Плата Arduino M0 (с шиной i2c 3,3 В)
• Модуль gy-521 со встроенным регулятором напряжения, но без преобразователя уровня
• vcc модуля gy-521 подключен к 5 В (из-за регулятора напряжения)

Arduino M0 быстрее, чем Arduino Mega или Uno.

// тест с платой Arduino M0
#include <Wire.h>

#define SER SerialUSB    // «Serial» для Arduino Uno, «SerialUSB» для Leonardo и Arduino M0

const int MPU = 0x68;   // I2C-адрес MPU

int16_t x_offset = 0;
int16_t y_offset = 0;
int16_t z_offset = 0;

float pitch = 0.0;
float roll  = 0.0;
float yaw   = 0.0;

unsigned long previousMillisSample;
unsigned long previousMillisOutput;
const unsigned long intervalOutput = 500;  // обновление последовательного монитора за полсекунды

void setup() {
  SER.begin(9600);
  while(!SER);         // ждем, пока откроется последовательный монитор для Леонардо и M0
  SER.println("Angle from gyro");

  Wire.begin();

  Wire.beginTransmission(MPU);
  Wire.write(0x6B); //регистр управления питанием 1
  Wire.write(0);
  Wire.endTransmission();

  // получаем значения гироскопа и используем их как смещение
  GetXYZ(x_offset, y_offset, z_offset);
}

void loop() {

  int16_t GyX;
  int16_t GyY;
  int16_t GyZ;

  GetXYZ(GyX, GyY, GyZ);

  unsigned long currentMillisSample = millis();  // время в миллисах, когда была взята эта выборка

  // удаляем смещение
  GyX -= x_offset;
  GyY -= y_offset;
  GyZ -= z_offset;

  float v_pitch = float(GyX) / 131.0;    // конвертируем в число с плавающей запятой и вычисляем градусы
  float v_roll  = float(GyY) / 131.0;
  float v_yaw   = float(GyZ) / 131.0;

  // вычисляем время в миллисекундах между предыдущим и текущим образцом
  unsigned long t = currentMillisSample - previousMillisSample;

  // время в секундах в виде числа с плавающей запятой
  float float_t = float(t) / 1000.0;

  // корректируем количество градусов во времени
  float a_pitch = v_pitch * float_t;
  float a_roll  = v_roll  * float_t;
  float a_yaw   = v_yaw   * float_t;

  // запоминаем время в миллисах, когда была взята проба для следующего раза
  previousMillisSample = currentMillisSample;

  pitch += a_pitch; 
  roll  += a_roll;
  yaw   += a_yaw;

  // Время от времени печатаем вывод
  if(millis() - previousMillisOutput >= intervalOutput) {
    previousMillisOutput = millis();

    SER.print("pitch = ");
    SER.print(pitch);
    SER.print(" | roll = ");
    SER.print(roll);
    SER.print(" | yaw = ");
    SER.println(yaw);
  }
}

void GetXYZ( int16_t &x, int16_t &y, int16_t &z) {
  // Получаем значения гироскопа
  Wire.beginTransmission(MPU);
  Wire.write(0x43);     // первый регистр значений гироскопа
  Wire.endTransmission(false);

  Wire.requestFrom(MPU,6);
  x = Wire.read() << 8 | Wire.read();
  y = Wire.read() << 8 | Wire.read();
  z = Wire.read() << 8 | Wire.read();
}

Можете ли вы попробовать этот эскиз? Он смещается от 10 до 60 градусов за 5 минут. Это очень много. Я думаю, что сенсор лучше, а значит, эскиз далек от совершенства.