Прерывание является спорадическим, возможно, после 220 Гц или около того

Из моего поста о прерываниях:

---

Я видел пример кода, предлагающий вам считать вещи в течение секунды, отключив прерывания на секунду, а затем снова включив. Я не рекомендую этого делать, потому что, во-первых, вы не можете выполнять последовательную печать, если прерывания отключены.

Пример (не рекомендуется):

volatile unsigned long events;
const unsigned long INTERVAL = 1000;  // 1 секунда

void eventISR ()     
  { 
  events++;  
  }   // конец eventISR

void setup () 
  { 
  Serial.begin(115200); 
  attachInterrupt (digitalPinToInterrupt (2), eventISR, FALLING); 
  }   // завершение настройки

void loop ()    
  {
  events = 0;       // сброс счетчика
  interrupts ();    // разрешить
  delay (INTERVAL); // ожидание требуемого времени
  noInterrupts();   // останавливать прерывания

  Serial.print ("I counted ");
  Serial.println (events);
  }  // конец цикла

Это может сработать в простых ситуациях, но отключение прерываний означает, что серийные отпечатки не будут работать до тех пор, пока они снова не будут включены (чего может и не быть в более сложном скетче).

Лучше использовать результат millis() и просто определить, когда истечет отведенное время.

Улучшенный скетч:

volatile bool counting;
volatile unsigned long events;

unsigned long startTime;
const unsigned long INTERVAL = 1000;  // 1 секунда

void eventISR ()
  {
  if (counting)
    events++;    
  }  // конец eventISR
  
void setup ()
  {
  Serial.begin (115200);
  Serial.println ();
  attachInterrupt (digitalPinToInterrupt (2), eventISR, FALLING);
  }  // завершение настройки

void showResults ()
  {
  Serial.print ("I counted ");
  Serial.println (events);
  }  // окончание показа результатов
  
void loop ()
  {
  if (counting)
    {
    // время вышло?
    if (millis () - startTime < INTERVAL)
      return;  
    counting = false;
    showResults ();
    }  // конец if
    
  noInterrupts ();
  events = 0;
  startTime = millis ();
  EIFR = bit (INTF0);  // снять флаг для прерывания 0
  counting = true;
  interrupts ();
  }  // конец цикла

В loop() здесь мы ждем истечения интервала (в данном случае 1 секунды), в противном случае мы возвращаемся, фактически ничего не делая. Конечно, вы могли бы заняться другими делами вместо того, чтобы просто возвращаться.

Если время истекло, мы показываем счетчик.

Если подсчет в данный момент не активен (и предполагается, что мы хотим, чтобы он был активным), мы запоминаем время начала, сбрасываем счетчик на ноль и даем ему начать отсчет.

Этот код, казалось, нормально работал до 100 кГц, хотя подсчеты становились немного неточными. Вы можете установить более точные тайминги, используя аппаратные счетчики / таймеры. Подробности здесь:

http://www.gammon.com.au/timers

---

Также вы должны объявить переменную L изменчивой.