Поворотный энкодер KY-040 пропускает шаги

Я аплодирую вам за упорство в идее "устранения дребезга", но для этого поворотного энкодера существует отличная библиотека, и автор также написал о ней статью: Бен Бакстон - поворотные энкодеры сделаны правильно. Вот ссылка на его библиотеку: GitHub - buxtronix.

Я уже использовал более старую версию библиотеки с прерываниями, и она отлично работала для моего приложения. Вижу автор обновил библиотеку и есть 2 примера скетча; один использует прерывания, а другой использует опрос. Я попробовал оба из них сегодня на Uno, и я был очень впечатлен производительностью скетча опроса. Казалось, что это эквивалентно методу прерывания.

Если вы удалите важные биты из файлов библиотеки, а затем добавите их в скетч, вы увидите, как мало кода требуется для этого «метода» обработки вывода кодировщика. Вот тестовый скетч с битами библиотеки.

#define R_START 0x0
#define R_CW_FINAL 0x1
#define R_CW_BEGIN 0x2
#define R_CW_NEXT 0x3
#define R_CCW_BEGIN 0x4
#define R_CCW_FINAL 0x5
#define R_CCW_NEXT 0x6
#define DIR_NONE 0x0
#define DIR_CW 0x10
#define DIR_CCW 0x20

const byte pin1 = 5;  // DT
const byte pin2 = 6;  // CLK
int state = R_START;
int counter = 0;

const unsigned char ttable[7][4] = {
  // R_START
  {R_START,    R_CW_BEGIN,  R_CCW_BEGIN, R_START},
  // R_CW_FINAL
  {R_CW_NEXT,  R_START,     R_CW_FINAL,  R_START | DIR_CW},
  // R_CW_BEGIN
  {R_CW_NEXT,  R_CW_BEGIN,  R_START,     R_START},
  // R_CW_NEXT
  {R_CW_NEXT,  R_CW_BEGIN,  R_CW_FINAL,  R_START},
  // R_CCW_BEGIN
  {R_CCW_NEXT, R_START,     R_CCW_BEGIN, R_START},
  // R_CCW_FINAL
  {R_CCW_NEXT, R_CCW_FINAL, R_START,     R_START | DIR_CCW},
  // R_CCW_NEXT
  {R_CCW_NEXT, R_CCW_FINAL, R_CCW_BEGIN, R_START},
};

unsigned char process(){

  // Grab state of input pins.
  unsigned char pinstate = (digitalRead(pin2) << 1) | digitalRead(pin1);

  // Determine new state from the pins and state table.
  state = ttable[state & 0xf][pinstate];

  // Return emit bits, ie the generated event.
  return state & 0x30;
}

void setup(){
  pinMode(pin1, INPUT_PULLUP);
  pinMode(pin2, INPUT_PULLUP);
  Serial.begin(9600);
}

void loop(){
  unsigned char result = process();
  if(result == DIR_CW){
    counter++;
    Serial.println(counter);
  }
  else if(result == DIR_CCW){
    counter--;
    Serial.println(counter);
  }
}

Вот упрощенный скетч (он работает так же, но мне не нравятся шестнадцатеричные числа, и я не использую определение):

const byte pin1 = 5;  // Подключен к DT на KY-040
const byte pin2 = 6;  // Подключен к CLK на KY-040
int state = 0;
int counter = 0;

const unsigned char ttable[7][4] = {
  {0, 2, 4, 0},
  {3, 0, 1, 0 | 16},
  {3, 2, 0, 0},
  {3, 2, 1, 0},
  {6, 0, 4, 0},
  {6, 5, 0, 0 | 32},
  {6, 5, 4, 0},
};

void setup(){
  pinMode(pin1, INPUT_PULLUP);
  pinMode(pin2, INPUT_PULLUP);
  Serial.begin(9600);
}

void loop(){

  unsigned char result = process();

  // Вращение по часовой стрелке.
  if(result == 16){
    counter++;
    Serial.println(counter);
  }

  // Вращение против часовой стрелки.
  else if(result == 32){
    counter--;
    Serial.println(counter);
  }

}

unsigned char process(){

  // Захват состояния входных контактов.
  unsigned char pinstate = (digitalRead(pin2) << 1) | digitalRead(pin1);

  // Определяем новое состояние из пинов и таблицы состояний.
  state = ttable[state & 0xf][pinstate];

  // Возвращаем испускаемые биты, т.е. сгенерированное событие.
  return state & 48;
}