Результаты Arduino FFT "красивого" сигнала кажутся противоречивыми

signal-processing analog-sampling mathematics

У меня есть ПРЕКРАСНЫЙ доплеровский радиолокационный сигнал от датчика 24.050-24.250 ГГц, измеряющего очень маленький объект со скоростью 143 кадра в секунду (скорость от другого радара 10 ГГц) в области измерения около 300 мм-500 мм перед датчиком(датчиками). Сигнал был ограничен примерно 3 В с помощью стабилитрона.

Я сделал несколько измерений (при такой скорости, размере объекта и расстоянии от датчиков), и в среднем было около 8-20 волновых пиков выше порогового уровня триггера (2,58 В) до конца коробки порогового уровня триггера, где пики начинают падать.

Глядя на график, можно отбросить первые 3 пика и последние 2-3 пика выше порога триггера, что оставляет приличную область (оранжевый прямоугольник) для выборки пиков по частоте/периоду. Таким образом, в этом случае у нас есть около 17 "хороших" пиков внутри оранжевого ящика, которые нужно измерить. В этом случае оранжевая коробка (измерительная площадь образца) имеет длину 5 х 500 us = 2500 us.

Я знаю, что БПФ был бы лучшим способом измерения, но одна программа БПФ, которую я использовал с Arduino, дала мне противоречивые результаты. Не уверен, как установить размер выборки (должен быть в силе 2 приращения от 2 до 256). А максимальная частота дискретизации составляет 10 кГц (аппаратные ограничения).

Я установил размеры выборки на 4, 16 и 128 на частоте 10 кГц, но получил противоречивые результаты. Я подозреваю логарифмические результаты, но даже они не складываются. Иногда я получаю в пределах 2-3%, но иногда это отклоняется на 30% без видимой корреляции.

Что я знаю:

• с помощью этого радара с частотой 24 ГГц (без углов) скорость = частота / 44 достигает км/ч (км/ч х 1,097 = кадров в секунду).
• в этом случае o-scope измерял 6613 Гц с периодом 151,2 us, но это было для всей области выше порога срабатывания 2,58 В. Но у него также были некоторые гораздо более изменчивые показания, такие как заметные в первые 2-3 пика после триггера и последние 2-3 пика, которые падают ниже порога триггера. Я исключил их из оранжевой коробки.

Как мне настроить этот БПФ, или другой БПФ, или аналогичный метод, который определял бы доминирующую частоту по данным внутри оранжевого прямоугольника? Размер выборки оранжевого прямоугольника всегда будет находиться в диапазоне от 8 до 20 пиков числа пиков. Я измерил частоту и периоды от "положительного восходящего фронта до положительного восходящего фронта".

Я попробовал использовать Adafruit nRF52840 Express (часы 16 Мгц) и Adafruit 32u4 Bluefruit (часы 8 Мгц).

Я использую эту библиотеку Arduino FFT: https://github.com/kosme/arduinoFFT

Некоторая широкая информация о самом этом БПФ: https://www.norwegiancreations.com/2017/08/what-is-fft-and-how-can-you-implement-it-on-an-arduino/

- Спасибо.

    #include "arduinoFFT.h"
 
#define SAMPLES 4         //Must be a power of 2     128, 256?
#define SAMPLING_FREQUENCY 10000 //Hz, must be less than 10000 due to ADC
 
arduinoFFT FFT = arduinoFFT();

 
unsigned int sampling_period_us;
unsigned long microseconds;
 
double vReal[SAMPLES];
double vImag[SAMPLES];
 
void setup() {
    Serial.begin(115200);

    sampling_period_us = round(1000000*(1.0/SAMPLING_FREQUENCY));
}
 
