ESP8266 Извлечение учетных данных с SD делает esp неспособным подключиться

esp8266 c++ wifi sd-card esp8266webserver

Я пытаюсь настроить Wi-Fi SD-сервер и хочу поместить учетные данные Wi-Fi в config.txt файл на SD-карте. Весь код работает нормально. когда я не использую учетные данные sd, но когда я это делаю, я сталкиваюсь с некоторыми проблемами;

Код чтения файлов, кажется, работает, потому что я печатаю учетные данные перед передачей их в wifi.begin, и они распечатывают те же значения, что и мои учетные данные. К сожалению, он не подключается к сети. Я думаю, что это как-то связано с паролем, потому что если SSID неверен, я получаю другую ошибку.

Я огляделся вокруг, и общей причиной этого является слишком слабый источник питания, но в настоящее время я включаю его с помощью своего источника питания 10A, так что это не может быть проблемой..

Выход:

Чтение конфигурационного файла MYSID MYPASSWORD SDWebserver scandone Подключение к MYSID scandone состояние: 0 -> 2 (b0) состояние: 2 -> 3 (0) состояние: 3 -> 5 (10) добавить 0 помощь 4 состояние cnt: 5 -> 2 (fc0) rm 0 Не удалось подключиться к MYSID состояние повторного подключения: 2 -> 0 (0) состояние scandone: 0 -> 2 (b0) состояние: 2 -> 3 (0) состояние: 3 -> 5 (10) добавить 0 помощь 4 состояние cnt: 5 -> 2 (fc0) rm 0 состояние переподключения: 2 - > 0 (0) состояние scandone: 0 - >2 (b0) состояние: 2 - > 3 (0) состояние: 3 -> 5 (10) добавить 0 помощь 4 cnt состояние: 5 -> 2 (fc0)

просто повторяет это снова и снова.

Код:

#include <ESP8266WiFi.h>
#include <WiFiClient.h>
#include <ESP8266WebServer.h>
#include <ESP8266mDNS.h>
#include <SPI.h>
#include <SD.h>



#define DBG_OUTPUT_PORT Serial

String SSID2;
String Password2;
String Host2;

ESP8266WebServer server(80);

static bool hasSD = false;
File uploadFile;


void returnOK() {
  server.send(200, "text/plain", "");
}

void returnFail(String msg) {
  server.send(500, "text/plain", msg + "\r\n");
}

bool loadFromSdCard(String path){
  String dataType = "text/plain";
  if(path.endsWith("/")) path += "index.htm";

  if(path.endsWith(".src")) path = path.substring(0, path.lastIndexOf("."));
  else if(path.endsWith(".htm")) dataType = "text/html";
  else if(path.endsWith(".css")) dataType = "text/css";
  else if(path.endsWith(".js")) dataType = "application/javascript";
  else if(path.endsWith(".png")) dataType = "image/png";
  else if(path.endsWith(".gif")) dataType = "image/gif";
  else if(path.endsWith(".jpg")) dataType = "image/jpeg";
  else if(path.endsWith(".ico")) dataType = "image/x-icon";
  else if(path.endsWith(".xml")) dataType = "text/xml";
  else if(path.endsWith(".pdf")) dataType = "application/pdf";
  else if(path.endsWith(".zip")) dataType = "application/zip";
  else if(path.endsWith(".gcode")) dataType = "text/gcode";

  File dataFile = SD.open(path.c_str());
  if(dataFile.isDirectory()){
    path += "/index.htm";
    dataType = "text/html";
    dataFile = SD.open(path.c_str());
  }

  if (!dataFile)
    return false;

  if (server.hasArg("download")) dataType = "application/octet-stream";

  if (server.streamFile(dataFile, dataType) != dataFile.size()) {
    DBG_OUTPUT_PORT.println("Sent less data than expected!");
  }

  dataFile.close();
  return true;
}

