Ардуино зависает/не отвечает- не могу понять почему

Я строю лодку с дистанционным управлением. Мой удаленный проект зависает через произвольное время. Последовательный порт перестает выводить, OLED больше не обновляется и инструкции больше не отправляются/не принимаются.

На всю жизнь я не могу понять, почему мой проект зависает. Использование Arduino Nano.

Я пробовал следующее:

• Держите память небольшой
• Отключите Serial, чтобы избежать переполнения.
• Не используйте рискованные переменные; как строка
• Определить, вызывает ли зависание конкретное обстоятельство (количество X времени, определенные инструкции, потеря радиосвязи и т. д.)
• Замените Arduino
• Замените блок питания
• Замените кабель питания.
• Переведите радио в режим отладки, оно станет медленным и ничего интересного не будет показываться по последовательному каналу.

Пожалуйста, помогите мне продолжить мой двухлетний проект. Моя благодарность за любые указания или помощь бесконечна.

Arduino подключен к NRF24L01 с платой адаптера, OLED и двумя потенциометрами.

Это мой код:

#include <SPI.h>
#include "printf.h"
#include "RF24.h"
#include "SSD1306Ascii.h"
#include "SSD1306AsciiAvrI2c.h"
#include <DifferentialSteering.h>

// Режим отладки:
int debugging_serial = 0;
int debugging_delay = 0;
int debugging_verbose = 0;

// Инициализация таймеров;
unsigned long start_timer = 0;
unsigned long end_timer = 0;

// Старое состояние для очистки
int oledstate = 0;

// Создайте трансивер nRF24L01, используя контакты 9 и 10.
RF24 radio(9, 10);

// OLED-инициализация
#define I2C_ADDRESS 0x3C // 0X3C+SA0 - 0x3C или 0x3D
#define RST_PIN -1 // При необходимости определить правильный RST_PIN.
SSD1306AsciiAvrI2c oled;

// Установка контактов потенциометра
int pot_one_pin = A0;
int pot_two_pin = A1;

// Установить управление разницей
DifferentialSteering DiffSteer;

// Зарегистрируйте два радиоадреса, чтобы использовать их для связи.
uint8_t address[][6] = { "1Node", "2Node" };


// Определяем отправку и получение структур полезной нагрузки. Примечание: они должны быть инвертированы для удаленного и лодочного кода.
// ОПРЕДЕЛЯЕМ, ЧТО МЫ БУДЕМ ОТПРАВЛЯТЬ
struct SendingPayloadObject 
{
  // Мы отправляем два числа
  uint8_t Motor1Speed; 
  uint8_t Motor2Speed;
};
// Также создайте объект полезной нагрузки для подготовки и загрузки со значениями по умолчанию в настройках
SendingPayloadObject payload;

// ОПРЕДЕЛЯЕМ, ЧТО МЫ ПОЛУЧИМ
struct ReceivingPayloadObject 
{
  // Мы отправляем сообщение и номер
  char message[7];  // использование только 6 символов для TX & Полезная нагрузка ACK
  uint8_t counter; // переменная-счетчик структуры в качестве примера
};

void setup() 
{
  if(debugging_serial) 
  {
    Serial.begin(115200);
    Serial.println("Remote Code Started!");
  }

  // Настройка Oled
  // Вызываем oled.setI2cClock(частота) для изменения частоты по умолчанию.
  oled.begin(&Adafruit128x64, I2C_ADDRESS, RST_PIN);
  //oled.setFont(System5x7);
  oled.clear();
  oled.println("Boat Remote Started!");
  oled.clear();
  
  // Проверяем, работает ли радио
  if (!radio.begin()) 
  {
    if(debugging_serial) 
    {
      Serial.println(F("Radio hardware is not responding!"));
    }
      
    while (1) {}  // держать
  }

  // Установите низкий уровень PA, чтобы попытаться предотвратить проблемы, связанные с питанием
  // потому что эти примеры, скорее всего, выполняются с узлами в непосредственной близости от
  // друг друга. (RF24_PA_MAX по умолчанию)
  radio.setPALevel(RF24_PA_LOW);

  // Чтобы использовать полезную нагрузку ACK, нам нужно включить динамическую длину полезной нагрузки (для всех узлов). Полезные нагрузки ACK имеют динамический размер
  radio.enableDynamicPayloads();

  // Пакеты подтверждения не имеют полезной нагрузки по умолчанию. Нам нужно включить эту функцию для всех узлов (TX и RX), чтобы использовать полезные данные ACK.
  radio.enableAckPayload();

  // Установите адрес TX узла RX в канал TX и наоборот в канал RX. Удаленный радиоадрес равен 1!
  radio.openWritingPipe(address[1]);
  radio.openReadingPipe(1, address[0]);

  // Код роли отправителя
  // Установить значения полезной нагрузки по умолчанию и перевести радио в режим отправки (TX)
  payload.Motor1Speed = 0;  // устанавливаем полезную нагрузку payloadMotor1Speed
  payload.Motor2Speed = 0;  // устанавливаем полезную нагрузку payloadMotor1Speed
  radio.stopListening();                 // перевести радио в режим TX
  
  if(debugging_verbose)
  {
    printf_begin();             // требуется только один раз для печати деталей
    radio.printDetails();       // (меньшая) функция, которая печатает необработанные значения регистров
    radio.printPrettyDetails(); // (более крупная) функция, которая печатает удобочитаемые данные
  }

  // Инициализация DiffSteer
  DiffSteer.begin(0);
}

