ADXL345 выдает ошибку проводки в режиме SPI

Я заставил его работать, используя библиотеку Sparkfun вместо библиотеки Adafruit, и вставив пару операторов delay(100) в настройку (без них вывод постоянно был -13365, -13365, -13365). Я до сих пор не совсем понимаю, зачем вообще нужны операторы задержки.

/* ************************************************* ***
* SparkFun_ADXL345_Пример
* Трехосевой акселерометр Breakout - ADXL345
* Пример руководства по подключению
*
* Использование библиотеки Sparkfun ADXL345.
* Исходный файл Bildr ADXL345 изменен для поддержки
* связь I2C и SPI
*
* Э. Роберт @ SparkFun Electronics
* Создано: 13 июля 2016 г.
* Обновлено: 6 сентября 2016 г.
*
* Особенности среды разработки:
* Ардуино 1.6.11
*
* Технические характеристики оборудования:
* СпаркФун ADXL345
* Ардуино Уно
* *************************************************/

#include <SparkFun_ADXL345.h>         // Библиотека SparkFun ADXL345

/*********** COMMUNICATION SELECTION ***********/
/*    Comment Out The One You Are Not Using    */
ADXL345 adxl = ADXL345(9);           // ИСПОЛЬЗОВАТЬ ДЛЯ СВЯЗИ SPI, ADXL345(CS_PIN);
//ADXL345 adxl = ADXL345(); // ИСПОЛЬЗОВАТЬ ДЛЯ СВЯЗИ I2C

/****************** INTERRUPT ******************/
/*      Uncomment If Attaching Interrupt       */
//целое прерываниеPin = 2; // Настройте контакт 2 как контакт прерывания (для большинства плат Arduino)


/******************** SETUP ********************/
/*          Configure ADXL345 Settings         */
void setup(){

  Serial.begin(9600);                 // Запускаем последовательный терминал
  Serial.println("SparkFun ADXL345 Accelerometer Hook Up Guide Example");
  Serial.println();

  adxl.powerOn();                     // Включаем ADXL345
  delay(100); 
  adxl.setRangeSetting(16);           // Задаем настройки диапазона
                                      // Допустимые значения: 2 г, 4 г, 8 г или 16 г
                                      // Более высокие значения = более широкий диапазон измерений
                                      // Более низкие значения = большая чувствительность
  delay(100); 
  adxl.setSpiBit(0);                  // Настройте устройство в 4-проводном режиме SPI, если установлено значение «0», или в 3-проводном режиме SPI, если установлено значение 1.
                                      // По умолчанию: установлено на 1
                                      // Выводы SPI на ATMega328: 11, 12 и 13 в качестве ссылки в библиотеке SPI
  delay(100); 
// Установить режим SPI на соответствующий ADXL345 (думаю, он будет здесь по умолчанию?)

  adxl.setActivityXYZ(1, 0, 0);       // Установите для активации обнаружения движения по осям "adxl.setActivityXYZ(X, Y, Z);" (1 == ВКЛ, 0 == ВЫКЛ)
  adxl.setActivityThreshold(75);      // 62,5 мг на шаг // Установить активность // Пороги бездействия (0-255)

  adxl.setInactivityXYZ(1, 0, 0);     // Установите для обнаружения бездействия по всем осям "adxl.setInactivityXYZ(X, Y, Z);" (1 == ВКЛ, 0 == ВЫКЛ)
  adxl.setInactivityThreshold(75);    // 62,5 мг на шаг // Установка бездействия // Пороги бездействия (0-255)
  adxl.setTimeInactivity(10);         // Сколько секунд бездействия неактивно?

  adxl.setTapDetectionOnXYZ(0, 0, 1); // Обнаружение касаний в направлениях, включенных "adxl.setTapDetectionOnX(X, Y, Z);" (1 == ВКЛ, 0 == ВЫКЛ)

  // Установите значения для того, что считается TAP и что такое DOUBLE TAP (0-255)
  adxl.setTapThreshold(50);           // 62,5 мг на шаг
  adxl.setTapDuration(15);            // 625 мкс на приращение
  adxl.setDoubleTapLatency(80);       // 1,25 мс на шаг
  adxl.setDoubleTapWindow(200);       // 1,25 мс на шаг

  // Установите значения для того, что считается СВОБОДНЫМ ПАДЕНИЕМ (0-255)
  adxl.setFreeFallThreshold(7);       // (5–9) рекомендуется — 62,5 мг за шаг
  adxl.setFreeFallDuration(30);       // (20 - 70) рекомендуется - 5 мс на приращение

  // установка всех прерываний на вывод INT1
  //adxl.setImportantInterruptMapping(1, 1, 1, 1, 1); // Устанавливает "adxl.setEveryInterruptMapping(одиночное нажатие, двойное нажатие, свободное падение, активность, бездействие);"
                                                        // Принимает только 1 или 2 значения для контактов INT1 и INT2. При этом выбирается контакт ADXL345, который будет использоваться для прерываний.
                                                        // У этой библиотеки могут быть проблемы с использованием контакта INT2. По умолчанию используется контакт INT1.

  // Включаем прерывания для каждого режима (1 == ON, 0 == OFF)
  adxl.InactivityINT(1);
  adxl.ActivityINT(1);
  adxl.FreeFallINT(1);
  adxl.doubleTapINT(1);
  adxl.singleTapINT(1);

//attachInterrupt(digitalPinToInterrupt(interruptPin), ADXL_ISR, RISING); // Присоединить прерывание

}