void loop() {

 
  if (analogRead(A0) >600) {
   
    /*SAMPLING*/
    for(int i=0; i<SAMPLES; i++)
    {
        microseconds = micros();    //Overflows after around 70 minutes!
     
        vReal[i] = analogRead(A0);
        vImag[i] = 0;
     
        while(micros() < (microseconds + sampling_period_us)){
        }
    }
 
    /*FFT*/
    FFT.Windowing(vReal, SAMPLES, FFT_WIN_TYP_HAMMING, FFT_FORWARD);
    FFT.Compute(vReal, vImag, SAMPLES, FFT_FORWARD);
    FFT.ComplexToMagnitude(vReal, vImag, SAMPLES);
    double peak = FFT.MajorPeak(vReal, SAMPLES, SAMPLING_FREQUENCY);


    /*PRINT RESULTS*/
    Serial.println(peak);     //Print out what frequency is the most dominant.
 
  //  for(int i=0; i<(SAMPLES/2); i++)
   // {
        /*View all these three lines in serial terminal to see which frequencies has which amplitudes*/
         
        //Serial.print((i * 1.0 * SAMPLING_FREQUENCY) / SAMPLES, 1);
        //Serial.print(" ");
      // Serial.println(vReal[i], 1);    //View only this line in serial plotter to visualize the bins
  //  }


 }
 
    //delay(1000);  //Repeat the process every second OR:
   // while(1);       //Run code once
}

ПРАВКА: @Dorian После нескольких дней невзгод и разочарований, я читал и перечитывал вашу дополнительную информацию и помог мне лучше прояснить ситуацию. Я думаю, что у меня есть некоторые аппаратные ограничения. Кстати...да, у меня есть конденсатор 27pf на GND с резистором 3,3 K и 3V zener параллельно на выходе OP AMP.

Но сначала поясню: я решил добавить компаратор после датчика и операционного усилителя. Теперь у меня есть базовое напряжение на ВЫСОКОМ уровне (3,1 В). Ранее, как я уже писал, OP AMP имел базовый уровень 1,65 В, и при обнаружении движения напряжение отскакивает между максимумами (2,5 В-3,1 В) и минимумами (1 В-0 В) примерно в 10-20 раз, пока оно снова не установится на базовом уровне 1,65 В. Я подозревал, что ВЫСОКИЙ и НИЗКИЙ пороги были не так уж ясны. Чтобы получить четкий МАКСИМУМ или МИНИМУМ, я добавил компаратор. Эти показания идут на цифровой вывод захвата MCU, способный к тикам 62,5 нс (16 МГц). Программа Arduino, которая подсчитывает импульсы, проверяется на работу. В спецификациях MCU при 3,3 В имеет 1 В и ниже как НИЗКИЙ, так и 2,5 В и выше как ВЫСОКИЙ.

См. Новое чтение oscope (прилагается). Я получаю точные импульсные захваты (соответствующие oscope), но я получаю только около 3 или 4 импульсных показаний вместо 10-20, показанных на прицеле. Я использовал НИЗКИЙ захват (ниже 1В). Но даже если я переключусь на TOGGLE capture (double) Кажется, я получаю только последние 3-4 полных волны (1/3) и, похоже, пропускаю первые 2/3. Или может получаться каждый 2-й или 3-й?

Мой операционный усилитель работает быстро на частоте 50 МГц, и раньше я точно измерял с его помощью импульсы 100ус-800ус. А мой компаратор (после операционного усилителя) - это MAX 9052 с задержкой распространения 400 нс. время подъема/падения 40-80 нс. Так что я не должен пропустить ни одного импульса. Программа Arduino тоже не может быть такой медленной.

ПРАВКА №2:

//the best resolution you can achieve is 1/16us.

#include <Arduino.h>

#define FREQ_MEASURE_PIN 8  // actual 6 is PIN D11 and 8 is PIN D12 on Adafruit Feather Express nRF52840 LE, pin 11 is D12 itsybitsy 52840
#define PPI_CHANNEL 1u
#define GPIOTE_CHANNEL 1   //just picked channel #1


volatile int pulseCount = 0;
volatile unsigned long duration; //Pulse2 - Pulse1 = count of time ticks at 62.5 ns each tick (16 Mhz clock scaled at 0)     (expected value example: 792.5620  => 7925620)
volatile unsigned long pulseTime;   // first signal reading
volatile unsigned long lastTime;   //  most current signal reading


