Управление регулятором вентилятора от Arduino

Для управления мощностью переменного тока индуктивной нагрузки (двигателя) используется симистор. Эта концепция называется фазовой резкой. Он работает и для резистивной нагрузки (нагревателя).

Этот модуль предназначен для фазовой резки. Он содержит детектор пересечения нуля и симистор. Управление осуществляется в микроконтроллере. Детектор пересечения нуля подключен к контакту прерывания. Управляющий сигнал симистора подключается к выходному контакту. В функции внешнего прерывания вы устанавливаете прерывание таймера для отправки импульса на симистор через несколько микросекунд. Более длительное время выключения приводит к снижению мощности двигателя.

При переменном токе 50 Гц один импульс составляет 10 миллисекунд. Чтобы отключить часть волны переменного тока, активируйте симисторный затвор на 20 микросекунд через 0-10 миллисекунд. Симистор самостоятельно отключает линию переменного тока при следующем пересечении нуля.

Robotdyn имеет библиотеку для этого модуля.

ПРАВКА:

Я купил модуль диммера переменного тока Robotdyn, чтобы использовать его в своем проекте регулирования нагревателя переменного тока, и протестировал его с помощью лампы накаливания и вентилятора. (видео на YouTube)

Библиотека Robotdyn работает, но она предназначена для управления многими диммерами и использует прерывание таймера каждые 12 микросекунд (да, микро). Библиотека устанавливает прерывания над регистрами MCU.

Я написал скетч arduino fade-in/out, используя библиотеку TimerOne, чтобы продемонстрировать фазовую резку с помощью этого модуля.

#include <TimerOne.h>

const byte INTERRUPT_PIN = 2;
const byte TRIAC_PIN = 4;
const byte TRIAC_PULSE_MICROS = 30;

const int FADE_MAX = 9800;
const int FADE_MIN = 2000;

volatile bool triacOn;
volatile int period = FADE_MIN; // микросекунды, вырезанные из импульса переменного тока

int fadeAmount = 10;

void zeroCrossing() {
  triacOn = false; // симистор отключает себя при пересечении нуля
  Timer1.setPeriod(period); // вызвать triacPulse() после периода выключения
}

void triacPulse() {
  if (triacOn) { // стоп-импульс
    digitalWrite(TRIAC_PIN, LOW);
    Timer1.stop();
  } else { // пусковой импульс
    digitalWrite(TRIAC_PIN, HIGH);
    triacOn = true;
    Timer1.setPeriod(TRIAC_PULSE_MICROS);
  }
}

void setup() {
  pinMode(TRIAC_PIN, OUTPUT);
  attachInterrupt(digitalPinToInterrupt(INTERRUPT_PIN), zeroCrossing, RISING);
  Timer1.initialize();
  Timer1.attachInterrupt(triacPulse);
}

void loop() {
  period = period + fadeAmount;
  if (period <= FADE_MIN || period >= FADE_MAX) {
    fadeAmount = -fadeAmount;
  }
  delay(25);
}

EDIT 2 версия с симистором, активированным выводом "pwm"

const byte TRIAC_PIN = 9;
const byte ZC_EI_PIN = 2;

unsigned long topMicroseconds = 9700; // 10000 микросекунд находится между пересечениями нуля
int prescaler = 8;
byte prescalerBits = _BV(CS11); // 8

void zeroCrossing() {
  TCNT1 = 0; // сброс счетчика таймера
}

void setup() {
  Serial.begin(115200);
  Serial.println("START");

  attachInterrupt(digitalPinToInterrupt(ZC_EI_PIN), zeroCrossing, RISING);

  pinMode(TRIAC_PIN, OUTPUT);
  uint32_t topPeriod = ((F_CPU / 1000000)* topMicroseconds) / prescaler ;
  ICR1 = topPeriod;
  OCR1A = topPeriod + 1; // полностью выкл.
  // WGM mode 14 - Fast PWM w/TOP=ICR1 
  TCCR1A = _BV(WGM11) | _BV(COM1A0) | _BV(COM1A1);
  TCCR1B = _BV(WGM13) | _BV(WGM12) | prescalerBits;
}

void loop() {
  if (Serial.available()) {
    unsigned long microseconds = Serial.parseInt();
    Serial.find("\n");
    uint32_t period = ((F_CPU / 1000000)* microseconds) / prescaler ;
    OCR1A = period;
  }
}

на SAMD можно настроить это для запуска таймера при внешнем прерывании по событию, без функции прерывания. тогда центральный процессор MCU не участвует в фазовой резке после первоначальной настройки периферийных устройств

ПРАВКА 3:

Библиотека TriacDimmer версии 1.1.0 для AVR ардуино, доступная в Library Manager, хорошо работает с этим диммером. Забавный факт: он использует входной захват timer1 на выводе 8 вместо внешнего прерывания на выводе 2 или 3.