Как EEMEM отображает переменные? (avr/eeprom.h)

Я бы не стал полагаться на то, что компилятор обязательно разместит переменные по какому-либо конкретному адресу памяти, особенно после того, что вы опубликовали. Вы можете создать небольшой включаемый файл, который упростит чтение/запись в EEPROM, как показано ниже:

#include <Arduino.h>  // for type definitions
#include <EEPROM.h>

template <typename T> unsigned int EEPROM_writeAnything (int ee, const T& value)
{
    const byte* p = (const byte*)&value;
    unsigned int i;
    for (i = 0; i < sizeof(value); i++)
        EEPROM.write(ee++, *p++);
    return i;
}

template <typename T> unsigned int EEPROM_readAnything (int ee, T& value)
{
    byte* p = (byte*)&value;
    unsigned int i;
    for (i = 0; i < sizeof(value); i++)
        *p++ = EEPROM.read(ee++);
    return i;
}

Тогда вы можете сделать что-то вроде этого:

int someData;  // объявляем локальную переменную


...


EEPROM_readAnything (0, someData);  // считываем с нулевого адреса в EEPROM

...

someData++;
EEPROM_writeAnything (0, someData);  // записываем его обратно по нулевому адресу

Приведенная выше библиотека использует шаблоны для управления данными любого размера, поэтому вы можете записывать или писать целые числа, массивы и т. д. Один из вариантов — создать структуру и каждый раз читать/записывать все целиком. Таким образом, вам не нужно отслеживать смещения (вся структура может быть записана по адресу 0).

Вот пример использования offsetof для управления смещениями отдельных полей внутри вашей общей структуры, которая хранится в EEPROM.

#include <EEPROMAnything.h>

const long MAGIC_ID = 'Nick';

// информация в EEPROM
typedef struct {
    unsigned long magic;   // чтобы проверить, инициализировали ли мы EEPROM
    unsigned long counter;
    char myName [30];
}  myInformation;


void setup() {
  Serial.begin (115200);
  Serial.println ("Starting ...");

  // проверяем, инициализирована ли EEPROM

  unsigned long magicTest;
  EEPROM_readAnything (offsetof (myInformation, magic), magicTest);

  if (magicTest != MAGIC_ID)
    {
    Serial.println ("Initialising EEPROM");
    myInformation initStuff;
    initStuff.magic = MAGIC_ID;
    initStuff.counter = 0;
    strcpy (initStuff.myName, "Nick Gammon");
    EEPROM_writeAnything (0, initStuff); // пишем всю структуру
    } // конец, если не инициализировано


  // находим счетчик
  unsigned long myCounter;
  EEPROM_readAnything (offsetof (myInformation, counter), myCounter);
  Serial.print ("Counter is ");
  Serial.println (myCounter);

  // находим имя
  char hisName [sizeof (myInformation().myName)];
  EEPROM_readAnything (offsetof (myInformation, myName), hisName);
  Serial.print ("Name is ");
  Serial.println (hisName);

  // добавляем в счетчик
  myCounter++;

  // записываем счетчик обратно
  EEPROM_writeAnything (offsetof (myInformation, counter), myCounter); // пишем всю структуру

  Serial.println ("Done.");
  
} // конец настройки

void loop() 
{
  // что бы ни
}   // конец цикла