void handleFileUpload(){
  if(server.uri() != "/edit") return;
  HTTPUpload& upload = server.upload();
  if(upload.status == UPLOAD_FILE_START){
    if(SD.exists((char *)upload.filename.c_str())) SD.remove((char *)upload.filename.c_str());
    uploadFile = SD.open(upload.filename.c_str(), FILE_WRITE);
    DBG_OUTPUT_PORT.print("Upload: START, filename: "); DBG_OUTPUT_PORT.println(upload.filename);
  } else if(upload.status == UPLOAD_FILE_WRITE){
    if(uploadFile) uploadFile.write(upload.buf, upload.currentSize);
    DBG_OUTPUT_PORT.print("Upload: WRITE, Bytes: "); DBG_OUTPUT_PORT.println(upload.currentSize);
  } else if(upload.status == UPLOAD_FILE_END){
    if(uploadFile) uploadFile.close();
    DBG_OUTPUT_PORT.print("Upload: END, Size: "); DBG_OUTPUT_PORT.println(upload.totalSize);
  }
}

void deleteRecursive(String path){
  File file = SD.open((char *)path.c_str());
  if(!file.isDirectory()){
    file.close();
    SD.remove((char *)path.c_str());
    return;
  }

  file.rewindDirectory();
  while(true) {
    File entry = file.openNextFile();
    if (!entry) break;
    String entryPath = path + "/" +entry.name();
    if(entry.isDirectory()){
      entry.close();
      deleteRecursive(entryPath);
    } else {
      entry.close();
      SD.remove((char *)entryPath.c_str());
    }
    yield();
  }

  SD.rmdir((char *)path.c_str());
  file.close();
}

void handleDelete(){
  if(server.args() == 0) return returnFail("BAD ARGS");
  String path = server.arg(0);
  if(path == "/" || !SD.exists((char *)path.c_str())) {
    returnFail("BAD PATH");
    return;
  }
  deleteRecursive(path);
  returnOK();
}

void handleCreate(){
  if(server.args() == 0) return returnFail("BAD ARGS");
  String path = server.arg(0);
  if(path == "/" || SD.exists((char *)path.c_str())) {
    returnFail("BAD PATH");
    return;
  }

  if(path.indexOf('.') > 0){
    File file = SD.open((char *)path.c_str(), FILE_WRITE);
    if(file){
      file.write((const char *)0);
      file.close();
    }
  } else {
    SD.mkdir((char *)path.c_str());
  }
  returnOK();
}

void printDirectory() {
  if(!server.hasArg("dir")) return returnFail("BAD ARGS");
  String path = server.arg("dir");
  if(path != "/" && !SD.exists((char *)path.c_str())) return returnFail("BAD PATH");
  File dir = SD.open((char *)path.c_str());
  path = String();
  if(!dir.isDirectory()){
    dir.close();
    return returnFail("NOT DIR");
  }
  dir.rewindDirectory();
  server.setContentLength(CONTENT_LENGTH_UNKNOWN);
  server.send(200, "text/json", "");
  WiFiClient client = server.client();

  server.sendContent("[");
  for (int cnt = 0; true; ++cnt) {
    File entry = dir.openNextFile();
    if (!entry)
    break;

    String output;
    if (cnt > 0)
      output = ',';

    output += "{\"type\":\"";
    output += (entry.isDirectory()) ? "dir" : "file";
    output += "\",\"name\":\"";
    output += entry.name();
    output += "\"";
    output += "}";
    server.sendContent(output);
    entry.close();
 }
 server.sendContent("]");
 dir.close();
}
void handleNotFound(){
  if(hasSD && loadFromSdCard(server.uri())) return;
  String message = "SDCARD Not Detected\n\n";
  message += "URI: ";
  message += server.uri();
  message += "\nMethod: ";
  message += (server.method() == HTTP_GET)?"GET":"POST";
  message += "\nArguments: ";
  message += server.args();
  message += "\n";
  for (uint8_t i=0; i<server.args(); i++){
    message += " NAME:"+server.argName(i) + "\n VALUE:" + server.arg(i) + "\n";
  }
  server.send(404, "text/plain", message);
  DBG_OUTPUT_PORT.print(message);
}

