Кнопка для запуска 5-кратной вспышки

Прежде всего, учитывая ваш комментарий: "У меня нет времени [...] заниматься программированием arduino" - Если вы не научитесь кодировать, то не сможете работать с кодом (а это включает в себя создание библиотек, которые вы найдете в Интернете). А обучение требует времени, это так просто.

Я рекомендую вам забыть об этих библиотеках и реализовать эту легкую задачу с нуля, чтобы вы действительно чему-то научились. Приведенный ниже код имеет логику, которую вы просите, попробуйте понять, что он делает.

#define BUTTON_PIN   11
#define LED_PIN      13

bool button_was_pressed=false;

void setup(){
  pinMode(LED_PIN,OUTPUT);
}

void loop() {
  if (digitalRead(BUTTON_PIN)) {
    if(!button_was_pressed) {
      for (int i=0;i<5;i++) {
        digitalWrite(LED_PIN,HIGH);
        delay(50);
        digitalWrite(LED_PIN,LOW);
        delay(50);
      }
    }
    button_was_pressed=true;
  }
  else {
    button_was_pressed=false;
  }
}

...довольно просто, и это всего лишь несколько строк. Вы можете отказаться от кнопки и использовать неблокирующий стиль кодирования, но это другая глава.

Мой совет заключается в том, что вы изучаете программирование структурированным образом, например, просматривая учебники. Сайт вопросов и ответов не является подходящим местом для этого, так как мы отвечаем только на вопросы.

Мне удалось сделать это с другой библиотекой с "doFlash(5)", но я должен работать с LC basetools в этом сценарии, и я не могу понять, как это сделать.

Похоже, вам все еще разрешено писать код Arduino в своем скетче, так почему бы не использовать "концепцию" BlinkWithoutDelay и просто написать свой собственный код.

Я бы предпочел решение ООП для светодиодной мигающей части вашего требования.

// Arduino IDE 1.8.9.
// Sketch uses 1126 bytes (3%) of program storage space.
// Global variables use 25 bytes (1%) of dynamic memory.
class Flasher{

  private:

    byte ledPin;
    byte ledState;
    unsigned int flashCounter;
    unsigned long highTime;
    unsigned long lowTime;
    unsigned long previousMillis;

  public:

    Flasher(byte ledPinNumber, unsigned long ledOnTime, unsigned long ledOffTime){
      ledPin = ledPinNumber;
      ledState = LOW;
      highTime = ledOnTime;
      lowTime = ledOffTime;
      previousMillis = 0;
      pinMode(ledPinNumber, OUTPUT);
      digitalWrite(ledPinNumber, LOW);
    }

    void Update(){

      // Проверка, не пришло ли время изменить состояние светодиода.
      unsigned long currentMillis = millis();

      if((ledState == HIGH) && (currentMillis - previousMillis >= highTime) && ((flashCounter > 0))){
        ledState = LOW;
        previousMillis += highTime;
        digitalWrite(ledPin, ledState);
        if(flashCounter > 0){flashCounter--;}
      }
      else if((ledState == LOW) && (currentMillis - previousMillis >= lowTime) && ((flashCounter > 0))){
        ledState = HIGH;
        previousMillis += lowTime;
        digitalWrite(ledPin, ledState);
        if(flashCounter > 0){flashCounter--;}
      }
    }

    void Start(unsigned int flashNumberOfTimes){
      flashCounter = flashNumberOfTimes * 2;
      ledState = LOW;
      digitalWrite(ledPin, ledState);
    }

    void Stop(){
      Start(0);
    }

    void SetPinHighTime(unsigned long pinHighTime){
      highTime = pinHighTime;
    }

    void SetPinLowTime(unsigned long pinLowTime){
      lowTime = pinLowTime;
    }

};

// Flasher object_name(Pin Number, ON Time MS, OFF Time MS);
Flasher led1(LED_BUILTIN, 500, 500);

void setup(){

  // Мигнуть светодиодом 5 раз.
  led1.Start(5);

}

void loop(){

  // Вызовите функцию обновления как можно быстрее.
  led1.Update();

}