PinChange прерывает проблему с весами DRO

Функция Arduino attachInterrupt() работает только с так называемыми «внешние прерывания», которые в Nano доступны только контакты 2 и 3. Для любого другого контакта, digitalPinToInterrupt() возвращает константу NOT_AN_INTERRUPT (-1) и attachInterrupt() ничего не делает. Если вы хотите работать с прерываниями по изменению контактов, вам нужно нужно либо найти библиотеку, которая предоставляет им хороший API, либо сделать это низкоуровневый, установив себе регистры управления оборудованием и определение настоящего ISR.

Поскольку вы устанавливаете и PCICR, и PCMSK2, вы следуете Низкоуровневый подход, и вы почти у цели. Единственное, чего не хватает, определяет ISR, который действительно делает что-то полезное. Возможно, просто это:

ISR(PCINT2_vect) { trig(); }

Пока вы этим заняты, удалите два нерелевантных вызова attachInterrupt(). Кроме того, я бы не стал читать обе шкалы каждый раз. одна шкала посылает импульс: вам нужно прочитать только одну шкалу, которая дала пульс. Таким образом, можно разделить trig() на одну функцию для каждой шкалы, затем в setup():

attachInterrupt(digitalPinToInterrupt(pinA), trig_scale_1, CHANGE);
attachInterrupt(digitalPinToInterrupt(pinB), trig_scale_1, CHANGE);

И тогда ISR будет:

ISR(PCINT2_vect) { trig_scale_2(); }

Это должно сэкономить вам довольно много циклов в контексте прерывания, и таким образом уменьшить задержку прерывания и сделать всю программу более надежной.

Спасибо всем.

У меня есть решение с форума Arduino.

Я выложу код на Github, чтобы все могли его увидеть и поделиться.

/*
  Pins require interrupts to read scale value. Scale is incremental only.
  pinA, pinB are for dro scale 1
  pinC, pinD1 are for dro scale 2

  D2 = pinA - Hardware Interrupt - Scale 1 clk
  D3 = pinB - Hardware Interrupt - scale 1 data
  D4 = pinC - Pinchange Interrupt - scale 2 clk
  D5 = pinD -Pinchange Interrupt - scale 2 data
*/
#include <avr/interrupt.h>
const int pinA = 2, pinB = 3, phaseLookup1[] = {0, -1, 1, -1, 1, 0, -1, -1, -1, 1, 0, 1, 1, 1, -1, 0};
const int pinC = 4, pinD = 5, phaseLookup2[] = {0, -1, 1, -1, 1, 0, -1, -1, -1, 1, 0, 1, 1, 1, -1, 0}; // seperate lookup tables for each scale

volatile bool A = false, B = false, C = false, D = false, updated = false;
volatile int scale1 = 0, phase1 = 0, scale2 = 0, phase2 = 0;


void setup()
{
  Serial.begin(9600);
  Serial.println("T.I.S.M"); // Google it
  pinMode(pinA, INPUT);
  pinMode(pinB, INPUT);
  pinMode(pinC, INPUT);
  pinMode(pinD, INPUT);
  cli();
  PCICR |= B00000100;// Enable PCIE2 Bit3 = 1 (Port D)
  PCMSK2 |= B00111100;// Enable PCINT20  & PCINT21 (Pins D4 & D5) + D2 + D3

  sei();
}

void loop() {
  if (updated)
  {
    Serial.println(String(scale1*2));
    Serial.println(String(scale2*2));
    updated = false;
  }
}

ISR (PCINT2_vect)
{
  static byte oldState = 0;
  byte newState = PIND & B111100;
  if (newState != oldState) {
    A = (newState & 1 << pinA) > 0; //Scale 1
    B = (newState & 1 << pinB) > 0; //  "
    C = (newState & 1 << pinC) > 0; // Scale 2
    D = (newState & 1 << pinD) > 0; // "
    if ((newState & B1100) != (oldState & B1100)) {
      phase1 <<= 1;//Scale 1
      phase1 |= A;
      phase1 <<= 1;
      phase1 |= B;
      phase1 &= 0xF;
      scale1 += phaseLookup1[phase1];
    }
    if ((newState & B110000) != (oldState & B110000)) {
      phase2 <<= 1;//Scale 2
      phase2 |= C;
      phase2 <<= 1;
      phase2 |= D;
      phase2 &= 0xF;
      scale2 += phaseLookup2[phase2];
    }
    updated = true;
  }
}