Не могу разбудить Attiniy44 из режима сна_mode_pwr_down

Обновлено Я написал следующую программу. Он должен предоставлять запрашиваемые функции.

Но пока у меня нет доступа к ATtiny44a, поэтому я использовал Arduino UNO. Я прочитал оба даташита и не нашел ничего, что мешало бы программе работать на ATtiny44. Поэтому, пожалуйста, попробуйте его, и если он заработает, вы можете прочитать комментарии в программе, чтобы понять, что я сделал, чтобы заставить ее работать.

У меня очень "веселый" кнопку, поэтому иногда программа может не различаться, щелкнул ли я дважды или кнопка отскакивает. Я использовал длительные периоды устранения дребезга, чтобы избавиться от этого. Я прокомментировал это в коде, пожалуйста, проверьте, какое значение подходит вам лучше всего.

Ах, и я немного ускорил мелодию ;-). Мне нравится Heavy Metal больше, чем стиль Walzing Matilda ;-). И я меняю программу так, чтобы она запускала мелодию снова и снова, пока ты снова не нажмешь кнопку. Ваша Программа однажды перестала часто воспроизводить мелодию.

// Этот код предназначен для работы на обычном Arduino Uno
// Первоначальный запрос состоял в том, чтобы реализовать это для ATtiny44a.
// Я задокументирую, если есть разница
// во внимание. Большая часть кода должна выполняться на
// также attiny44.

// Цель этой программы — позволить микроконтроллеру воспроизвести мелодию
// запускается и останавливается нажатием кнопки. MCU должен войти
// энергосберегающий спящий режим при остановке мелодии.
// В спящем режиме нажатие кнопки должно разбудить MCU
// который затем должен продолжить воспроизведение мелодии.

#include <avr/sleep.h>
#include <avr/power.h>

// Контакт кнопки должен быть вторым для Arduino Uno
// для крошечного можно использовать любой вывод, так что вывод 2 подойдет.
const int buttonPin = 2;
const int buzzerPin = 10;
const int led1 = 8;
const int led2 = 7;

// Внимание!!!!: Я использую подтяжку и кнопку
// подключен к GND.
// С этой настройкой нажатие на кнопку приведет контакт к GND.
// Поэтому мы читаем LOW, пока кнопка нажата.
// Если кнопка ВЫСОКАЯ активна - это означает, что кнопка
// подключен к VCC - LOW следующей константы должен
// изменить на HIGH, а RISING нужно изменить на FALLEN.
#define BUTTON_PRESSED LOW
#define INTERRUPT_TRIGGER_METHOD RISING

// Я решил использовать очень большую задержку для устранения дребезга, потому что
// показал очень "веселый" кнопка. Не стесняйтесь экспериментировать
// с этой задержкой.
const long debounceDelay = 150L;


// установка мелодии

// определяем значения высоты тона ноты
#define cs6 1109
#define fs5 740
#define d6 1175
#define c6 1047
#define f5 698
#define b5 988
#define e5 659
#define bf5 932
#define ef5 622
#define b4 494
#define g5 784

// предоставить мелодию в виде массива.
const uint16_t halloween[] PROGMEM = { 
  cs6, fs5, fs5, cs6, fs5, fs5, cs6, fs5,  d6, fs5,
  cs6, fs5, fs5, cs6, fs5, fs5, cs6, fs5,  d6, fs5,
  cs6, fs5, fs5, cs6, fs5, fs5, cs6, fs5,  d6, fs5,
  cs6, fs5, fs5, cs6, fs5, fs5, cs6, fs5,  d6, fs5,
  cs6, fs5, fs5, cs6, fs5, fs5, cs6, fs5,  d6, fs5,
  cs6, fs5, fs5, cs6, fs5, fs5, cs6, fs5,  d6, fs5,
  c6,  f5,  f5,  c6,  f5,  f5,  c6,  f5,  cs6,  f5,
  c6,  f5,  f5,  c6,  f5,  f5,  c6,  f5,  cs6,  f5,
  cs6, fs5, fs5, cs6, fs5, fs5, cs6, fs5,  d6, fs5,
  cs6, fs5, fs5, cs6, fs5, fs5, cs6, fs5,  d6, fs5,
  c6,  f5,  f5,  c6,  f5,  f5,  c6,  f5,  cs6,  f5,
  c6,  f5,  f5,  c6,  f5,  f5,  c6,  f5,  cs6,  f5,
  b5,  e5,  e5,  b5,  e5,  e5,  b5,  e5,  c6,  e5,
  b5,  e5,  e5,  b5,  e5,  e5,  b5,  e5,  c6,  e5,
  bf5, ef5, ef5, bf5, ef5, ef5, bf5, ef5,  b5, ef5,
  bf5, ef5, ef5, bf5, ef5, ef5, bf5, ef5,  b5, ef5,
  b5,  e5,  e5,  b5,  e5,  e5,  b5,  e5,  c6,  e5,
  b5,  e5,  e5,  b5,  e5,  e5,  b5,  e5,  c6,  e5,
  bf5, ef5, ef5, bf5, ef5, ef5, bf5, ef5,  b5, ef5,
  bf5, ef5, ef5, bf5, ef5, ef5, bf5, ef5,  b5, ef5,
  fs5,  b4,  b4, fs5,  b4,  b4, fs5,  b4,  g5,  b4,
  fs5,  b4,  b4, fs5,  b4,  b4, fs5,  b4,  g5,  b4,
  fs5,  b4,  b4, fs5,  b4,  b4, fs5,  b4,  g5,  b4,
  fs5,  b4,  b4, fs5,  b4,  b4, fs5,  b4,  g5,  b4,
  fs5,  b4,  b4, fs5,  b4,  b4, fs5,  b4,  g5,  b4,
  fs5,  b4,  b4, fs5,  b4,  b4, fs5,  b4,  g5,  b4,
  fs5,  b4,  b4, fs5,  b4,  b4, fs5,  b4,  g5,  b4,
  fs5,  b4,  b4, fs5,  b4,  b4, fs5,  b4,  g5,  b4,
  fs5,  b4,  b4, fs5,  b4,  b4, fs5,  b4,  g5,  b4
};

