Как запомнить значения переменных после перезагрузки платы Arduino Uno R3

Сохраните их во встроенной EEPROM.

• http://www.arduino.cc/en/Reference/EEPROM
• http://www.arduino.cc/en/Tutorial/EEPROMWrite
• http://www.arduino.cc/en/Tutorial/EEPROMRead

Внутренняя оперативная память Arduino будет сброшена при повторном включении чипа, поэтому, если вы хотите сохранить свои данные, вам необходимо сохранить их в EEPROM.

Если вас беспокоит ограниченность циклов записи/стирания, вам следует оценить, как часто данные будут обновляться (т. е. записываться в EEPROM) и как долго вы планируете срок службы создаваемого вами устройства. Если 100 000 циклов по-прежнему являются проблемой, у вас есть несколько вариантов:

• Храните переменные в ОЗУ и записывайте их в EEPROM, скажем, каждые 5 минут (тогда 100 000 циклов составляют примерно один год непрерывного использования, пока EEPROM может выйти из строя).
• Используйте внешнюю EEPROM (в гнезде), которую можно легко заменить при необходимости.
• Если заменить его невозможно, рассмотрите возможность использования вместо него FRAM (преимущество по сравнению с EEPROM: много больше циклов стирания/записи, но и очень дорого, поэтому не подходит для больших объемов данных, но определенно для нескольких переменных).

Однако обратите внимание, что ваше описание похоже на типичный вариант использования пользовательских настроек, которые вы не хотите потерять при перезагрузке. Для них внутренняя EEPROM — подходящее место: храните их только тогда, когда они изменены, и вы в безопасности — пользователь не будет легко менять их 100 000 раз...

Пространство EEPROM, как уже упоминалось, будет работать, если требуется энергонезависимость. Однако вы не знаете, должен ли он быть энергонезависимым или нет. Если нет, то вы можете использовать __attribute__, чтобы определить пространство переменных, которое не будет инициализироваться. Поскольку SRAM на ATmega не очищается при перезагрузке или выключении питания. Компилятор по умолчанию инициализирует их. Где это можно отключить для каждой переменной, как в примере ниже:

//неинициализированное значение
union configUnion{
  uint8_t    byte[6]; // соответствие приведенной ниже структуре...
  struct {
    uint16_t value1;
    uint16_t value2;
    uint16_t chksum;
  } val ;
} config  __attribute__ ((section (".noinit")));

void setup() {
  uint16_t sum; 
  //Инициализируем последовательный порт и ждем открытия порта:
  Serial.begin(9600);
  while (!Serial) {
    ; // ждем подключения последовательного порта. Требуется только для Леонардо.
  }

  // печатает заголовок с конечным переносом строки
  Serial.print("Out of Reset -");
  sum = getchksum();
  printValues();

  if (sum != config.val.chksum) {
    config.val.chksum = sum;
    Serial.print("chksum is incorrect setting config.val.chksum = 0x"); Serial.println(config.val.chksum, HEX);
  }

  config.val.value1++;
  config.val.value2++;
  Serial.print("setup new values - ");
  printValues();
  config.val.chksum = getchksum();
  Serial.print("updating chksum config.val.chksum = 0x"); Serial.println(config.val.chksum, HEX);
}

int counter = 0;

void loop() {
  if (counter < 200) {
    Serial.print("after a while - ");
    printValues();
    Serial.println();
    while (true) {
      continue;
    }
  }
  counter++;
}

void printValues() {
  Serial.print(" value1 = 0x"); Serial.print(config.val.value1, HEX);
  Serial.print(", value2 = 0x"); Serial.print(config.val.value2, HEX);
  Serial.print(", sum = 0x"); Serial.print(getchksum(), HEX);
  Serial.print(", chksum = 0x"); Serial.println(config.val.chksum, HEX);
}

uint16_t getchksum() {
  int sum = 0;
  for (int position = 0; position < (sizeof(config) - sizeof(config.val.chksum)); position++) {
    sum = sum + config.byte[position];
  }
  return sum;
}