void setup(void){
  DBG_OUTPUT_PORT.begin(115200);
  DBG_OUTPUT_PORT.setDebugOutput(true);
  if (SD.begin(SS)){
     DBG_OUTPUT_PORT.println("SD Card initialized.");
     hasSD = true;
  }
   File configfile;
   configfile = SD.open("config.txt", FILE_READ);
   if (configfile.available()){
     DBG_OUTPUT_PORT.println("Reading config file");
      String SSID1 = configfile.readStringUntil('\r');
      SSID1.replace("SSID=[", "");
      SSID1.replace("]", "");
      SSID2 = SSID1;
      String Password1 = configfile.readStringUntil('\r');
      Password1.replace("password=[", "");
      Password1.replace("]", "");
      Password2 = Password1;
      String Host1 = configfile.readStringUntil('\r');
      Host1.replace("host=[", "");
      Host1.replace("]", "");
      Host2 = Host1;
   }
   else{
    DBG_OUTPUT_PORT.println("config.txt not found");
   }

  const char* ssid = SSID2.c_str(); 
  DBG_OUTPUT_PORT.print(ssid);
  const char* password = Password2.c_str();
  DBG_OUTPUT_PORT.print(password);
  const char* host =  Host2.c_str();
  DBG_OUTPUT_PORT.print(host);
  DBG_OUTPUT_PORT.println();
  WiFi.begin(ssid, password);
  DBG_OUTPUT_PORT.print("Connecting to ");
  DBG_OUTPUT_PORT.print(ssid);
  DBG_OUTPUT_PORT.println();

  // Wait for connection
  uint8_t i = 0;
  while (WiFi.status() != WL_CONNECTED && i++ < 20) {//wait 10 seconds
    delay(500);
  }
  if(i == 21){
    DBG_OUTPUT_PORT.print("Could not connect to ");
    DBG_OUTPUT_PORT.println(ssid);
    while(1) delay(500);
  }
  DBG_OUTPUT_PORT.print("Connected! IP address: ");
  DBG_OUTPUT_PORT.println(WiFi.localIP());

  if (MDNS.begin(host)) {
    MDNS.addService("http", "tcp", 80);
    DBG_OUTPUT_PORT.println("MDNS responder started");
    DBG_OUTPUT_PORT.print("You can now connect to http://");
    DBG_OUTPUT_PORT.print(host);
    DBG_OUTPUT_PORT.println(".local");
  }


  server.on("/list", HTTP_GET, printDirectory);
  server.on("/edit", HTTP_DELETE, handleDelete);
  server.on("/edit", HTTP_PUT, handleCreate);
  server.on("/edit", HTTP_POST, [](){ returnOK(); }, handleFileUpload);
  server.onNotFound(handleNotFound);

  server.begin();
  DBG_OUTPUT_PORT.println("HTTP server started");

}

void loop(void){
  server.handleClient();
  MDNS.update();
}

Любая помощь будет оценена по достоинству!

, 👍1

Обсуждение

Интересно, где находится \n после строки ssid? Я думаю, что это все еще в начале пароля, @Juraj

Я все понял! мне нужно было заменить "/n" и "/r"., @Earthbound Ruben


1 ответ

0

мне нужно было заменить "/n" и "/r" ничем

      SSID1.replace("SSID=", "");
      SSID1.replace("\r", "");
      SSID1.replace("\n", "");
      SSID2 = SSID1;
      Password1.replace("password=", "");
      Password1.replace("\r", "");
      Password1.replace("\n", "");
      Password2 = Password1;
      Host1.replace("host=", "");
      Host1.replace("\r", "");
      Host1.replace("\n", "");
      Host2 = Host1;
,

В ответе должно быть нечто большее, чем просто этот код. Похоже, вы сделали комментарии по своему собственному вопросу, которые можно и нужно внести в ответ., @timemage

readStringUntil отбрасывает символ терминатора. поэтому readStringUntil('\r'); отбрасывает \r., @Juraj

Смотрите также: