Как использовать Multipile millis()

Если я правильно понимаю, вы написали пример кода, который переключает Индикатор переключается между двумя состояниями (включено и выключено), и вы застреваете, потому что реальная проблема, которую вы хотите решить, более сложна, чем эта. И действительно, мне кажется, что вы хотите управлять системой с тремя возможными состояниями: она может быть включена или выключена, но когда она выключена, она может быть готова к включению, если влажность высокая, или может находиться в пятиминутном ожидании.

Самый естественный способ думать о такого рода системах - это конечный автомат, или FSM. FSM определяется набором состояний, в которых он может находиться, условиями, которые заставляют его переключать состояния, и действиями , выполняемыми при этом. Если я правильно понял вашу спецификацию, ваша система может быть либо ГОТОВОЙ, ЗАПУЩЕННОЙ, либо ОЖИДАЮЩЕЙ, а переходы следующие:

• когда ВСЕ будет ГОТОВО, если влажность слишком высока, он переключается на РЕЖИМ РАБОТЫ; при этом включается вентилятор
• при ЗАПУСКЕ, если он работает в течение 3 минут, он переключается в режим ОЖИДАНИЯ и выключает вентилятор
• при ОЖИДАНИИ, если он ждал в течение 5 минут, он переключается в режим ГОТОВНОСТИ

Это можно проиллюстрировать следующей диаграммой состояний:

Вы должны поправить меня на этом этапе, если я не до конца понял вашу спецификацию. В противном случае, если диаграмма состояний соответствует вашим требованиям, преобразовать ее в код довольно просто:

const uint32_t MINUTE = 60000;

void loop() {
    static enum {READY, RUNNING, WAITING} state;
    static uint32_t last_change;
    uint32_t now = millis();
    switch (state) {
        case READY:
            if (humidity_is_high()) {
                turn_fan_on();
                state = RUNNING;
                last_change = now;
            }
            break;
        case RUNNING:
            if (now - last_change >= 3 * MINUTE) {
                turn_fan_off();
                state = WAITING;
                last_change = now;
            }
            break;
        case WAITING:
            if (now - last_change >= 5 * MINUTE) {
                state = READY;
            }
            break;
    }
}