передать последовательность бит с помощью Arduino Uno

Побитовая отправка фрагмента данных на самом деле выглядит так:

• пройти по каждому байту данных
• для каждого байта (= 8 бит) поместите каждый бит на светодиод и ждите

Это также имеет некоторые существенные недостатки:

• Отсутствие обнаружения и исправления ошибок. Если на датчике освещенности/камере возникнут помехи из-за окружающей среды, данные будут считаны неверно. Для этого потребуется закодировать данные с помощью какой-либо схемы кодирования или добавить контрольную сумму.
• Вывод сигнала на встроенный светодиод Arduino Uno / Nano — плохая идея, так как он находится прямо рядом со светодиодами питания, RX и TX
• Передача сигнала в видимом спектре создаёт помехи. Именно поэтому мы используем инфракрасные передачи.
• Приёмник и передатчик могут быть рассинхронизированы. Это означает, что приёмник не производит выборку выходного сигнала передатчика в нужное время. Для решения этой проблемы следует использовать преамбулу, избыточную выборку и усреднение на приёмнике.

Тем не менее, на мой взгляд, лучше использовать другие проверенные методы, такие как ИК-порт, приёмопередатчики 2,4 ГГц и т. д. Другие микроконтроллеры (пример) даже имеют встроенные периферийные устройства для передачи ИК-сигналов по определённому протоколу.

На Arduino Uno/Nano вы также можете использовать библиотеку IRemote для отправки и получения данных с помощью недорогого ИК-светодиода и ИК-приемника, многие из которых входят в стартовые наборы (и в остальном тоже недорогие).

Приведённый ниже код просто принимает поток байтов и выводит их побитово на светодиод. Больше ничего не происходит. Кроме того, метод digitalWrite медленный и его следует заменить на более быстрый вариант.

#include <Arduino.h>

/* LED to output from */
const int LEDTrans = 13;
/* Length of a symbol */
const int timeWait = 500;

const char dataToSend[] = "Hello World";

/* Transmits data bitwise */
void transmitData(const char* data, size_t length) {
    //go through each byte of the data
    for(size_t i = 0; i < length; i++) {
        uint8_t currentByte = (uint8_t) data[i];

        //Go through each of the 8 bits in the byte
        //Goes from LSB to MSB (right-to-left)
        for(int j = 0; j < 8; j++) {
            //uses Arduino.h macro "bitRead"
            bool currentBit = bitRead(currentByte, j);

            //Set the LED on/off
            digitalWrite(LEDTrans, currentBit);
            //Wait for the symbol time
            delay(timeWait);
        }
    }
}

void setup() {
    pinMode(LEDTrans, OUTPUT);
}

void loop() {
    transmitData(dataToSend, strlen(dataToSend));
    //turn LED OFF again
    digitalWrite(LEDTrans, 0);
    delay(2000);
}