void setup() {

    Serial.begin(115200);
   
  initCounter();
}

void loop() 
{  

  
  if  ((pulseCount == 2) && (duration>0))  {

    Serial.println(duration);   //

   }

}



//must use extern "C" because IRQ will not compile since it's "C" coded
extern "C"  
{
void GPIOTE_IRQHandler(void)
{
                                   
  lastTime = pulseTime;
  
  if (NRF_GPIOTE->EVENTS_IN[GPIOTE_CHANNEL] == 1)    //if an input pulse is detected on pin 6 then...
  {
    NRF_GPIOTE->EVENTS_IN[GPIOTE_CHANNEL] = 0;     //  reset event detection to zero to ready for next event detection? 
    pulseTime = NRF_TIMER2->CC[0];                     // save Timer value at same time when signal was read on pin 6

    //pulseCounter
    pulseCount++;
    duration =(((pulseTime*10000) - (lastTime*10000))/16); //multiply by 10000 to avoid float, and divide by 16 for 16 Mhz clock tick = 62.5 ns per tick

   // goes from here to Loop if pulse = 2 (complete PULSE) so a reading can be sent 
    }
  }
}



void initCounter()
{    
  NRF_P0->PIN_CNF[FREQ_MEASURE_PIN] = GPIO_PIN_CNF_DIR_Input << GPIO_PIN_CNF_DIR_Pos |        //sets up PIN 6 for event read
                                      GPIO_PIN_CNF_INPUT_Connect << GPIO_PIN_CNF_INPUT_Pos |  //pos going signal
                                    //  GPIO_PIN_CNF_PULL_Pulldown << GPIO_PIN_CNF_PULL_Pos |   //pulldown LOW so no floating of pin voltage 
                                   //   GPIO_PIN_CNF_SENSE_High << GPIO_PIN_CNF_SENSE_Pos;      //a HIGH POS signal is the trigger
  
                                      GPIO_PIN_CNF_PULL_Pullup << GPIO_PIN_CNF_PULL_Pos |   //Pullup or Pulldown LOW so no floating of pin voltage 
                                      GPIO_PIN_CNF_SENSE_Low << GPIO_PIN_CNF_SENSE_Pos;      //a HIGH POS signal is the trigger .... or a LOW POS
                                      
                                      
  NRF_PPI->CHEN |= 1 << PPI_CHANNEL;
  NRF_PPI->CH[PPI_CHANNEL].EEP = (uint32_t)&NRF_GPIOTE->EVENTS_IN[GPIOTE_CHANNEL];
  NRF_PPI->CH[PPI_CHANNEL].TEP = (uint32_t)&NRF_TIMER2->TASKS_CAPTURE[0];   //sets up Timer channel

  NRF_GPIOTE->CONFIG[GPIOTE_CHANNEL] = GPIOTE_CONFIG_MODE_Event << GPIOTE_CONFIG_MODE_Pos |         //sets up pin for event capture 
                                    FREQ_MEASURE_PIN << GPIOTE_CONFIG_PSEL_Pos |                   //sets up event capture on pin 6
                                    GPIOTE_CONFIG_POLARITY_HiToLo << GPIOTE_CONFIG_POLARITY_Pos;   //sets event capture signal trigger type:  LoToHi   or HiToLo or  Toggle                                    
  NRF_GPIOTE->INTENSET = (1 << GPIOTE_CHANNEL);    //  Interrupt routine setup on a pin
  NVIC_EnableIRQ(GPIOTE_IRQn);                     //  Interrupt routine setup if signal detected on pin 6

  NRF_TIMER2->TASKS_STOP = 1;    //stops timer
  NRF_TIMER2->TASKS_CLEAR = 1;    //clear timer to zero
  NRF_TIMER2->MODE = TIMER_MODE_MODE_Timer << TIMER_MODE_MODE_Pos;   //sets up TIMEr mode as "Timer"
  NRF_TIMER2->BITMODE = TIMER_BITMODE_BITMODE_32Bit << TIMER_BITMODE_BITMODE_Pos;    // sets values for Timer input
  NRF_TIMER2->PRESCALER = 0;       //read at max resolution (at MCU speed)
  NRF_TIMER2->TASKS_START = 1;      // starts the Timer
}

