Как определить, когда выходной сигнал датчика значительно меняется?

Не существует простого и универсального способа решить, что считать “значительным” изменением. Моя рекомендация состояла бы в том, чтобы создать алгоритм, играя с данными на вашем компьютере:

• Загрузите скетч на ардуино, который просто считывает датчик и передает показания на ваш компьютер по последовательномуканалу.

• Запишите длинный цикл таких показаний в файл.

• Составьте график показаний и внимательно посмотрите на графики: что бы вы сочли существенным изменением? Какие критерии вы могли бы использовать, чтобы решить , что изменение является значительным? Разработайте алгоритм принятия этого решения.

• Реализуйте и протестируйте алгоритм на своем компьютере, используя записанные данные.

• Перенесите код на Arduino.

Ниже приведены два примера, которые, возможно, могли бы дать вам некоторые идеи. Сначала приходит самое простое, что я могу придумать: он говорит, что изменение является значительным, если текущее значение достаточно далеко от ранее записанного значения. Это записанное значение обновляется только после обнаружения значительных изменений.

bool changed_significantly(int value) {
    const int change_threshold = 4;  // настройте по вкусу
    static int old_value;
    bool changed = abs(value - old_value) >= change_threshold;
    if (changed)
        old_value = value;
    return changed;
}

Он будет использоваться следующим образом:

void loop() {
    int value = sensorRead();
    if (changed_significantly(value))
        Serial.println("Signal changed.");
}

Обратите внимание, что с помощью этого алгоритма очень медленный дрейф будет периодически вызывать обнаружение значительных изменений. Если это не то, что вы хотите, вы можете предпочесть обнаруживать только те изменения, которые происходят достаточно быстро. Это может быть обнаружено с помощью фильтра высоких частот. Приведенная ниже функция реализует простой фильтр нижних частот (экспоненциально взвешенное скользящее среднее) и сравнивает текущий вход с предыдущим выходом. Разница эквивалентна фильтру высоких частот. Если эта разница достаточно велика, обнаруживается значительное изменение, затем фильтр сбрасывается , чтобы предотвратить его повторное срабатывание из - за дрейфа:

bool changed_significantly(int value) {
    const float change_threshold = 4;   // tune to taste
    const float filter_constant = 0.1;  // this one also
    static float filtered_value;
    float delta = value - filtered_value;
    bool changed = abs(delta) >= change_threshold;
    if (changed)
        filtered_value = value;
    else
        filtered_value += filter_constant * delta;  // low-pass filter
    return changed;
}

---

Edit: некоторые подробности о фильтре.

Один только этот фильтр высоких частот можно упростить следующим образом:

float filter(float x)
{
    static float y;
    float delta = x - y;
    y += filter_constant * delta;
    return delta;
}

Заметим, что если бы эта функция возвращала y, то у нас был бы обычный фильтр нижних частот первого порядка (экспоненциально взвешенная скользящая средняя). Поскольку вместо этого он возвращает разницу между входным и предыдущим значением с фильтрацией нижних частот, он ведет себя как фильтр верхних частот. Его передаточная функция такова:

H = (z − 1) / (z + k − 1)

где k - постоянная фильтра. Эта константа связана с частотой среза следующим образом:

f_c ≈ k f_s / (2π)

где f_s-частота дискретизации. Обратите внимание, что для частот, значительно меньших среза, фильтр ведет себя как масштабированная производная:

H x ≈ 1/(k f_s) dx/dt