Во-первых, вам нужно решить, хотите ли вы отправлять данные как необработанные байты («двоичные данные») или в виде текстового представления ASCII. Бинарный имеет тенденцию быть более эффективным: вы можете отправить float с полной точностью всего в четыре байта, тогда как обычно требуется от 8 до 9 значащих цифры для восстановления полной точности из представления ASCII. Однако с двоичным кодом сложнее работать: некоторые типы имеют разные двоичные значения. представления на вашем Arduino и вашем ПК, и вам может потребоваться определить своего рода протокол, чтобы получить правильное оформление. ASCII проще, и обычно вы можете использовать конец строки как простое устройство кадрирования. я обычно рекомендуется использовать ASCII, если вам действительно не нужны дополнительные эффективность бинарного протокола.

Отправка в виде двоичного файла

Вы можете легко отправлять произвольные двоичные данные, используя метод write(const uint8_t *buffer, size_t size) из объекта Serial:

Gyro_data_structure Gyro_data = {"Gyro", 0.0, 4.0, 5.0};

void loop() {
    Gyro_data.gyro_X++;
    Serial.write((uint8_t *) &Gyro_data, sizeof Gyro_data);
    delay(200);
}

Вот шестнадцатеричный дамп вывода:

0000  47 79 72 6f 00 00 00 80  3f 00 00 80 40 00 00 a0  |Gyro....?...@...|
0010  40 47 79 72 6f 00 00 00  00 40 00 00 80 40 00 00  |@Gyro....@...@..|
[...]

который можно разобрать следующим образом:

47 79 72 6f 00 = {'G', 'y', 'r', 'o', '\0'}
00 00 80 3f    = 0x3f800000 = 1.0f
00 00 80 40    = 0x40800000 = 4.0f
00 00 a0 40    = 0x40a00000 = 5.0f

Обратите внимание, что числа с плавающей запятой отправляются с прямым порядком байтов: чтобы байт первый. Приведенные выше 32-битные шестнадцатеричные числа являются двоичными представлениями float.

Отправка как текст

Serial.print() предназначен для печати текстового представления данных. вы даете это. Но так как он не умеет представлять Gyro_data_structure, вы должны Serial.print() каждый член данных в поверните, а затем добавьте форматирование вокруг всего этого:

void print_gyro(const Gyro_data_structure &gyro) {
    Serial.print(F("Gyro{command = \""));
    Serial.print(gyro.command_name);
    Serial.print(F("\", X = "));
    Serial.print(gyro.gyro_X);
    Serial.print(F(", Y = "));
    Serial.print(gyro.gyro_Y);
    Serial.print(F(", Z = "));
    Serial.print(gyro.gyro_Z);
    Serial.print(F("}"));
}

void loop() {
    Gyro_data.gyro_X++;
    print_gyro(Gyro_data);
    Serial.println();
    delay(200);
}

Вывод

Gyro{command = "Gyro", X = 1.00, Y = 4.00, Z = 5.00}
Gyro{command = "Gyro", X = 2.00, Y = 4.00, Z = 5.00}
[...]

Подготовка данных для печати

Это разновидность предыдущей техники. Вы можете Serial.print() ваш объект напрямую, если вы сообщите ядру Arduino, как напечатать это тип объектов. Это делается путем предоставления вашему классу наследования от Printable и реализации виртуального метода printTo(). Но потом класс больше не является «агрегатом» и, следовательно, нуждается в явном конструктор:

struct Gyro_data_structure : Printable
{
    char command_name[5];
    float gyro_X;
    float gyro_Y;
    float gyro_Z;
    Gyro_data_structure(const char *name, float x, float y, float z)
    : gyro_X(x), gyro_Y(y), gyro_Z(z) {
        strncpy(command_name, name, 4);
        command_name[4] = '\0';
    }
    size_t printTo(Print& p) const {
        size_t count = 0;
        count += p.print(F("Gyro{command = \""));
        count += p.print(command_name);
        count += p.print(F("\", X = "));
        count += p.print(gyro_X);
        count += p.print(F(", Y = "));
        count += p.print(gyro_Y);
        count += p.print(F(", Z = "));
        count += p.print(gyro_Z);
        count += p.print(F("}"));
        return count;
    }
};

Gyro_data_structure Gyro_data("Gyro", 0.0, 5.0, 5.0);

void loop() {
    Gyro_data.gyro_X++;
    Serial.println(Gyro_data);
    delay(200);
}

Вывод идентичен предыдущему. Определение класса получает немного корявее, но зато можно очень легко печатать на любой сериал порт (будь то UART или программная реализация), на LCD... или все, что понимает print().