ПИД-регулятор Arduino для симистора

Мне нужна помощь в установлении соединения между библиотекой PID и вывод в коде

PID вычисляет значение output и используется в int dimtime = (75*output);.

Объект aaa_PID получает ссылку на переменную output с помощью &, поэтому, когда алгоритм PID устанавливает выходное значение, он устанавливает значение эту переменную в вашем скетче.

output должен быть volatile double output = 0;, потому что он используется в прерывании.

РЕДАКТИРОВАНИЕ 2:

Надеюсь, вы подключили детектор пересечения нуля к контакту 2, потому что это контакт для внешнего прерывания 0. И не используйте контакт 1 для симистора, он также подключен к USB-чипу.

ИЗМЕНИТЬ: Ваш код слишком долго остается в прерывании. Вы выходите из прерывания только через время после срабатывания симистора и следующего пересечения нуля.

В этом ответе на Arduino SE я предлагаю два скетча, демонстрирующих управление симистором. Вот один из них:

#include <TimerOne.h>

const byte INTERRUPT_PIN = 2;
const byte TRIAC_PIN = 4;
const byte TRIAC_PULSE_MICROS = 30;

const int FADE_MAX = 9800;
const int FADE_MIN = 2000;

volatile bool triacOn;
volatile int period = FADE_MIN; // микросекунды вырезаны из импульса переменного тока

int fadeAmount = 10;

void zeroCrossing() {
  triacOn = false; // симистор отключается при пересечении нуля
  Timer1.setPeriod(period); // для вызова triacPulse() после периода отключения
}

void triacPulse() {
  if (triacOn) { // остановить импульс
    digitalWrite(TRIAC_PIN, LOW);
    Timer1.stop();
  } else { // запускаем импульс
    digitalWrite(TRIAC_PIN, HIGH);
    triacOn = true;
    Timer1.setPeriod(TRIAC_PULSE_MICROS);
  }
}

void setup() {
  pinMode(TRIAC_PIN, OUTPUT);
  attachInterrupt(digitalPinToInterrupt(INTERRUPT_PIN), zeroCrossing, RISING);
  Timer1.initialize();
  Timer1.attachInterrupt(triacPulse);
}

void loop() {
  period = period + fadeAmount;
  if (period <= FADE_MIN || period >= FADE_MAX) {
    fadeAmount = -fadeAmount;
  }
  delay(25);
}

другой использует прямой доступ к регистрам AVR.

РЕДАКТИРОВАТЬ 3: выходной сигнал осциллографа микрофона на скетче выше: https://www.youtube.com/watch?v= dnfy_EsPlVI

РЕДАКТИРОВАТЬ 4: ПИД-регулятор выдает высокие значения для высокой мощности и малые значения для меньшей мощности. но период симистора - время выключения. поэтому период должен быть примерно таким: period = 11000 - (75 * output)

вот входные и выходные значения кода микрофона, основанные на этом ответе (синий — температура, красный — выходной период симистора):

ПИД-регулятор со временем становится более плавным по мере точной настройки его параметров, но я думаю, что простой PID имеет некоторые проблемы с синусоидальной зависимостью между выходной мощностью (временем) и результирующей мощностью нагрева.

Я вижу здесь несколько проблем.

Самая серьезная проблема связана с проводкой Arduino. Первый аргумент attachInterrupt() — это номер прерывания. На Uno «прерывание 0» подключен к контакту «цифровой 2». Здесь следует подключить выход детектора пересечения нуля (ZERO_OUT).

Затем, как заметил Юрай, возникает проблема с обработчиком прерываний. слишком долго выполняется. Обычно это считается плохой практикой, и это имеет некоторые негативные последствия для работы ядра Arduino. например, функция millis() будет полностью отключена. я не делаю думаю, однако, что это серьезная проблема для вас. Есть один единственный критичный по времени бит в вашей программе, который является генерацией триггерные импульсы. Вы действительно не заботитесь о millis() или любом другом другие вещи, связанные со временем. Таким образом, по крайней мере, для начальной версии программа, мне было бы все равно, а просто пусть обработчик прерывания задержка по мере необходимости.

Третья проблема была отмечена chrisl в комментарии: есть гонка состояние, при котором и основная программа, и обработчик прерывания обращаются к ту же переменную output. Условия гонки - неприятный вид ошибки потому что обычно все работает нормально «большую часть времени», а затем выходит из строя в какой-то момент. неожиданные времена. Я бы не рекомендовал, однако, запускать myPID.Compute() с отключенными прерываниями: это может синхронизация импульсов симистора. Вместо этого вычислите задержку, требуемую прерывание, сохраните его во временную переменную, затем скопируйте в переменную совместно с обработчиком. Только копирование нужно делать с прерываниями отключено, и это занимает всего несколько циклов процессора:

// Переменная, используемая zero_crosss_int().
// Не забывайте о квалификаторе volatile.
volatile int dimtime;

void loop() {
    // PID и связанные с ним вычисления.
    set_value = map(analogRead(A1), 0, 1023, 150, 400);
    input = map(analogRead(A0), 0, 550, 25, 400);
    aaa_PID.Compute();
    int tmp_dim_time = 75*output;

    // Критическая секция выполняется с отключенными прерываниями.
    noInterrupts();
    dimtime = tmp_dim_time;
    interrupts();
}

Обновление: если что-то не работает, попробуйте отладить по частям. Отправка отладочных сообщений на последовательный порт должна помочь, хотя серийный общение, вероятно, будет значительно замедлено из-за долго работающий обработчик прерываний. Как вариант можно использовать симистор контрольные импульсы в качестве средства отладки, возможно, при отключенном нагревательном элементе. Например:

• В loop() задайте для dimtime значение, пропорциональное set_value. Поверните потенциометр и посмотрите на сигнал FIRING_PULSE. Есть ли пульс ширина меняется пропорционально положению горшка? Синхронно ли это с V_в пересечениях нуля?

• Установите dimtime пропорционально input. Нагрейте термопару на некоторое время. внешние средства. FIRING_PULSE отличается от ожидаемого?

• Установите dimtime пропорционально выходной мощности, но оставьте нагревательный элемент отключен. Как меняется пульс, когда вы двигаете кастрюлю или нагреваете термопара?