Почему Adafruit motor shield не крутит моторы?

Я вижу пару вещей...

1.) Возможно, провода двигателя замыкают корпус двигателя. убедитесь, что это не так.

2.) Возможно, двигатель подключен к неправильному порту для данного кода:

В строке 7 кода написано: AF_DCMotor motor(4);

Поэтому попробуйте физически переключить двигатель на порт 4.

3.) Кроме того, у этой платы есть адрес I2C, и я не вижу его нигде в коде. Вы можете проверить, что такое адрес I2C с этим кодом. Это также покажет вам, что плата управления мотором действительно отвечает.

// --------------------------------------
// i2c_scanner
//
// Версия 1
// Эта программа (или код, похожий на нее)
// можно найти во многих местах.
// Например, на форуме Arduino.cc.
// Первоначальный автор неизвестен.
// Версия 2, июнь 2012 г., использование Arduino 1.0.1
// Максимально упрощено адаптировано пользователем Arduino.cc Krodal
// Версия 3, 26 февраля 2013 г.
// V3 Луарнольда
// Версия 4, 3 марта 2013 г., Использование Arduino 1.0.3
// пользователем Arduino.cc Krodal.
// Изменения Луарнольда удалены.
// Адреса сканирования изменены с 0...127 на 1...119,
// согласно сканеру i2c Ника Гэммона
// http://www.gammon.com.au/forum/?id=10896
// Версия 5, 28 марта 2013 г.
// То же, что и версия 4, но теперь адрес сканируется до 127.
// Кажется, датчик использует адрес 120.
// Версия 6, 27 ноября 2015 г.
// Добавлено ожидание серийной связи Леонардо.
//
//
// Этот скетч тестирует стандартные 7-битные адреса
// Устройства с более высоким битовым адресом могут отображаться некорректно.
//

#include <Wire.h>


void setup()
{
  Wire.begin();

  Serial.begin(9600);
  while (!Serial);             // Леонардо: дождитесь серийного монитора
  Serial.println("\nI2C Scanner");
}


void loop()
{
  byte error, address;
  int nDevices;

  Serial.println("Scanning...");

  nDevices = 0;
  for(address = 1; address < 127; address++ ) 
  {
    // i2c_scanner использует возвращаемое значение
    // Write.endTransmission, чтобы узнать,
    // устройство подтвердило адрес.
    Wire.beginTransmission(address);
    error = Wire.endTransmission();

    if (error == 0)
    {
      Serial.print("I2C device found at address 0x");
      if (address<16) 
        Serial.print("0");
      Serial.print(address,HEX);
      Serial.println("  !");

      nDevices++;
    }
    else if (error==4) 
    {
      Serial.print("Unknow error at address 0x");
      if (address<16) 
        Serial.print("0");
      Serial.println(address,HEX);
    }    
  }
  if (nDevices == 0)
    Serial.println("No I2C devices found\n");
  else
    Serial.println("done\n");

  delay(5000);           // ждем 5 секунд до следующего сканирования
}