Оптимизация кода для ATtiny10

Вы уверены, что выводы правильные?

Может быть, использовать меньший генератор случайных чисел на https://arduino.stackexchange.com/a/18092/6628 ?

static uint8_t lfsr = 0x01;
const byte LFSR_MASK = 0x8e;

void setup() {
  pinMode(0, OUTPUT);
  pinMode(1, OUTPUT);
  pinMode(3, INPUT);
}
void loop() {
  //      int buttonState = digitalRead(3);
  if (digitalRead(3)) {
    if (generateNoise()) {
      digitalWrite(0, HIGH);
    }
    else {
      digitalWrite(1, HIGH);
    }
    //delay(2000)
    //for (int i = 31; i; i--)_delay_us(64516);
    _delay_ms(2000);
    digitalWrite(0, LOW);
    digitalWrite(1, LOW);
  }
}


uint8_t generateNoise() {
  // Return 1 bit of noise using a Galois Linear Feedback Shift Register
  // See https://en.wikipedia.org/wiki/Linear_feedback_shift_register#Galois_LFSRs

  if (lfsr & 1) {
    lfsr =  (lfsr >> 1) ^ LFSR_MASK ;
    return (1);
  }
  else         {
    lfsr >>= 1;
    return (0);
  }
}

ГСЧ помог не так сильно, как изменение столь пренебрежительной задержки.

Как я уже говорил в комментарии, это устройство было бы слишком маленьким, чтобы я мог запрограммировать его с помощью ядра Arduino. Я бы предпочел придерживаться avr-libc и прямых манипуляций с портом:

#include <stdlib.h>
#include <avr/io.h>
#include <util/delay.h>

int main(void)
{
    DDRB = _BV(PB0)   // PB0 as output
         | _BV(PB1);  // PB1 as output
    for (;;) {
        loop_until_bit_is_set(PINB, PB3);  // wait for PB3 high
        if (rand() & 1)
            PORTB |= _BV(PB1);  // PB1 high
        else
            PORTB |= _BV(PB0);  // PB0 high
        _delay_ms(2000);
        PORTB &= ~_BV(PB0);     // PB0 low
        PORTB &= ~_BV(PB1);     // PB1 low
    }
}

Это обычный C, но я ожидаю, что он будет принят Arduino IDE как допустимый файл .ino. Я попытался скомпилировать его следующим образом:

avr-gcc -mmcu=attiny10 -Os -Wall -Wextra -DF_CPU=8000000 prog.c -o prog.elf

И это привело к созданию программы, которая использует 660 байт флэш-памяти. Большая часть этого заключается в реализации rand() и его зависимостей (процедуры умножения и деления).

Если кнопка нажата человеком и ваши часы достаточно высоки (диапазон МГц), вы можете использовать трюк и избавиться от ГСЧ.

Вы можете заменить его счетчиком свободного хода следующим образом:

unsigned char count = 0;

void loop() {

    count += 1;

    buttonState = digitalRead(3);

    if (buttonState == HIGH) {
        if( (count & 1) == 0) {
            digitalWrite(0, HIGH);
        }
        else {
            digitalWrite(1, HIGH);
        }
        delay(2000);
        digitalWrite(1, LOW);
        digitalWrite(2, LOW);
    }
}

Вы увеличиваете счетчик каждые ⪝10 us (в зависимости от вашей тактовой частоты attiny выполняет одну инструкцию за цикл), поэтому, когда пользователь нажимает кнопку, счетчик будет отбираться.

Примечание: я предположил, что loop () - это все, что должен делать микроконтроллер, и он постоянно вызывается.

8-битный чип требует нескольких инструкций для обработки 16 бит. Изменение ints на uint8_t или int8_t сохранит код.

В зависимости от оптимизации компилятора, замена

if ( (count & 1) == 0) {
    digitalWrite(0, HIGH);
}
else {
    digitalWrite(1, HIGH);
}

с

digitalWrite((count & 1), HIGH);

можно было бы сэкономить байты.