/****************** MAIN CODE ******************/
/*     Accelerometer Readings and Interrupt    */
void loop(){

  // Показания акселерометра
  int x,y,z;   
  adxl.readAccel(&x, &y, &z);         // Чтение значений акселерометра и сохранение их в объявленных выше переменных x,y,z

  // Вывод результатов в последовательный порт
  /* UNCOMMENT TO VIEW X Y Z ACCELEROMETER VALUES */  
  Serial.print(x);
  Serial.print(", ");
  Serial.print(y);
  Serial.print(", ");
  Serial.println(z); 

// ADXL_ISR();
  // Вы также можете не использовать прерывания и просто запускать функции в ADXL_ISR();
  // и вместо этого поместите его в цикл.
  // Это может пригодиться, когда не имеет значения, когда происходит действие.

}

/********************* ISR *********************/
/* Look for Interrupts and Triggered Action    */
void ADXL_ISR() {

  // getInterruptSource очищает все запущенные действия после возврата значения
  // Не вызывайте снова, пока вам не понадобится перепроверить сработавшие действия
  byte interrupts = adxl.getInterruptSource();

  // Обнаружение свободного падения
  if(adxl.triggered(interrupts, ADXL345_FREE_FALL)){
    Serial.println("*** FREE FALL ***");
    //добавьте сюда код, который будет выполняться при обнаружении свободного падения
  } 

  // Бездействие
  if(adxl.triggered(interrupts, ADXL345_INACTIVITY)){
    Serial.println("*** INACTIVITY ***");
     //добавьте сюда код, который будет выполняться при обнаружении бездействия
  }

  // Активность
  if(adxl.triggered(interrupts, ADXL345_ACTIVITY)){
    Serial.println("*** ACTIVITY ***"); 
     //добавьте сюда код, который будет выполняться при обнаружении активности
  }

  // Обнаружение двойного касания
  if(adxl.triggered(interrupts, ADXL345_DOUBLE_TAP)){
    Serial.println("*** DOUBLE TAP ***");
     //добавьте сюда код, который будет выполняться при обнаружении двойного касания
  }

  // Обнаружение нажатия
  if(adxl.triggered(interrupts, ADXL345_SINGLE_TAP)){
    Serial.println("*** TAP ***");
     //добавьте сюда код, который будет выполняться при обнаружении касания
  } 
}