// определяем переменные обработки для функции воспроизведения
unsigned long previousMillis = 0;
unsigned long pauseBetweenNotes = 300;
unsigned long lengthOfActiveNote = 300;
int noteCounter = 0;
boolean toneOn = false;

// обработка режима воспроизведения
// после вставки батарейки мелодия не играет.
// После того, как пользователь нажал и отпустил
// кнопка, мы начнем с мелодии.
volatile boolean playMelody = false;
volatile bool playModeChangeRequested = false;

// чтение и устранение дребезга кнопки
volatile unsigned long lastDebouncingMillis = 0;


void stopTheMelody()
{
  noTone(buzzerPin);
  toneOn = false;
  digitalWrite(led1, toneOn);
  digitalWrite(led2, toneOn);  
}

void startTheMelody()
{
  previousMillis = 0;
  pauseBetweenNotes = 0;
  noteCounter = 0;
  toneOn = false;
  digitalWrite(led1, toneOn);
  digitalWrite(led2, toneOn);  
}

void melody () 
{
  unsigned long currentMillis = millis();
  if (! toneOn && 
      (currentMillis - previousMillis) > pauseBetweenNotes)
  {
    pauseBetweenNotes = 167 * 0.2;
    tone(buzzerPin, pgm_read_word(&halloween[noteCounter]));
    noteCounter++;    
    if (noteCounter > 290)
    {
      // старая программа проигрывает мелодию только один раз
      // со сбросом счетчика банкнот в 0
      // мелодия запускается снова и снова.
      noteCounter = 0;
    }
    toneOn = true;
    digitalWrite(led1, toneOn);
    digitalWrite(led2, toneOn);  
    previousMillis = currentMillis;
  }
  else if(toneOn && 
          (currentMillis - previousMillis) > lengthOfActiveNote)
  {
    lengthOfActiveNote = 58;
    noTone(buzzerPin);
    toneOn = false;
    digitalWrite(led1, toneOn);
    digitalWrite(led2, toneOn);  
    previousMillis = currentMillis;
  } 
}

// Это процедура обслуживания прерывания.
// Он вызывается каждый раз, когда кнопка будет отпущена.
void ISR_buttonReleased()
{ 
  // Здесь мы знаем, что этот ISR вызывается, потому что,
  // кнопка была отпущена.
  lastDebouncingMillis = 0L;
  playModeChangeRequested = true;

  if (!playMelody)
  {
    // если прерывание сработало во время сна MCU
    // нам нужно выключить спящий режим, чтобы возобновить работу
    // нормальная активность. В противном случае метод устранения дребезга не работает.
    // работать, как это делает код вне ISR.
    sleep_disable();
    power_all_enable();
  }
}

void setup()
{
  pinMode(buttonPin, INPUT_PULLUP);
  pinMode(led1, OUTPUT);
  pinMode(led2, OUTPUT);
  pinMode(buzzerPin, OUTPUT);

  // настройка паранойи
  playMelody = false;
  playModeChangeRequested = false;
  lastDebouncingMillis = 0;
  
  // прерывание срабатывает по переднему фронту, т.е.
  // когда кнопка будет отпущена
  attachInterrupt(
       digitalPinToInterrupt(buttonPin), 
       ISR_buttonReleased, 
       INTERRUPT_TRIGGER_METHOD);

  // остановить мелодию и спать
  stopTheMelody();
  set_sleep_mode(SLEEP_MODE_PWR_DOWN);
  sleep_enable();
  sleep_cpu();
}

void loop()
{
  // lastDebouncingMillis будет установлено в 0 1st) в
  // подпрограмма установки и 2-я) в ISR.
  if (lastDebouncingMillis==0 || 
      digitalRead(buttonPin)==BUTTON_PRESSED)
  {
    // Вот волшебство!
    // Синхронизируем ISR, спящий режим, длинная кнопка
    // нажмите без отпускания и
    // кнопка подпрыгивает с этим единственным оператором if.
    lastDebouncingMillis = millis();
  }  
  
  if (playModeChangeRequested) 
  {
    unsigned long tempMillis = millis();
    if((tempMillis - lastDebouncingMillis) > debounceDelay)
    {      
      playModeChangeRequested = false;
      playMelody = !playMelody;
      if (!playMelody)
      {
        // остановить мелодию и спать
        stopTheMelody();
        set_sleep_mode(SLEEP_MODE_PWR_DOWN);
        sleep_enable();
        sleep_cpu();
      }
      else
      {
        startTheMelody();
      }
    }
  }
  
  if(playMelody)
  {
      melody();
  }      
}

Старый ответ удален

Старый ответ был недостаточно ясен для этой сложной темы.