Управление шаговым двигателем с помощью PIR и датчика Холла

Примечание: этот ответ — это обновление с кодом, который я написал для получения нужного мне результата

Благодаря Ацуши Ёкояме мне пришлось переосмыслить всю логику скетча. Я переписал код, понимая, что мне не нужно проверять количество шагов, а значит, использование AccelStepper для решения этой задачи необязательно.

Следующий код делает именно то, что мне нужно, и я публикую его на случай, если он кому-то понадобится:

// Определения контактов
const int hallSensorPin = 2;    // Датчик Холла
const int pirSensorPin = 3;     // ПИР-датчик
const int dirPin = 4;           // Направляющий контакт для A4988
const int stepPin = 5;          // Шаговый вывод для A4988

// Переменные
bool motorRunning = false;      // Отслеживает, работает ли двигатель
bool coolDownActive = false;    // Отслеживает, активен ли период охлаждения
unsigned long coolDownStart = 0; // Отслеживает начало периода охлаждения
unsigned long motorStartTime = 0; // Отслеживает момент запуска двигателя
int movementCount = 0;          // Отслеживает количество перемещений
bool directionForward = true;   // Отслеживает направление двигателя
bool checkForHigh = true;       // Поочередно определяет HIGH и LOW

void setup() {
  // Режимы фиксации
  pinMode(hallSensorPin, INPUT);
  pinMode(pirSensorPin, INPUT);
  pinMode(dirPin, OUTPUT);
  pinMode(stepPin, OUTPUT);
  pinMode(enablePin, OUTPUT);

  // Включить драйвер двигателя
  digitalWrite(enablePin, LOW);

  // Инициализируем последовательный порт для отладки
  Serial.begin(9600);
  Serial.println("System Initialized. Waiting for PIR trigger...");
}

void loop() {
  // Проверяем, работает ли двигатель
  if (motorRunning) {
    // Перемещаем мотор: меняем задержку для управления скоростью
    digitalWrite(stepPin, HIGH);
    delayMicroseconds(2500);
    digitalWrite(stepPin, LOW);
    delayMicroseconds(2500);

    // Проверяем, сработал ли датчик Холла (конечный упор)
    // Проверяйте только через 1 секунду после начала движения двигателя
    if (millis() - motorStartTime >= 1000) {
      if ((checkForHigh && digitalRead(hallSensorPin) == HIGH) || 
          (!checkForHigh && digitalRead(hallSensorPin) == LOW)) {
        motorRunning = false; // Остановить двигатель
        movementCount++;     // Увеличить счетчик движений
        coolDownActive = true; // Начать период охлаждения
        coolDownStart = millis();

        Serial.println("Hall effect sensor triggered. Motor stopped.");
        Serial.print("Movement count: ");
        Serial.println(movementCount);

        // Менять направление каждые 4 движения
        if (movementCount % 4 == 0) {
          directionForward = !directionForward;
          digitalWrite(dirPin, directionForward ? HIGH : LOW);
          Serial.println("Direction reversed.");
        }

        // Поочередно между ВЫСОКИМ и НИЗКИМ обнаружением
        checkForHigh = !checkForHigh;
        Serial.print("Next Hall effect detection: ");
        Serial.println(checkForHigh ? "HIGH" : "LOW");

        Serial.println("Starting 10-second cool-down period...");
      }
    }
  } else {
    // Проверяем, активен ли период охлаждения
    if (coolDownActive) {
      if (millis() - coolDownStart >= 10000) { // 10-секундное охлаждение
        coolDownActive = false;
        Serial.println("Cool-down period ended. Ready for new PIR trigger.");
      }
    } else {
      // Проверяем, сработал ли ИК-датчик
      if (digitalRead(pirSensorPin) == HIGH) {
        motorRunning = true; // Запустить двигатель
        motorStartTime = millis(); // Записываем время запуска двигателя
        Serial.println("PIR sensor triggered. Motor started.");
      }
    }
  }
}

Спасибо!