ПРАВКА #3: ================================================

Я добавил схему операционного усилителя ниже. Эта схема прекрасно работала с индуктивным датчиком, использующим вихревые токи. Я очень точно измерил одиночные импульсы @ 700-800us, но у меня не было резистора R1 (22k). Добавил резистор R1 и GND сразу после него, когда заменил индуктивный датчик на радарный датчик 24 ГГц, потому что я не получал показаний. Эта схема обеспечивает первый график, который я опубликовал, с центром около 1,6 В. Я снял компаратор после выключения операционного усилителя, чтобы не усложнять схему, а также у него были некоторые артефакты.

Подводя итог: есть подозрение, что программа Arduino, которую я разместил для nRF52, недостаточно быстра, чтобы захватить 100us импульсов в быстрой последовательности. Я пытался использовать только BLE и раскомментировал SerialPrint и SerialBegin и т. Д., но даже с BLE я получил те же ограниченные показания импульса. Например: было 10-20 импульсов, я смог захватить только последнюю 1/3 импульсов (3-4). Я также попробовал HIGH и LOW (HiToLo/LoToHi/Toggle).

Радарный датчик-это: источник питания 3,3 В. ЕСЛИ выход (считывание сигнала) находится в диапазоне 60мВ-250мВ. 60 мв - это состояние нулевого сигнала.

Here are some sample period (wave pulse) readings in micro seconds:

97.0000
53.2500
45.2500
42.0625
40.8125
**40.9375**

And the actual period that it should read based on reference measurement:  **38.4435**us

==========================
Another set of period (wave pulse) readings in micro seconds:

95.6875
55.0000
46.7500
41.7500
**40.2500**

And the actual period that it should read based on reference measurement: **39.1703**us

Таким образом, последнее значение довольно близко, но не пропорционально близко, где я могу надежно "оценить" фактическое значение. Так что, например, каждый раз он снижается не на 5,13%, а на 3-6%.

График примера волновых импульсов (меньший означает более короткий импульс):

Стабилитрон на выходе предназначен для того, чтобы удерживать волны от превышения 3,3 В, что может повредить входной захватный штифт микроконтроллера.

Спасибо вам за вашу помощь!

Только для информации: ЭТО БЫЛИ ПОКАЗАНИЯ ОСЦИЛЛОГРАФА СО СХЕМОЙ КОМПАРАТОРА, ДОБАВЛЕННОЙ К ВЫХОДУ ОПЕРАЦИОННОГО УСИЛИТЕЛЯ, НО С ТЕХ ПОР Я УДАЛИЛ СХЕМУ КОМПАРАТОРА:

EDIT: Это была довольно большая задержка, так как мне нужно было сделать что-то еще после того, как я ничего не добился с этим проектом. Затем сегодня, когда я снова боролся, я думаю, что пришел к решению. Это требует больше работы, но, по крайней мере, у меня есть собранная версия, которая, кажется, хорошо работает.

Проблема, по-видимому, заключалась в том, что сам сигнал был синусоидальной или квазиквадратичной волной. Используя скетч Arduino AVR для внутреннего компаратора, которому ISR компаратора помогает "квадратировать" входящий сигнал с помощью таймеров и прерываний, переключая другой вывод на вывод Ref компаратора, я смог получить надежные показания. Я фактически использовал внешний компаратор с AVR и nRF52 для подсчета периодов. Это программа и смотрит другой человек тоже прошел через ад: https://electronics.stackexchange.com/questions/357131/random-and-unpredictable-analog-comparator-behaviour/566974#566974

Я предпочитаю использовать nRF52 из-за интеграции BLE, но я думаю, что смогу заставить AVR работать сначала автономно, выяснив, как отредактировать библиотеку, чтобы обратить прерывание с низкого уровня на Высокий, с высокого на низкий...так как выход компаратора противоположен моему сигнальному входу.

