Отсутствуют импульсы ATTiny88 - возможно

Хорошо, у меня есть ответ. MCU по-прежнему пропускает много импульсов, но я совершенно уверен, что это аппаратная проблема, или, по крайней мере, в основном так. Я нашел код Ральфа С. Бэкона и Марко Пинтерика. Видео YouTube можно найти здесь

Как и всегда, ISR краток. Здесь это единственная строка, которая просто устанавливает логическую переменную в значение true. В секции цикла код неоднократно проверяет, произошло ли прерывание. Затем функция checkRo taryEncoder проверяет значения выводов, чтобы убедиться, что кодировщик находится в допустимом состоянии (не дребезжит). Если это так, то значение счетчика обновляется результатом.

#include <Arduino.h>
#include <TM1637Display.h>
#include "PinChangeInterrupt.h"

uint8_t lrmem = 3;
int lrsum = 0;
int num = 0;
unsigned int counter = 0;

// Выход отключения
#define SW 11
// Входы поворотного энкодера
#define Phase_A 12
#define Phase_B 13
// Ввод/вывод дисплея TM1637
#define DIO 3
#define CLK 4
TM1637Display display(CLK, DIO);

// Счетчик оборотов для поворотного энкодера (отрицательное значение = против часовой стрелки)
int rotationCounter = 200;
// Флаг из подпрограммы прерывания (moved=true)
volatile bool rotaryEncoder = false;

// Поворотный энкодер сдвинулся (об этом нам сообщает прерывание), но что произошло?
// См. https://www.pinteric.com/rotary.html
int8_t checkRotaryEncoder()
{
    // Сбрасываем флаг, который привел нас сюда (из ISR)
    rotaryEncoder = false;

    static uint8_t lrmem = 3;
    static int lrsum = 0;
    static int8_t TRANS[] = {0, -1, 1, 14, 1, 0, 14, -1, -1, 14, 0, 1, 14, 1, -1, 0};

    // Прочитать состояния ОБЕИХ выводов, чтобы определить правильность вращения (т.е. не просто отскок переключателя)
    int8_t l = digitalRead(Phase_A);
    int8_t r = digitalRead(Phase_B);

    // Перемещаем предыдущее значение на 2 бита влево и добавляем новые значения
    lrmem = ((lrmem & 0x03) << 2) + 2 * l + r;
    // Преобразование битового паттерна в индикатор движения (14 = невозможно, т.е. переключить отскок)
    lrsum += TRANS[lrmem];
    /* encoder not in the neutral (detent) state */
    if (lrsum % 4 != 0)
    {
        return 0;
    }
    /* encoder in the neutral state - clockwise rotation*/
    if (lrsum == 4)
    {
        lrsum = 0;
        return 1;
    }
    /* encoder in the neutral state - anti-clockwise rotation*/
    if (lrsum == -4)
    {
        lrsum = 0;
        return -1;
    }
    // Обнаружено невозможное вращение - игнорируем движение
    lrsum = 0;
    return 0;
}

void setup() {
  // Установить выводы энкодера в качестве входных данных
  pinMode(Phase_A,INPUT);
  pinMode(Phase_B,INPUT);
  // Установить выключатель питания в качестве выхода
  pinMode(SW, OUTPUT);
  // Инициализировать отображение
  display.setBrightness(0x0f);
  display.clear();
  display.showNumberDec(0, false);
  // Настраиваем пины прерывания и вектор
  attachPCINT(digitalPinToPCINT(Phase_A), rotary, CHANGE);
  attachPCINT(digitalPinToPCINT(Phase_B), rotary, CHANGE);
}

void loop()
{
  // Сдвинулся ли поворотный регулятор?
  if (rotaryEncoder) {
    // Получить движение (если допустимо)
    int8_t rotationValue = checkRotaryEncoder();
    // Если допустимое движение, делаем что-то
    if (rotationValue != 0) {
      counter += rotationValue;
      if (counter > 1023){
        counter = 1023;
      }
      else if (counter < 0){
        counter = 0;
      }
      display.showNumberDec(counter, false);
    }
  }
}

// Процедура прерывания просто устанавливает флаг при обнаружении поворота
void rotary()
{
    rotaryEncoder = true;
}

Приветствуются любые комментарии. Кроме того, Ральф Бэкон использовал директиву IRAM_ATTR для создания ISR rotate(). Я понимаю эту директиву так, что в большинстве случаев в ней нет необходимости. С другой стороны, предположительно код будет выполняться быстрее, если он будет помещен во флэш-память. Я не мог сделать эту работу. Компилятор жалуется: "ожидаемый инициализатор перед 'rotary'"; Случайно ли это, потому что у ATTiny88 нет флэш-памяти? Если нет, то что?