Управление двигателем постоянного тока ARDUINO через ИК-датчик INPUT

У вас есть общее представление.

Ваш код выглядит немного загроможденным. Комментарии не являются частью программы, держите их подальше от кода.

Инструкции if сокращаются до if (true), что означает, что часть == true является избыточной. Все, что вам нужно, это if(state). Блок if будет выполняться, когда state истинно. И наоборот, if (!state) проверяет, является ли state ложным

Если есть только два возможных значения, то else if(state == true) может быть просто else.

Идентичный код, который находится в обеих частях блока if-else, должен быть перемещен за пределы блока, rememberTime=millis(); должен быть перемещен после закрывающая фигурная скобка } блока if-else.

Вот код, который делает то, что вы хотите.

Этот код не тестировался на аппаратном устройстве.

https://wokwi.com/projects/364353854313747457

const int     sensor_blocked  = LOW;              // определяем значения датчиков
const int     sensor_clear    = HIGH;

const int     motor_on        = HIGH;
const int     motor_off       = LOW;

const int     master_enable   =  2;
const int     motor_pin       =  3;
const int     sensor_pin      = 12;

int           sensor_state;
int           sensor_previous = sensor_clear;
int           motor_state     = motor_on;

unsigned long millis_previous = 0;
unsigned long millis_now;

const long    interval        = 500;  

void setup() {

  pinMode(master_enable, INPUT_PULLUP);
  pinMode(sensor_pin,    INPUT_PULLUP);
  pinMode(motor_pin,     OUTPUT);

}

void loop() {

  sensor_state = digitalRead( sensor_pin );

  // ------------------------------------------------ -------------------------------------------------- -

  if ( sensor_state != sensor_previous ) {             // запускаем этот код только при изменении состояния датчика
    sensor_previous = sensor_state;                    // запоминаем новое состояние датчика
    
    if ( sensor_state == sensor_blocked ) {            // датчик заблокировался
      motor_state = motor_off;                         // выключаем двигатель
      millis_previous = millis();                      // начало "двигатель выключен" интервал
    }
    delay(20);                                         // датчик подавления дребезга
  }

  // ------------------------------------------------ -------------------------------------------------- -

  if ( motor_state == motor_off ) {                    // проверка таймера актуальна только при выключенном двигателе
    millis_now = millis();
    if ( millis_now - millis_previous >= interval ) {  // проверяем, не истек ли срок действия таймера
      motor_state = motor_on;                          // включить двигатель
    }
  }

  // ------------------------------------------------ -------------------------------------------------- -

  if ( digitalRead( master_enable ) != LOW ) motor_state = motor_off;     // главный переключатель

  // ------------------------------------------------ -------------------------------------------------- -

  digitalWrite(motor_pin, motor_state);                // перевести моторное состояние в действие

}