Как независимо запускать позиционные и непрерывные сервоприводы с помощью millis()?

Это описано в учебнике по Arduino "Мигание без задержки". Позвольте мне перефразировать основную часть примера кода здесь:

uint8_t ledState = LOW;
uint32_t lastTimeLedChanged = 0;

void loop() {
    uint32_t now = millis();
    if (now - lastTimeLedChanged >= 1000) {

        // Сохраните последний раз, когда мы обновляли светодиод.
        lastTimeLedChanged = now;

        // Вычислите новое состояние светодиода.
        if (ledState == LOW) {
            ledState = HIGH;
        } else {  // ledState is HIGH
            ledState = LOW;
        }

        // Установите индикатор в вычисленное состояние.
        digitalWrite(LED_BUILTIN, ledState);
    }
}

Это позволит светодиоду переключаться между двумя возможными состояниями с требуемой скоростью. Вы можете применить этот принцип как есть к вашему сервоприводу непрерывного вращения.

Для позиционных сервоприводов все еще можно применить тот же принцип, но есть одна загвоздка. В то время как и светодиод, и сервопривод CR переключаются между двумя состояниями, пара позиционных сервоприводов проходит через множество состояний (92 240, если я правильно посчитал). Таким образом, Вам понадобится:

• дополнительные переменные для хранения текущего состояния сервопары
• больше кода для вычисления нового желаемого состояния
• больше кода для обновления состояния

Чтобы понять, как представить состояние, вам нужно посмотреть на ваш текущий код на основе функции delay (), посмотреть, сколько вызовов функции delay() выполняется в каждом полном цикле, и выяснить, как идентифицировать каждый из этих вызовов. Каждая из этих задержек соответствует одному состоянию вашей системы. Я бы сказал, что вам нужна одна переменная, чтобы знать, в каком из циклов for вы находитесь, и другая переменная, чтобы знать последнюю позицию, которую вы записали на сервопривод в этом цикле. Я буду называть каждый из оригиналов для зацикливает “фазу”. Существует два из шести таких этапов:

• фаза 0: наклон: 90° → 60°
• фаза 1: наклон: 60° → 120°
• фаза 2: наклон: 120° → 90°
• фаза 3: панорамирование: 90° → 60°
• фаза 4: панорамирование: 60° → 120°
• фаза 5: панорамирование: 120° → 90°

Обратите внимание, что в исходном вопросе было только два цикла for, но затем он был отредактирован, чтобы включить шесть циклов, поэтому я отредактировал свой ответ.

Затем вам нужно будет сохранить время последнего обновления, таким образом:

int phase = 0;  // в какой из шести фаз мы находимся
int pos = 90;   // последняя позиция, записанная на сервопривод
uint32_t lastTimeServoMoved = 0;

Как только у вас появятся правильные переменные для описания состояния, обновить его будет несложно. Если вы достигли конца фазы, переходите к следующей. Затем обновите позицию на один шаг. Таким образом:

void loop() {
    uint32_t now = millis();
    if (now - lastTimeServoMoved >= 30) {

        // Сохраните последний раз, когда мы обновляли позиционный сервопривод.
        lastTimeServoMoved = now;

        // Вычислите новое состояние.        
        if (phase == 0 && pos == 60)
            phase = 1;
        else if (phase == 1 && pos == 120)
            phase = 2;
        else if (phase == 2 && pos == 90)
            phase = 3;
        else if (phase == 3 && pos == 60)
            phase = 4;
        else if (phase == 4 && pos == 120)
            phase = 5;
        else if (phase == 5 && pos == 90)
            phase = 0;
        if (phase == 1 || phase == 4)
            pos += 1;
        else
            pos -= 1;

        // Установите сервопривод в вычисленное состояние.
        if (phase < 3)
            tiltservo.write(pos);
        else
            panservo.write(pos);
    }
}

Лично мне не нравится такой повторяющийся код. Если вас устраивают структуры данных, я бы рекомендовал использовать массив структур для хранения всей информации, описывающей действия, выполняемые на каждом этапе:

struct {
    Servo *servo;   // какой сервопривод перемещать
    int step;       // шаги, по которым он перемещается
    int final_pos;  // конечное угловое положение
} moves[] = {
    { &tiltservo, -1, 60 },   // tilt:  90 ->  60
    { &tiltservo, +1, 120 },  // tilt:  60 -> 120
    { &tiltservo, -1, 90 },   // tilt: 120 ->  90
    { &panservo,  -1, 60 },   // pan:   90 ->  60
    { &panservo,  +1, 120 },  // pan:   60 -> 120
    { &panservo,  -1, 90 }    // pan:  120 ->  90
};

Тогда фактический код становится проще:

void loop() {
    uint32_t now = millis();
    if (now - lastTimeServoMoved >= 30) {

        // Сохраните последний раз, когда мы обновляли позиционный сервопривод.
        lastTimeServoMoved = now;

        // Compute the new state.
        if (pos == moves[phase].final_pos) {
            phase +=1;
            if (phase == 6)
                phase = 0;
        }
        pos += moves[phase].step;

        // Установите сервопривод в вычисленное состояние.
        moves[phase].servo->write(pos);
    }
}