GPS не отображается

Если вы подключите GPS к Serial (контакты 0 и 1), а GSM к AltSoftSerial (контакты 8 и 9), это может сработать. Вам придется отключить контакт 0, чтобы загрузить новые скетчи через USB. Я предполагаю, что у вас UNO или Nano, потому что вы не сказали, какой Arduino вы используете.

Как сказал Маженко, это никогда не будет работать с двумя портами SoftwareSerial. SoftwareSerial очень неэффективен, потому что он отключает прерывания на длительные периоды времени. Это может помешать другим частям вашего скетча или другим библиотекам. И он не может отправлять и получать данные одновременно. Этот ответ содержит полную информацию.

Возможно, вам также захочется взглянуть на мою библиотеку NeoGPS. Она меньше, быстрее, надежнее и точнее всех других библиотек GPS. Даже если вы ее не используете, вам стоит прочитать страницу о выборе последовательного порта. Также есть много советов на странице устранения неполадок.

NeoGPS, AltSoftSerial и NeoSWSerial доступны в диспетчере библиотек IDE в меню Скетч -> Включить библиотеку -> Управление библиотеками.

Кстати, вы не можете использовать delay таким образом. Вы должны постоянно считывать и декодировать символы GPS. Скетч потеряет много-много символов GPS, не давая ему когда-либо получить полную информацию GPS. Вам нужно сделать что-то вроде этого:

#include <LiquidCrystal.h>
#include <NMEAGPS.h>
#include <AltSoftSerial.h>

AltSoftSerial gsmPort; // принимаем контакт 8 на GSM TX, передаем контакт 9 на GSM RX

char msg;

int knockPin = 7;                   // Используем контакт 7 как вход
int knockVal = HIGH;                // Здесь мы записываем наши измерения удара
boolean bAlarm = false;
int knockValue = digitalRead(6);
unsigned long lastKnockTime;        // Записываем время, когда мы измерили удар
int knockAlarmTime = 500;           // Количество миллисекунд, в течение которых сигнализация детонации будет оставаться высокой

static const int GPSBaud = 9600;
NMEAGPS gps;
gps_fix fix;
#define gpsPort Serial // RX-контакт 0 к GPS TX, TX-контакт 1 к GPS RX


const int rs = 12, en = 11, d4 = 5, d5 = 4, d6 = 3, d7 = 2;
LiquidCrystal lcd(rs, en, d4, d5, d6, d7);

void setup ()
{
  gsmPort.begin(19200);   // Установка скорости передачи данных GSM-модуля

  gpsPort.begin(GPSBaud); 
  //Serial.begin(115200); // gpsPort *является* последовательным
  // Последовательный монитор должен быть установлен на 9600 (нижний правый
  // углу окна последовательного монитора)
  Serial.println("GSM SIM900A BEGIN");
  pinMode (knockPin, INPUT) ;       // вход от KY-031
  pinMode (6, OUTPUT);   

  lcd.begin(16, 2);
  lcd.clear();
  lcd.setCursor(2,0);
  lcd.print("VeCAS System");
  lcd.setCursor(3,1);
  lcd.print(">>Begin>>");
  delay( 1000 );
}

void loop ()
{
  // Проверяйте наличие символов GPS (всегда!)
  if (gps.available( gpsPort )) {
    fix = gps.read(); // сохраняем последние поля GPS в одной структуре
    gpsTrack();       // показать последние поля GPS
  }

  // Проверка на наличие стуков

  knockVal = digitalRead (knockPin) ; // прочитать значение KY-031

  if (knockVal == LOW)                // Если мы видим стук
  {

    lastKnockTime = millis();         // записываем время удара
                                      // Следующее не нужно прокручивать экран вывода
    if (!bAlarm)
    {

      bAlarm = true;
      digitalWrite (6, HIGH);

      Serial.println("KNOCK, KNOCK");
      Serial.println(knockVal);

      lcd.clear();
      lcd.setCursor(4,0);
      lcd.print("KNOCK!");
      lcd.setCursor(3,1);
      lcd.print("Detected");
    }
  }
  else
  {
    if( (millis()-lastKnockTime) > knockAlarmTime  &&  bAlarm)
    {
      Serial.println("no knocks");
      bAlarm = false;
      digitalWrite (6, LOW);
    }
  }
}

void gpsTrack()
{
  Serial.print("Latitude= "); 
  if (fix.valid.location)
    Serial.print( fix.latitude(), 6);
  Serial.print(" Longitude= "); 
  if (fix.valid.location)
    Serial.println( fix.longitude(), 6);

  lcd.clear();
  lcd.setCursor(0,0);
  lcd.print("LAT:");
  lcd.setCursor(5,0);
  if (fix.valid.location)
    lcd.print( fix.latitude() );
  lcd.setCursor(0,1);
  lcd.print("LON:");
  lcd.setCursor(5,1);
  if (fix.valid.location)
    lcd.print( fix.longitude() );
}

Обратите внимание, что он также проверяет флаг достоверности местоположения перед использованием значений широты/долготы. Ваш GPS может не знать местоположение, возможно, из-за плохого приема спутников.