Существуют ли библиотеки сглаживания сигналов для Arduino?

Вы пробовали фильтр нижних частот? Я нашел пример здесь и еще один здесь.

Обе эти библиотеки имеют список данных, считываемых с выбранного вами аналогового датчика, которые усредняются. Каждое новое значение датчика добавляется в список, а последнее выбрасывается, вот так:

List: 3 4 3 3 4 3 5 3 2 3 4 3 
new reading added. old one thrown out
      /--                     /--
List: 5 3 4 3 3 4 3 5 3 2 3 4
list averaged

Вы можете отфильтровать это в цифровом виде, используя фильтр нижних частот:

int valueFilt = (1-0.99)*value + 0.99*valueFilt;

Измените значение 0,99, чтобы изменить частоту среза (ближе к 1,0 — более низкая частота). Фактическое выражение для этого значения — exp(-2*pi*f/fs), где f — желаемая частота среза, а fs — частота выборки данных.

Другой тип «цифрового фильтра» — фильтр событий. Он хорошо работает с данными, имеющими выбросы; например 9,9,8,10,9,25,9 . Фильтр событий возвращает наиболее частое значение. По статистике это именно такой режим.

Статистические средние значения, такие как среднее значение, режим и т. д., можно рассчитать с помощью Библиотеки средних значений Arduino.

Пример взят со страницы библиотеки Arduino:

#include <Average.h>
#define CNT 600
int d[CNT];

void setup()
{
  Serial.begin(9600);
}

void loop()
{
  int i;

  for(i=0; i<CNT; i++)
  {
    d[i] = random(500);
  }  

  Serial.print("Mean: ");
  Serial.print(mean(d,CNT),DEC);
  Serial.print(" Mode: ");
  Serial.print(mode(d,CNT),DEC);
  Serial.print(" Max: ");
  Serial.print(maximum(d,CNT),DEC);
  Serial.print(" Min: ");
  Serial.print(minimum(d,CNT),DEC);
  Serial.print(" Standard deviation: ");
  Serial.print(stddev(d,CNT),4);
  Serial.println("");
  Serial.println("");

  delay(5000);
}

Мне кажется, я вижу в вашем зашумленном сигнале множество одновыборочных всплесков шума.

Медианный фильтр лучше устраняет всплески шума одной выборки, чем любой линейный фильтр. (Он лучше, чем любой фильтр нижних частот, скользящее среднее, взвешенное скользящее среднее и т. д. с точки зрения времени отклика и способности игнорировать такие выбросы шума в одной выборке).

На самом деле для Arduino существует множество библиотек сглаживания сигналов, многие из которых включают медианный фильтр.

Библиотеки сглаживания сигналов на arduino.cc:

• Пол Бэджер: плавный цифровой фильтр нижних частот
• Пол Бэджер: цифровой фильтр нижних частот digitalSmooth с подавлением выбросов
• Дэвид А. Меллис и Том Айго: руководство по сглаживанию
• Маженки: Средняя библиотека

Библиотеки сглаживания сигналов на github:

• AsheeshR/Microsmooth
• jeroendoggen: Arduino-signal-filtering-library
• karlward: библиотека фильтрации данных Arduino
• sebnil: FIR-filter-Arduino-Library
• daPhoosa: MedianFilter
• arc12: Коллекция фильтров цифровых сигналов (предназначена для использования с Arduino)
• sebnil: Самобалансирующийся робот в Arduino. Реализовано с ПИД-регуляторами, КИХ-фильтрами, дополнительным фильтром.

Подойдет ли что-то подобное для вашего робота? (Медиана-3 требует очень мало мощности процессора и, следовательно, быстро):

/*
median_filter.ino
2014-03-25: started by David Cary
*/

int median_of_3( int a, int b, int c ){
    int the_max = max( max( a, b ), c );
    int the_min = min( min( a, b ), c );
    // излишне умный код
    int the_median = the_max ^ the_min ^ a ^ b ^ c;
    return( the_median );
}

int newest = 0;
int recent = 0;
int oldest = 0;

void setup()
{
    Serial.begin(9600);
    // читаем первое значение, инициализируем его.
    oldest = random(200);
    recent = oldest;
    newest = recent;
    Serial.println("median filter example: ");
}

void loop()
{
    // удаляем самое старое значение и сдвигаем последнее значение
    oldest = recent;
    recent = newest;
    newest = random(200);

    Serial.print("new value: ");
    Serial.print(newest, DEC);

    int median = median_of_3( oldest, recent, newest );

    Serial.print("smoothed value: ");
    Serial.print(median, DEC);
    Serial.println("");

    delay(5000);
}

Ознакомьтесь с библиотекой Arduino Smooth. Он не использует абсолютно никаких массивов, не имеет циклов по прошлым значениям, работает быстро, имеет постоянное время вычислений, а объекты занимают 8 байт независимо от размера окна выборки.