void loop() 
{
  //// ДИСТАНЦИОННОЕ УПРАВЛЕНИЕ:

  // НОВАЯ ЛОГИКА ДЛЯ МАНЕВРИРОВАНИЯ
  int motorSpeed1 = 0;
  int motorSpeed2 = 0;

  // Управление с помощью потенциометров
  int steering_pot_value = map(analogRead(pot_two_pin), 0, 1023, -127, 127);
  int power_pot_value = map(analogRead(pot_one_pin), 0, 1023, 0, 127);

  // Идти прямо, когда рулишь почти прямо
  if(steering_pot_value <= 15 && steering_pot_value >= -15)
  {
    steering_pot_value = 0;
  }

  // Вычисление дифференциального рулевого управления
  DiffSteer.computeMotors(steering_pot_value, power_pot_value);
  
  // сопоставляем выходы мотора с нужным диапазоном
  motorSpeed1 = map(DiffSteer.computedLeftMotor(), 0, 127, 0, 255);
  motorSpeed2 = map(DiffSteer.computedRightMotor(), 0, 127, 0, 255);

  // Корректирующие меры для более плавного управления
  // Исправлено деление на 0, полная мощность, когда банк полностью выключен
  if(power_pot_value <= 1) { motorSpeed1 = 0; motorSpeed2 = 0; };

  // Код управления двигателем OLED (для тестирования)
  // Скорости напрямую от счетчиков
  // motorSpeed1 = map(analogRead(pot_one_pin), 0, 1023, 0, 255);
  // motorSpeed2 = map(analogRead(pot_two_pin), 0, 1023, 0, 255);
  //
  
  // Установить скорость двигателя в полезной нагрузке
  payload.Motor1Speed = motorSpeed1;
  payload.Motor2Speed = motorSpeed2;

  //// РАДИОМАТЕРИАЛЫ:
  
  // Рассчитываем время передачи для маагда/ботаника
  if(debugging_serial) 
  {
     start_timer = micros();                  // запускаем таймер
  }

  // Отправляем по радио TX;
  bool report = radio.write(&payload, sizeof(payload));  // передать & сохранить отчет

  if(debugging_serial) 
  {
    end_timer = micros();                    // конец таймера
  }

  if (report) 
  {
    if(debugging_serial) 
    {
      Serial.print(F("Time to transmit = "));
      Serial.print(end_timer - start_timer);  // распечатать результат таймера
      Serial.print(F(" us. Sent (Motor 1 Speed: "));
      Serial.print(payload.Motor1Speed);
      Serial.print(F(" , Motor 2 Speed: "));
      Serial.print(payload.Motor2Speed);
      Serial.print(F(")"));
    }

    // Определяем трубу
    uint8_t pipe;
    
    if (radio.available(&pipe)) 
    {
      if (oledstate != 1) { oled.clear(); }; oledstate = 1;
      oled.set1X();
      oled.setFont(System5x7);
      oled.setCursor(0 , 0);
      oled.print("Transmission OK \n");
      oled.setCursor(0 , 30);
      oled.print("Motors L:");
      // Добавляем ведущие нули, чтобы получить истинные значения (иначе останется старое число)
      if(payload.Motor1Speed < 100 && payload.Motor1Speed >= 10) { oled.print("0"); };
      if(payload.Motor1Speed < 10) { oled.print("00"); };
      oled.print(payload.Motor1Speed);
      oled.setCursor(80 , 30);
      oled.print("R:");
      if(payload.Motor2Speed < 100 && payload.Motor2Speed >= 10) { oled.print("0"); };
      if(payload.Motor2Speed < 10) { oled.print("00"); };
      oled.print(payload.Motor2Speed);
      
      // есть ли полезная нагрузка ACK? возьмите номер трубы, которая его получила
      ReceivingPayloadObject received;
      radio.read(&received, sizeof(received));  // получаем входящую полезную нагрузку ACK

      if(debugging_serial) 
      {
        Serial.print(F(" Recieved "));
        Serial.print(radio.getDynamicPayloadSize());  // вывод размера входящей полезной нагрузки
        Serial.print(F(" bytes on pipe "));
        Serial.print(pipe);  // вывести номер канала, который получил ACK
        Serial.print(F(": "));
        Serial.print(received.message);    // печатаем входящее сообщение
        Serial.println(received.counter);  // вывести входящий счетчик
      }
    } 
    else 
    {
      if (oledstate != 2) { oled.clear(); }; oledstate = 2;
      oled.set1X();
      oled.setCursor(0, 0);
      oled.setFont(System5x7);
      oled.print("Transmission: \n \n");
      oled.setCursor(0, 80);
      oled.set2X();
      oled.print("No Reply (empty ACK)");

      if(debugging_serial) 
      {
        Serial.println(F(" Recieved: an empty ACK packet"));
      }
    }
  } 
  else 
  {
    if (oledstate != 3) { oled.clear(); }; oledstate = 3;
    oled.set1X();
    oled.setCursor(0, 0);
    oled.setFont(System5x7);
    oled.print("Transmission: \n \n");
    oled.setCursor(0, 80);
    oled.set2X();
    oled.print("Failed");

    if(debugging_serial) 
    {    
      Serial.println(F("Transmission failed or timed out"));
    }
  }

  // Добавляем задержку при программировании для чтения
  if(debugging_verbose)
  {
    delay(10000); 
  }
  else
  {
    if(debugging_delay)
    {
      delay(1000); 
    }
  }
}