Сокращение времени считывания показаний датчиков температуры DS18B20.

Выполнять поиск каждый раз довольно неэффективно. Функция поиска нужна, если вы не знаете адрес устройства, и это занимает некоторое время. В вашем случае, по-видимому, адреса никогда не изменятся. Найдите адреса и жестко закодируйте их в свой код. Или, если это нецелесообразно, сохраните их в EEPROM. А если даже это нецелесообразно, найдите адреса один раз в настройках.

Далее вам нужна задержка, пока вы снимаете показания температуры. Почему бы не сделать их параллельными? В цикле скажите всем устройствам снять показания. Затем подождите одну секунду. Затем прочитайте их все (в другом цикле). Таким образом, задержка в одну секунду распределяется между всеми вашими датчиками.

Однако на странице, на которую ссылается Гербен:

Нельзя использовать датчики DS1820 с простым подтягивающим резистором. Во время фазы «Конверсия» ему требуется больше энергии. И есть Application Note, в котором это подробно обсуждается.

Это говорит о том, что если вы используете паразитную мощность, мое предложение не будет работать слишком хорошо (если несколько устройств считывают показания, это ухудшит ситуацию).

Я нашел этот код на своем диске пару лет назад. Задержек между датчиками считывания вроде бы нет. В конце основного цикла есть задержка, в основном для того, чтобы остановить спам на последовательном мониторе.

Обратите внимание на комментарий:

Вызвать sensor.requestTemperatures(), чтобы отправить запрос глобальной температуры всем устройствам на шине

Посмотрите, подходит ли это вам.

#include <OneWire.h>
#include <DallasTemperature.h>
#include <Streaming.h>

// Провод данных подключен к порту 10 на Arduino
const byte ONE_WIRE_BUS = 10;
const byte TEMPERATURE_PRECISION = 10;
// Настройте экземпляр oneWire для связи с любыми устройствами OneWire (не только с микросхемами температуры Maxim/Dallas)
OneWire oneWire(ONE_WIRE_BUS);

// Передаем нашу ссылку oneWire в Dallas Temperature.
DallasTemperature sensors(&oneWire);

// массивы для хранения адресов устройств
DeviceAddress myThermometer [10];
int deviceCount;

void setup(void)
{

  // запускаем последовательный порт
  Serial.begin (115200);
  Serial << "Dallas Temperature IC Control Library Demo" << endl;

  // Запускаем библиотеку
  sensors.begin();

  // найти устройства на шине
  Serial << "Locating devices..." << endl;
  deviceCount = sensors.getDeviceCount();

  Serial << "Found " << deviceCount << " devices." << endl;

  // сообщаем о требованиях к питанию паразита
  Serial << "Parasite power is: " << (sensors.isParasitePowerMode() ? "ON" : "OFF") << endl; 

  // метод 1: по индексу

  for (int i = 0; i < deviceCount; i++)
  {
    if (sensors.getAddress(myThermometer [i], i))
    { 
      Serial << "Device " << i << " Address: ";
      printAddress(myThermometer [i]);
      Serial << endl;
      sensors.setResolution(myThermometer [i], TEMPERATURE_PRECISION);
    }
    else
      Serial << "Unable to find address for Device " << i << endl;
  }  // конец цикла

}

// функция для вывода адреса устройства
void printAddress(DeviceAddress deviceAddress)
{
  for (uint8_t i = 0; i < 8; i++)
  {
    // дополнить адрес нулями, если необходимо
    if (deviceAddress[i] < 16) Serial.print("0");
    Serial.print(deviceAddress[i], HEX);
  }
}


void loop(void)
{ 

  // вызов Sensors.requestTemperatures() для выдачи глобальной температуры
  // запрос ко всем устройствам на шине
  sensors.requestTemperatures();

  // теперь получаем все температуры
  for (int i = 0; i < deviceCount; i++)
  {
    float tempC = sensors.getTempC(myThermometer [i]);
    if (tempC > -80)
    { 
      Serial << "Device " << i << " Temperature: " << tempC << endl;
    }
    else
      Serial << "Unable to find temperature for Device " << i << endl;
  }  // конец цикла

  delay (1000);
}

В случае, если "Время преобразования температуры (tCONV)" каждого разрешения недостаточно быстро ([MAX] 9-бит: 93,75 мс; 10-бит: 187,5 мс; 11-бит: 375 мс; 12-бит: 750 мс), вы можете использовать больше датчиков.

Например, чтобы получить время полураспада (для 9-битного): 47 мс:

• Вы можете использовать два датчика в одной и той же точке измерения (они могут работать параллельно, если программное обеспечение может работать с каждым из них). При считывании данных с одного программа начинает преобразовывать другой.

Каждый из них имеет свое нормальное время преобразования, но при выполнении показаний с чередованием можно получить более короткое время чтения.

Для 8 датчиков можно достичь времени менее 11,75 мс (для 9 бит).