Остановить мигание светодиодов

while (buttonState == LOW)

погружает вас в бесконечный цикл, как только buttonState == LOW.
Вы должны опросить buttonState внутри этого цикла, если хотите выйти из него.
Однако этого недостаточно для ваших целей. Что вам действительно нужно, так это переменная (логическая) — назовем ее, например, blinking, — которая меняет свое значение каждый раз, когда вы видите спадающий фронт в buttonState.
Затем проверьте значение этой переменной в предложении if/else следующим образом:

if (blinking == true)
{
   digitalWrite(led, HIGH);   // включаем светодиод (HIGH - уровень напряжения)
   delay(1000);               // ждем секунду
   digitalWrite(led, LOW);    // выключаем светодиод, понижая напряжение
   delay(1000);               // ждем секунду
}
else
{
   digitalWrite(led, LOW);}
}

Но при этом вы вскоре столкнетесь со следующей проблемой: скорость опроса для вашей кнопки очень низкая из-за очень длительных задержек, которые удерживают вас около 2 секунд внутри предложения if.< бр> Попробуйте настроить цикл моргания с помощью ШИМ, как описано здесь
Затем используйте приведенное выше предложение if, чтобы установить коэффициент заполнения ШИМ равным 50%, и предложение else, чтобы установить его равным 0%.

ОТРЕДАКТИРОВАНО

Функция Arduino loop() делает использование цикла while избыточным в этом случае. Хуже того: то, как вы реализовали этот цикл while, предотвращает обновление buttonState, что приводит к застреванию в цикле.

Что вам действительно нужно, так это использовать таймеры для мигания светодиода и машину с двумя состояниями, управляемую переходами кнопок с ВЫСОКОГО на НИЗКИЙ.

Вместо этого попробуйте следующее:

#include "Timer.h"

// К контакту 13 подключен светодиод на большинстве плат Arduino.
// дать ему имя:
const int led = 13;
const int buttonPin = 2;

// объявляем переменные состояния глобальными
bool buttonState = LOW;
bool buttonState_prev = LOW;
bool toggleBlinking;
bool blinkState;

// объявляем объект Timer, чтобы мигание можно было выполнять без потери нажатия кнопок
Timer timer_b;
int blink_id;

// процедура установки запускается один раз, когда вы нажимаете сброс:
void setup() {
  // инициализируем цифровой вывод как выход.
  pinMode(led, OUTPUT);
  pinMode(buttonPin, INPUT_PULLUP);

  // исходное состояние: переключать светодиод каждые 1000 мс
  blink_id = timer_b.oscillate(led, 1000, HIGH);
  blinkState = true;
  toggleBlinking = false;
}

// процедура цикла выполняется снова и снова навсегда:
void loop() {
  // Обновить таймер (обязательно)
  timer_b.update();

  // проверяем, была ли нажата кнопка (с ВЫСОКОГО на НИЗКИЙ),
  // затем отменить дребезг и поднять флаг переключения
  buttonState = digitalRead(buttonPin);
  if ((buttonState != buttonState_prev) && (buttonState_prev == HIGH)) {
    // простое устранение дребезга кнопок (подтверждение нажатия через несколько мс)
    delay (50);
    buttonState = digitalRead(buttonPin);
    if (buttonState != buttonState_prev) toggleBlinking = true;
  }

  // сохранить текущее состояние светодиода, если кнопка не была нажата
  switch (blinkState) {
    case true:
      // если кнопка была нажата, прекращаем мигать и меняем состояние светодиода
      if (toggleBlinking == true) {
        timer_b.stop (blink_id);
        blinkState = false;
      }
      break;
    case false:
      digitalWrite(led, LOW);
      // если кнопка была нажата, начинаем мигать и менять состояние светодиода
      if (toggleBlinking == true) {
        blink_id = timer_b.oscillate(led, 1000, HIGH);
        blinkState = true;
      }
      break;
  }

  buttonState_prev = buttonState;
  toggleBlinking = false;
}

ПРИМЕЧАНИЕ. Вам потребуется установить библиотеку Timer.h. Я ПРОВЕРИЛ СВОЙ КОД, И ОНО РАБОТАЕТ.

Как объяснил ОП в комментарии, он пытается добиться того, чтобы кнопка попеременно мигала и выключалась, а не нажималась кнопка, чтобы выключить светодиод.

Это можно сделать следующим образом:

bool prevButtonState;
bool ledBlinking;

void loop() 
{
    bool buttonState = digitalRead(buttonPin);

    if (prevButtonState && !buttonState)
    { // Нажатие края: есть переход между высоким и низким
        ledBlinking = !ledBlinking;
    }
    prevButtonState = buttonState;

    if (ledBlinking)
    {
        digitalWrite(led, HIGH);   // включаем светодиод (HIGH - уровень напряжения)
        delay(1000);               // ждем секунду
        digitalWrite(led, LOW);    // выключаем светодиод, понижая напряжение
        delay(1000);               // ждем секунду
    }
    else
    {
        digitalWrite(led, LOW);
    }
}

Однако это приводит к очень длительному времени между последовательными проверками кнопки (поскольку между циклами существует 2-секундная задержка). Вы можете решить эту проблему с помощью функции millis:

bool prevButtonState;
bool ledBlinking;
unsigned long prevMillis;

void loop() 
{
    bool buttonState = digitalRead(buttonPin);

    if (prevButtonState && !buttonState)
    { // Нажатие края: есть переход между высоким и низким
        ledBlinking = !ledBlinking;

        prevMillis = millis() - 1000; // Принудительная проверка
    }
    prevButtonState = buttonState;

    if (ledBlinking)
    {
        if ((millis() - prevMillis) >= 1000)
        {
            prevMillis += 1000;
            digitalWrite(led, !digitalRead(led));
        }
    }
    else
    {
        digitalWrite(led, LOW);
    }
}

Далее возникает проблема устранения дребезга, но она становится ОТ. Предложение: используйте библиотеку Bounce2 для управления кнопкой, если вы испытываете отказы

попробуйте это:

if (key_pressed()) digitalWrite(LED_PIN, (digitalRead(LED_PIN)==ON)?OFF:ON);
else digitalWrite(LED_PIN, OFF);

определить ВКЛ/ВЫКЛ в зависимости от подключения светодиода.

Изменить.

Если вы хотите, чтобы кнопка также меняла режим мигания светодиода, попробуйте это.

    if (btn_pressed())                  //если обнаружен задний фронт btn
        btn_status ^= 1;                // перевернуть последний бит. btn_status += 1; работает также
    if (btn_status & 0x01) led1_flp();  //перевернуть светодиод1
    else led1_off();                    //иначе выключаем led1

    //перевернуть светодиод2
    IO_FLP(LED_PORT, LED2);

логика довольно проста: если кнопка нажата (активный низкий уровень), переключается btn_status. если btn_status равен 1, мигает светодиод 1.

в основном, нажмите кнопку, светодиод начнет мигать; нажмите кнопку второй раз, светодиод перестанет мигать;

индикатор 2 всегда мигает, чтобы показать синхронность кода.

вот оно в действии.

код написан для картинки, но в основном работает на любом микроконтроллере.