Конечно, мне все еще нужно обработать показания, чтобы отсортировать доминирующую частоту, но вручную я смог вычислить 5 из 5 событий в пределах 2-5% от действительного значения.

Однако, по-видимому, ключом к надежному считыванию входного сигнала является дополнительный вывод, который используется для "преобразования" синусоидальной волны в квадрат в рамках процедуры прерывания компаратора.

Мне все еще нужно обернуть голову вокруг того, как дополнительный вывод программы AVR, переключенный LOW/HIGH, подключенный к VREF компаратора, "формирует" синусоидальную волну и действует как обратная связь для гистерезиса. Я верю, что какой бы способ я ни пришел к "хорошей" прямоугольной волне для считывания входного счетчика AVR или nRF52, он будет победителем. Но я открою новую тему, если застряну. Спасибо вам за вашу помощь, и любые ваши предложения приветствуются.

// Циклы процессора на полупериод импульсного пакета.
const uint16_t half_period = 64;

// Статистика, записанная с помощью входного захвата ISR.
volatile uint16_t capture_count;
volatile uint16_t timer_start;
volatile uint16_t timer_end;

// Input capture ISR.
ISR(TIMER1_CAPT_vect) {
    uint16_t now = ICR1;
    uint16_t count = capture_count;
    if (count == 0)
        timer_start = now;
    else
        timer_end = now;
    capture_count = count+1;
}

void setup() {
    Serial.begin(9600);
    Serial.print("Expected frequency: ");
    Serial.print((float) F_CPU / (2*half_period));
    Serial.println(" Hz");
    Serial.println("Measured frequency:");
    Serial.flush();

    // Настройте таймер 2 для быстрого ШИМ-сигнала.
    DDRB  |= _BV(PB3);    // цифровой 11 = PB3 = OC2A в качестве выхода
    TCCR2A = _BV(COM2A0)  // переключить OC2A на сравнение совпадений
          | _BV(WGM21); // mode 2 = CTC, TOP = OCR2A
    TCCR2B = 0;           // держать таймер остановленным
    OCR2A  = half_period - 1;

    // Настройте таймер 1 для захвата входных данных.
    TCCR1A = 0; // нормальный режим
    TCCR1B = _BV(CS10); // часы @ F_CPU
    TIFR1 = _BV(ICF1); // очистить флаг захвата входного сигнала
    TIMSK1 = _BV(ICIE1); // включить прерывание захвата входного сигнала
}

void loop() {
    // Сбросить счетчик.
    capture_count = 0;

    // Послать серию импульсов.
    TCCR2B = _BV(CS20);   // таймер часов 2 @ F_CPU
    delayMicroseconds(1000);
    TCCR2B = 0;           // таймер остановки 2

    // Отчет о результатах.
    uint16_t timer_cycles = timer_end - timer_start;
    uint16_t pulse_count = capture_count - 1;
    Serial.print(pulse_count);
    Serial.print(" pulses in ");
    Serial.print(timer_cycles);
    Serial.print(" timer cycles -> ");
    Serial.print((float) pulse_count / timer_cycles * F_CPU);
    Serial.println(" Hz");
    delay(500);
}

Expected frequency: 125000.00 Hz
Measured frequency:
255 pulses in 32640 timer cycles -> 125000.00 Hz
255 pulses in 32640 timer cycles -> 125000.00 Hz
256 pulses in 32768 timer cycles -> 125000.00 Hz
256 pulses in 32768 timer cycles -> 125000.00 Hz
255 pulses in 32640 timer cycles -> 125000.00 Hz
256 pulses in 32768 timer cycles -> 125000.00 Hz
256 pulses in 32768 timer cycles -> 125000.00 Hz
256 pulses in 32768 timer cycles -> 125000.00 Hz
255 pulses in 32640 timer cycles -> 125000.00 Hz
256 pulses in 32768 timer cycles -> 125000.00 Hz
256 pulses in 32768 timer cycles -> 125000.00 Hz