Почему декодер ИК-пульта NEC не работает

Внешняя версия прерывания декодера протокола NEC, использующая micros() для синхронизации вместо Таймера 1. Отбрасывает повторяющиеся коды NEC, В противном случае, в стиле кода в вопросе.

volatile boolean nec_ok = 0;
byte command, inv_command;
volatile byte nec_state = 0 ;
unsigned int address;
volatile unsigned long nec_code;
volatile uint32_t errFlag = 0 ;
volatile uint32_t decodeStartAtMs = 0 ;


void setup() {
  Serial.begin(9600);
  pinMode( 2, INPUT_PULLUP ) ;
  attachInterrupt(digitalPinToInterrupt(2), remote_read, CHANGE); // Включить внешнее прерывание (INT0)
}

void remote_read() {

  static byte i = 0 ;
  static bool wasSpace;
  static unsigned long enteredAtUs = 0 ;
  static unsigned long pulseLengthLastUs ;

  wasSpace = ! digitalRead( 2 ) ;
  pulseLengthLastUs = micros() - enteredAtUs; // Расчет длины импульса
  enteredAtUs = micros(); // Сохраняем текущее время для следующей записи


  switch (nec_state) {

    case 0 : // Подождите здесь, пока не будет найден импульс 9 мс )
      if ( pulseLengthLastUs > 8000 && pulseLengthLastUs < 10000 ) {  // получен импульс длительностью 9 мс
        decodeStartAtMs = millis() ;  // для тайм-аута
        nec_state = 1 ;
        nec_code = 0 ;
        i = 0 ;
      }
      break;

    case 1 : // обработка 4,5 мс пробела
      /*
      if ((pulseLengthLastUs > 2000) && (pulseLengthLastUs < 2500)) {
          // беззвучно отбрасываем повторяющиеся коды !!!
          nec_state = 0; // Сброс процесса декодирования
      }
      else 
      */
      if ((pulseLengthLastUs > 5500) || (pulseLengthLastUs < 3500)) {
        errFlag = 10000000 + pulseLengthLastUs ;
        nec_state = 0; // Сброс процесса декодирования
      }
      else
        nec_state = 2; // Следующее состояние: конец импульса 562 мкс (начало интервала 562 мкс или 1687 мкс)
      break;


    case 2 : // обрабатывать пространство 562 мкс или 1687 мкс
      if ((pulseLengthLastUs > 1900) || (pulseLengthLastUs < 400)) { // Недопустимый временной интервал ==> остановить декодирование
        errFlag = 20000000 + pulseLengthLastUs ;
        nec_state = 0; // Сброс процесса декодирования
        break;
      }

      if ( wasSpace ) {
        // нас интересует только длина пробела
        if ( pulseLengthLastUs > 1000) // Если ширина пробела > 1 мс (короткий пробел)
          bitSet(nec_code, (31 - i)); // Записать 1 в бит (31 - i)
        else // Если ширина пробела < 1 мс (длинный пробел)
          bitClear(nec_code, (31 - i)); // Записать 0 в бит (31 - i)
        i++;
        if (i > 31) { // Если все биты получены
          i = 0 ;
          nec_ok = 1; // Процесс декодирования ОК
          detachInterrupt(0); // Запретить внешнее прерывание (INT0)
        }
      }
      break;
  }
}

void loop() {

  if ( errFlag > 0 ) {
    Serial.print( "Error: " ) ;
    Serial.println( errFlag ) ;
    errFlag = 0 ;
  }

  if ( nec_state > 0 && millis() - decodeStartAtMs > 90 ) {
    Serial.println( "Timeout" ) ;
    nec_state = 0 ;
  }


  if (nec_ok) {
    Serial.print( "Code received = " ) ;
    Serial.println( nec_code, HEX ) ;

    address = (nec_code >> 16) & 0xFF; // Извлекаем адрес из полученного кода
    inv_command = (nec_code >> 8) & 0xFF; // Извлечь инвертированную команду из полученного кода
    command = nec_code & 0xFF; // Извлечь команду из полученного кода
    if (command == ((~inv_command) & 0xFF)) { // Проверка правильности команды
      Serial.print("Received valid NEC code: ");
      Serial.print(address, HEX); Serial.print(", ");
      Serial.print(command, HEX); Serial.print(", ");
      Serial.println(inv_command, HEX);
    }
    else {
      Serial.println("Received invalid NEC code!");
    }
    nec_ok = 0; // Сброс процесса декодирования
    nec_state = 0; // Сбросить состояние декодирования
    attachInterrupt(digitalPinToInterrupt(2), remote_read, CHANGE); // Повторно разрешить внешнее прерывание (INT0)
  }

}

Эту утилиту можно использовать для проверки выходных данных ИК-приемника, показывающих синхронизацию импульсов и промежутков с разрешением 4 мкс.

// утилита анализатора протоколов
// предназначен для передачи таймингов на последовательную консоль, например, из демодулированных IR-кодов NEC
// Подключите выход ИК-приемника к контакту 2


const uint8_t DATA_SIZE = 100 ;

struct intervalRead_t {
  uint32_t durationUs ;
  bool space ;
} ;

intervalRead_t intervalRead[ DATA_SIZE ] ;

volatile unsigned long enteredAtUs = 0 ;
volatile uint8_t index = 0 ;
volatile bool firstPulse = true ;


void saveTimes() {

  bool wasSpace;
  uint32_t pulseLengthLastUs ;

  wasSpace = ! digitalRead( 2 ) ;
  pulseLengthLastUs = micros() - enteredAtUs; // Расчет длины импульса
  enteredAtUs = micros(); // Сохраняем текущее время для следующей записи

  if ( firstPulse ) {
    firstPulse = false ;
    index = 0 ;
  }
  else {
    if ( index < DATA_SIZE  )  {
      intervalRead[ index ].durationUs = pulseLengthLastUs ;
      intervalRead[ index ].space = wasSpace ;
      index++ ;
    }
  }
}

void setup() {
  Serial.begin(9600);
  pinMode( 2, INPUT_PULLUP ) ;
  attachInterrupt(digitalPinToInterrupt(2), saveTimes, CHANGE); // Включить внешнее прерывание (INT0)
}

void loop() {
  if ( !firstPulse && micros() - enteredAtUs > 500000UL  ) {
    for ( uint8_t i = 0; i < index ; i++ ) {
      Serial.print( i ) ;
      Serial.print( "\tinterval= " ) ;
      Serial.print( intervalRead[ i ].durationUs ) ;
      Serial.print( "us  \t") ;
      Serial.print( intervalRead[ i ].space ? "space" : "pulse" ) ;
      Serial.println( ) ;
    }
    Serial.println( ) ;
    firstPulse = true ;
  }
}