Приведенный ниже код позволяет достичь того, о чем вы просите:

#include <avr/sleep.h>
#include <avr/power.h>

const byte AWAKE_LED = 8;
const byte GREEN_LED = 9;
const unsigned long WAIT_TIME = 5000;

ISR (PCINT2_vect)
{
  // здесь обрабатывается прерывание по смене вывода для D0-D7
}  // конец PCINT2_vect

void setup() 
{
  pinMode (GREEN_LED, OUTPUT);
  pinMode (AWAKE_LED, OUTPUT);
  digitalWrite (AWAKE_LED, HIGH);
  Serial.begin (9600);
} // конец настройки

unsigned long lastSleep;

void loop() 
{
  if (millis () - lastSleep >= WAIT_TIME)
  {
    lastSleep = millis ();

    noInterrupts ();

    byte old_ADCSRA = ADCSRA;
    // отключить АЦП
    ADCSRA = 0;  
    // прерывание смены контакта (пример для D0)
    PCMSK2 |= bit (PCINT16); // нужен пин 0
    PCIFR  |= bit (PCIF2);   // очистить все невыполненные прерывания
    PCICR  |= bit (PCIE2);   // включить прерывания по смене контактов для D0-D7

    set_sleep_mode (SLEEP_MODE_PWR_DOWN);  
    power_adc_disable();
    power_spi_disable();
    power_timer0_disable();
    power_timer1_disable();
    power_timer2_disable();
    power_twi_disable();

    UCSR0B &= ~bit (RXEN0);  // отключить приемник
    UCSR0B &= ~bit (TXEN0);  // отключить передатчик

    sleep_enable();
    digitalWrite (AWAKE_LED, LOW);
    interrupts ();
    sleep_cpu ();      
    digitalWrite (AWAKE_LED, HIGH);
    sleep_disable();
    power_all_enable();

    ADCSRA = old_ADCSRA;
    PCICR  &= ~bit (PCIE2);   // отключить прерывания смены контактов для D0-D7
    UCSR0B |= bit (RXEN0);  // включить приемник
    UCSR0B |= bit (TXEN0);  // включить передатчик
  }  // конец времени сна

  if (Serial.available () > 0)
  {
    byte flashes = Serial.read () - '0';
    if (flashes > 0 && flashes < 10)
      {
      // мигает светодиодом x раз
      for (byte i = 0; i < flashes; i++)
        {
        digitalWrite (GREEN_LED, HIGH);
        delay (200);  
        digitalWrite (GREEN_LED, LOW);
        delay (200);  
        }
      }        
  }  // конец if

}  // конец цикла

Я использовал прерывание смены контакта на выводе Rx, чтобы заметить, когда приходят последовательные данные. В этом тесте плата переходит в спящий режим, если в течение 5 секунд не происходит никакой активности (светодиод «wake» гаснет). Входящие последовательные данные вызывают прерывание смены контакта, чтобы разбудить плату. Она ищет число и мигает «зеленым» светодиодом указанное количество раз.

Измеренный ток

Работая при 5 В, я измерил около 120 нА тока во время сна (0,120 мкА).

Пробуждающее сообщение

Однако проблема заключается в том, что первый поступивший байт теряется из-за того, что последовательное оборудование ожидает падающего уровня на Rx (стартовый бит), который уже поступил к моменту его полного пробуждения.

Я предлагаю (как в ответе geometrikal) сначала отправить сообщение "wake", а затем сделать паузу на короткое время. Пауза нужна для того, чтобы убедиться, что оборудование не интерпретирует следующий байт как часть сообщения wake. После этого все должно работать нормально.

Поскольку здесь используется прерывание по смене контакта, никакого другого оборудования не требуется.

Измененная версия с использованием SoftwareSerial

Версия ниже успешно обрабатывает первый байт, полученный по последовательному порту. Она делает это следующим образом:

• Использование SoftwareSerial, который использует прерывания по смене выводов. Прерывание, вызванное стартовым битом первого последовательного байта, также пробуждает процессор.

• Установка предохранителей таким образом, чтобы мы использовали:

  • Внутренний RC-генератор
  • БПК отключен
  • Предохранители были: низкий: 0xD2, высокий: 0xDF, расширенный: 0xFF

Вдохновленный FarO в комментарии, это позволяет процессору просыпаться за 6 тактов (750 нс). При 9600 бод время каждого бита составляет 1/9600 (104,2 мкс), поэтому дополнительная задержка незначительна.

#include <avr/sleep.h>
#include <avr/power.h>
#include <SoftwareSerial.h>

const byte AWAKE_LED = 8;
const byte GREEN_LED = 9;
const unsigned long WAIT_TIME = 5000;
const byte RX_PIN = 4;
const byte TX_PIN = 5;

SoftwareSerial mySerial(RX_PIN, TX_PIN); // RX, TX

void setup() 
{
  pinMode (GREEN_LED, OUTPUT);
  pinMode (AWAKE_LED, OUTPUT);
  digitalWrite (AWAKE_LED, HIGH);
  mySerial.begin(9600);
} // конец настройки

unsigned long lastSleep;

void loop() 
{
  if (millis () - lastSleep >= WAIT_TIME)
  {
    lastSleep = millis ();

    noInterrupts ();

    byte old_ADCSRA = ADCSRA;
    // отключить АЦП
    ADCSRA = 0;  

    set_sleep_mode (SLEEP_MODE_PWR_DOWN);  
    power_adc_disable();
    power_spi_disable();
    power_timer0_disable();
    power_timer1_disable();
    power_timer2_disable();
    power_twi_disable();

    sleep_enable();
    digitalWrite (AWAKE_LED, LOW);
    interrupts ();
    sleep_cpu ();      
    digitalWrite (AWAKE_LED, HIGH);
    sleep_disable();
    power_all_enable();

    ADCSRA = old_ADCSRA;
  }  // конец времени сна

  if (mySerial.available () > 0)
  {
    byte flashes = mySerial.read () - '0';
    if (flashes > 0 && flashes < 10)
      {
      // мигает светодиодом x раз
      for (byte i = 0; i < flashes; i++)
        {
        digitalWrite (GREEN_LED, HIGH);
        delay (200);  
        digitalWrite (GREEN_LED, LOW);
        delay (200);  
        }
      }        
  }  // конец if

}  // конец цикла

Потребление энергии в спящем режиме составило 260 нА (0,260 мкА), так что это очень низкое потребление, когда оно не нужно.

Обратите внимание, что при такой установке фьюзов процессор работает на частоте 8 МГц. Поэтому вам необходимо сообщить об этом IDE (например, выбрать "Lilypad" в качестве типа платы). Таким образом, задержки и SoftwareSerial будут работать на правильной скорости.