Как повторить другое действие внутри цикла?

Вам просто нужно сохранить состояние светодиодов в новой переменной ...

void loop ()
{
  if (digitalRead(buttonON)== LOW)
      ledEffectON = true;

  if (digitalRead(buttonOFF)== LOW)
      ledEffectON = false;

  if(ledEffectON)
  {
    delay(300), digitalWrite(LED1, HIGH);
    delay(50), digitalWrite(LED2, HIGH);
    delay(50), digitalWrite(LED3, HIGH);
    delay(50), digitalWrite(LED4, HIGH);
    delay(50), digitalWrite(LED5, HIGH);
    delay(300), digitalWrite(LED1, LOW);
    delay(100), digitalWrite(LED2, LOW);
    delay(100), digitalWrite(LED3, LOW);
    delay(100), digitalWrite(LED4, LOW);
    delay(100), digitalWrite(LED5, LOW);
  }
}

Используя функцию delay (), она блокирует остальную часть кода. Программе необходимо отслеживать две кнопки и обновлять световое шоу в соответствующее время, поэтому необходим неблокирующий стиль кодирования, аналогичный примеру "Мигание без задержки", где delay() заменяется таймером с использованием millis(), который периодически проверяется. Это позволяет периодически проверять и другие вещи, например, кнопки.

Кроме того, контакты кнопок, как правило, несколько раз отскакивают в течение нескольких миллисекунд, когда они меняют состояние, посылая последовательность импульсов включения/выключения в микроконтроллер, поэтому их необходимо отключить. Вы можете найти много алгоритмов дебоунсинга в Интернете, но вот простой дебоунсер, который я разместил на GitHub.

void loop ()
{
  static bool doLightshow = false;

  static Debouncer buttonOn(buttonON);
  static Debouncer buttonOff(buttonOFF);

  buttonOn.Update();
  buttonOff.Update();

  if (buttonOn.Fall())
  {
    Serial.println("buttonOn falling edge.");
    doLightshow = true;
  }
  else if (buttonOff.Fall())
  {
    Serial.println("buttonOff falling edge.");
    doLightshow = false;
  }

  if (doLightshow)
  {
    // Do lightshow.
    . . .
  }
  else
  {
    digitalWrite(LED1, LOW);
    digitalWrite(LED2, LOW);
    digitalWrite(LED3, LOW);
    digitalWrite(LED4, LOW);
    digitalWrite(LED5, LOW);
  }
}

Благодаря тому, как вы аккуратно написали свой код, вы, вероятно, сможете выделить шаблон в световом шоу.

Это хорошо подходит для создания конечного автомата, который может храниться в массиве структур:

typedef struct LightshowData
{
  unsigned int delayTime;
  byte ledPin;
  bool ledState;
};

const byte numStates = 10;

const LightshowData lightshowData[numStates] =
{
  { 300, LED1, HIGH },
  {  50, LED2, HIGH },
  {  50, LED3, HIGH },
  {  50, LED4, HIGH },
  {  50, LED5, HIGH },
  { 300, LED1, LOW },
  { 100, LED2, LOW },
  { 100, LED3, LOW },
  { 100, LED4, LOW },
  { 100, LED5, LOW }
};

Теперь конечный автомат может циклически перемещаться по массиву неблокирующим образом:

    // Do lightshow.
    static byte state = 0;
    unsigned long currentTimestamp = millis();
    static unsigned long previousTimestamp = currentTimestamp;

    if (currentTimestamp - previousTimestamp >= lightshowData[state].delayTime)
    {
      previousTimestamp += lightshowData[state].delayTime;
      digitalWrite(lightshowData[state].ledPin, lightshowData[state].ledState);
      state = ++state % numStates;
      Serial.print("state = ");
      Serial.println(state);
    }

Возможно, вам захочется сбросить состояние до 0 после отрицательного края при нажатиикнопки, в противном случае световое шоу продолжится с того места, на котором оно остановилось после остановки и перезапуска.

Вот моделирование светового шоу Wokwi с защитными резисторами 250 Ом для светодиодов.

Wokwi по умолчанию имитирует отскок кнопки, чтобы более точно моделировать реальный мир, поэтому желательно иметь некоторую форму отскока кнопки.