Вывод приведенного выше кода приведен ниже. Обратите внимание, что первый вывод был результатом включения UNO с нажатой кнопкой Reset, а затем отпущенной после запуска окна Monitor. В противном случае печать «неверной настройки» была бы пропущена до того, как окно монитора можно было бы запустить.

Out of Reset - value1 = 0xBFED, value2 = 0xD2F9, sum = 0x377, chksum = 0xF457
chksum is incorrect setting config.val.chksum = 0x377
setup new values -  value1 = 0xBFEE, value2 = 0xD2FA, sum = 0x379, chksum = 0x377
updating chksum config.val.chksum = 0x379
after a while -  value1 = 0xBFEE, value2 = 0xD2FA, sum = 0x379, chksum = 0x379

Out of Reset - value1 = 0xBFEE, value2 = 0xD2FA, sum = 0x379, chksum = 0x379
setup new values -  value1 = 0xBFEF, value2 = 0xD2FB, sum = 0x37B, chksum = 0x379
updating chksum config.val.chksum = 0x37B
after a while -  value1 = 0xBFEF, value2 = 0xD2FB, sum = 0x37B, chksum = 0x37B

Out of Reset - value1 = 0xBFEF, value2 = 0xD2FB, sum = 0x37B, chksum = 0x37B
setup new values -  value1 = 0xBFF0, value2 = 0xD2FC, sum = 0x37D, chksum = 0x37B
updating chksum config.val.chksum = 0x37D
after a while -  value1 = 0xBFF0, value2 = 0xD2FC, sum = 0x37D, chksum = 0x37D

При этом ваши переменные будут сохранять сброс. Пока власть не потеряна. Для начала обратите внимание на вышеизложенное, где вы получите случайные данные.

Используя EEPROM или .noinit, я бы рекомендовал вам подсчитать контрольную сумму вашего постоянного пространства переменных во время установки, и если она неверна, вы можете инициализировать или выдать предупреждение.

Если вам действительно необходимо часто обновлять NVRAM, загляните в FRAM (сегнетоэлектрическое оперативное запоминающее устройство), срок записи которого составляет 10^13 циклов (это ~ 318 000 лет, если вы пишете один раз в секунду!). Их размер составляет 8 КБ, и они быстрее, чем Flash или EEPROM с частотой 20 МГц (SPI).

Adafruit (в США) продает их на специальной плате по цене около 6$ за штуку. Или вы можете купить голые чипы у обычных поставщиков примерно за 1,30 доллара, но не DIP, а только в упаковках SOP8.

Если вы готовы к внекристальному решению, купить/создать устройство чтения SD-карт несложно.

Я очень опоздал на эту вечеринку... Я только что купил UNO WiFi и собираюсь создать простой протокол для сохранения данных в хранилище данных на другом устройстве, подключенном к Wi-Fi. Вероятно, мы будем использовать HTTP с простыми конечными точками и рассматривать удаленное хранилище как непрерывный блок памяти:

GET IP:port/addr/len
PUT IP:port/addr data

Я также мог бы создавать именованные блоки (например, файлы):

GET IP:port/name
PUT IP:port/name data

Фактическим удаленным хранилищем может быть что угодно: файл диска с отображением в памяти, база данных SQLite3 и т. д.

Существует множество недостатков, таких как зависимость от внешнего сервиса, проблемы с подключением, обработка ошибок и т. д. Мне может не хватить места для кода, просто поддерживая протокол.

Меня это тоже озадачило. Я просто хотел использовать встроенную кнопку, чтобы вызвать команду «подсчитать целое число». независимо от каких-либо процедур настройки. Для меня ответ mpflaga дал мне правильное направление. Но данный пример был слишком сложен для моих нужд. Итак, вот минимальный пример целочисленного значения, которое сохраняется после сброса при обратном подсчете. (Но НЕ потеря мощности, так как она находится в оперативной памяти!) Наслаждайтесь!

uint8_t c __attribute__ ((section (".noinit")));

void setup() {
  Serial.begin(9600);
  Serial.print("Just startet. c = ");
  Serial.print(c);
  if(c>7){c=0;}else{c++;}
  Serial.println(" - Waiting for RESET.");
}

void loop() {
  // Делаем больше вещей.
}