Возникли проблемы с массивом

В блоке if (a <= 10) вы находитесь внутри цикла for, который уменьшается и заменяет каждое значение значением внутри index+1. Это означает, что, спускаясь по индексам, вы несете с собой 11-е значение индекса. Вот как это происходит без переменных (позвольте мне сократить имя переменной до t):

t[10] = t[11];
t[9] = t[10];
t[8] = t[9];

И так далее. Все, что было в a[11], перетаскивается через каждую из переменных нижних индексов.

Я настоятельно рекомендую пойти наоборот: либо с вашим циклом, либо с тем, каким образом вы передаете данные. Например (продолжая имя массива t):

for (int i = 11; i >=0; i--) {
    if (i > 0)
        t[i] = t[i-1]; // сдвигаем данные с индекса 10->11, 9->10 и т.д.
}
t[0] = arbitrary_data; // заполняем новое «пустое» пространство

Или, если вы все еще хотите поместить новые данные в индекс 11:

for (int i = 0; i <= 11; i++) {
    if (i < 11)
        t[i] = t[i+1]; // сдвигаем данные с индекса 1->0, 2->1 и т.д.
}
t[i] = arbitrary_data; // заполняем новое «пустое» пространство

Это мое решение для вашего текущего метода управления данными. В другом ответе предлагался кольцевой буфер, в котором вы просто отслеживаете, какие данные изменяются за раз, и это гораздо более эффективно.

Ваша проблема связана с программированием на языке C и не имеет никакого отношения конкретно к Arduino. Вам следует изучить, как реализовать циклический буфер. Вы не хотите перемещать значения внутри массива, а просто увеличиваете значения индекса массива. Сохраните два значения индекса: одно из текущей позиции индекса (место, где будет размещено следующее записанное значение), а другое из числа записанных значений. В конечном итоге количество записанных значений будет равно максимальному размеру массива, и будет увеличиваться только позиция индекса. Когда индекс массива превышает максимальный размер массива, он возвращается к 0.

Чтобы расширить ответ Джеффа Вахауса, быстрый поиск в Google выявляет несколько библиотек кольцевых буферов для Arduino. Я скачал первый в списке, github rlogiacco CircularBuffer, и сделал простой эскиз, чтобы проверить некоторые его функции.

#include <CircularBuffer.h>

CircularBuffer<unsigned int, 12> buffer;

byte counter = 0;

void setup(){
  Serial.begin(9600);
}

void loop(){

  // Добавляем следующее чтение в «голову» буфера.
  buffer.unshift(counter);

  // Моделирование данных датчиков.
  counter += 10;
  if(counter > 254){counter = 1;}

  // Неразрушающее чтение. Дает вам последнее сохраненное показание.
  if(!buffer.isEmpty()){
    Serial.println(buffer.first());
  }

  delay(500);
}

Используя функцию unshift(), вы можете многократно добавлять данные в начало буфера, и он автоматически «забудет» последний элемент в буфере, как только он заполнится. Я использую функцию first(), чтобы увидеть, что находится в первой ячейке буфера (последнее чтение). Если вы хотите получить все сохраненные показания, вы можете использовать функцию shift() и перебирать элементы в буфере, пока он не станет пустым. В эту библиотеку включено множество функций для взаимодействия с буфером, например, isEmpty(), isFull(), size() , available(), capacity(), clear().

ИЗМЕНИТЬ

Вы также можете использовать массив для хранения показаний. Взгляните на результат этого эскиза.

byte arrayIndex = 0;
const byte arraySize = 12;
float temperature_c_minute_avg[arraySize] = {0.0};

// Имитация данных датчика.
float counter = 10.0;

void setup(){
  Serial.begin(9600);
}

void loop(){

  // Добавляем чтение в массив.
  temperature_c_minute_avg[arrayIndex] = counter;

  // Тестовый вывод: распечатываем содержимое массива.
  Serial.print("Array index = ");
  Serial.println(arrayIndex);
  for(byte i = 0; i < arraySize; i++){
    Serial.print("temperature_c_minute_avg[");
    Serial.print(i);
    Serial.print("] = ");
    Serial.println(temperature_c_minute_avg[i]);
  }
  Serial.println();

  // Обновляем индекс массива.
  arrayIndex++;
  if(arrayIndex > (arraySize - 1)){arrayIndex = 0;}

  // Имитация данных датчика.
  counter += 10.0;
  if(counter > 2400.0){counter = 0.0;}
  delay(1000);

}

Сразу после добавления показания в массив оно становится «последним показанием». Его индекс будет temperature_c_mine_avg[arrayIndex], пока вы не обновите индекс массива в конце loop(). Чтобы получить все показания из массива, вы можете использовать цикл for, который выполняется 12 раз, как указано в переменной arraySize, и начинается с arrayIndex. Вы можете уменьшить arrayIndex в цикле for. Имейте в виду, что вы не можете использовать отрицательные числа для доступа к индексу массива, поэтому вам придется сбросить индекс в цикле for до arraySize - 1, прежде чем он станет отрицательным.