код для автоматической двери

KennetRunner уже объяснил, что не так с вашим кодом. Здесь я буду попробуйте дать совет, как правильно реализовать автоматическую дверь.

Первое, что нужно сделать, это избавиться от delay(). Пока ваша программа находится внутри вызов delay(), он не может ничего сделать, кроме как ждать, пока задержка не закончится. Это допустимо, если программа должна выполнить только одну единственную задачу, как мигание светодиода. Как только у вас есть две задачи, delay() становится неприятно, потому что он блокирует все задачи.

Пример: после открытия дверцы в течение одной минуты ваша программа закрыл бы его, независимо от того, есть ли кто-то на пути. Это не мог видеть, как человек пришел, потому что он был занят задержкой закрытия двери.

Стандартный способ избавиться от delay() — никогда не ждать внутри цикл(). Вместо этого, если есть что сделать прямо сейчас, сделайте это; если не, только не делай, но и не жди. Псевдокод:

void loop()
{
    if (it_is_time_to_do_foo()) {
        do_foo();
    }
    if (it_is_time_to_do_bar()) {
        do_bar();
    }
    /// и т. д...
}

Вы можете использовать функцию millis(), чтобы узнать, когда время истекло. прийти, чтобы выполнить какое-то задание, как описано в разделе Мигание без задержки Учебник по ардуино. Это действительно второй учебник для каждого пользователя Arduino. следует читать сразу после того, как вы научитесь мигать светодиодом.

Затем вам нужно научиться реализовывать конечный автомат. я порекомендуйте руководство по конечному автомату Маженко, постоянный участник этого сайта.

Ваша проблема может быть естественным образом отображена на машине с четырьмя состояния: ЗАКРЫТО, ОТКРЫТИЕ, ОТКРЫТО и ЗАКРЫТИЕ. потом пишешь правила о том, что делать в каждом состоянии и когда переходить в другое состояние. Например:

• когда дверь ЗАКРЫТА
  • если датчики обнаруживают кого-то, переход в состояние ОТКРЫТИЯ
• когда дверь ОТКРЫВАЕТСЯ
  • если пришло время переместить сервопривод на один шаг, сделайте это
  • если мы уже прошли весь путь до открытой позиции, мы можем сказать, что дверь ОТКРЫТА сейчас
• когда дверь ОТКРЫТА
  • если пора закрыть, перейти в состояние ЗАКРЫТИЕ
  • если датчики обнаруживают кого-то, сбросить таймер <<<< обратите внимание!
• когда дверь ЗАКРЫВАЕТСЯ
  • если датчики обнаруживают кого-то, переход в состояние ОТКРЫТИЯ
  • если пришло время переместить сервопривод на один шаг, сделайте это
  • если мы уже прошли весь путь до закрытой позиции, мы говорим теперь дверь ЗАКРЫТА

Несколько вещей, на которые следует обратить внимание:

• Обратите внимание на строку, отмеченную символом <<<<: это предотвратит вышеупомянутое проблема закрытия двери в кого-то.
• Первое правило для состояния ЗАКРЫТИЕ следует из аналогичного обоснования.
• Я придумал некоторые из этих правил, так как задача вашей программы не полностью указано в вашем вопросе. Не стесняйтесь изменять эти правила на ваш вкус.

А вот и предлагаемая мной реализация. Внимание: не проверено. Как обычный для FSM, он основан на большой инструкции switch/case, идущей через все возможные состояния. Однако, чтобы не повторять правила, я правило «если кто-то есть, начните открывать» из переключатель. Еще я закинул «если есть кто, сбросьте таймер» в то же правило.

const int position_closed = 0;      // положение двери закрыто [град]
const int position_open = 180;      // положение двери открыто [град]
const uint32_t delay_step = 15;     // задержка между шагами сервопривода [мс]
const uint32_t delay_open = 60000;  // как долго дверь остается открытой [мс]

void loop()
{
    static enum { CLOSED, OPENING, OPEN, CLOSING } state;
    static int position;          // положение двери
    static uint32_t last_change;  // последнее время изменения состояния или позиции
    uint32_t now = millis();

    // При обнаружении присутствия переключиться в состояние ОТКРЫТИЯ.
    if ((digitalRead(pirPin) == HIGH || digitalRead(pirPin2) == HIGH)
            && state != OPENING) {
        state = OPENING;
        last_change = now;
    }
    else switch (state) {
        case CLOSED:
            break;
        case OPENING:
            if (position == position_open) {
                state = OPEN;
                last_change = now;
            } else if (now - last_change >= delay_step) {
                myservo.write(++position);
                last_change = now;
            }
            break;
        case OPEN:
            if (now - last_change >= delay_open) {
                state = CLOSING;
                last_change = now;
            }
            break;
        case CLOSING:
            if (position == position_closed) {
                state = CLOSED;
                last_change = now;
            } else if (now - last_change >= delay_step) {
                myservo.write(--position);
                last_change = now;
            }
            break;
    }
}