Использование значения MAX30100 SpO2 для включения светодиода

Question

Использование значения MAX30100 SpO2 для включения светодиода

arduino-uno programming arduino-ide sensors relay

датчик max30100 i2c выдает показания сердечного ритма и spo2 последовательно, а также может отображать значения на ЖК-дисплее. Я хочу показать его индикацию с помощью светодиода.

Если значение SpO2 <94 , то загорится красный светодиод на цифровом выводе 4

Если значение SpO2 >=94, он загорится зеленым светодиодом на цифровом выводе 5>

Здесь pox.getSpO2() дает значение SpO2.

Как я могу использовать это значение для переключения между двумя цифровыми выводами? Я понимаю, что для переключения легче считывать аналоговое значение вывода, но я ищу рекомендации по использованию значений I2C для этого условия.

Спасибо тебе.

Вот минималистичный код SpO2

#include <Wire.h>
#include "MAX30100_PulseOximeter.h"
#define REPORTING_PERIOD_MS     1000

PulseOximeter pox;
uint32_t tsLastReport = 0;

void setup()
{
    Serial.begin(9600);

    Serial.print("Инициализация пульсоксиметра..");

    if (!pox.begin()) {
        Serial.println("СБОЙ");
        for(;;);
    } else {
        Serial.println("УСПЕХ");
    }
}

void loop()
{

    pox.update();

    if (millis() - tsLastReport > REPORTING_PERIOD_MS) {
        Serial.print("SpO2:");
        Serial.print(pox.getSpO2());
        Serial.println("%");

        tsLastReport = millis();
    }
}

@Sayzar, 👍2

1 ответ

Лучший ответ:

@*Mat* · Accepted Answer · 2021-08-13 15:26-00:00

Вы уже проделали всю тяжелую работу, настроив датчик и научившись считывать данные с него.

Я бы определил константу для порога SpO2 в верхней части и удобные имена для контактов:

const uint8_t SpO2_threshold = 94;  // процент
const uint8_t red_pin = 4;
const uint8_t green_pin = 5;

Затем установите контакты в режим вывода в настройках (), как обычно. (Возможно, установите их оба слишком ВЫСОКО (или НИЗКО), чтобы указать, что чтение еще не было выполнено.)

В цикле, в разделе отчетов, просто возьмите значение и переключите контакты:

...
uint8_t spo2 = pox.getSpO2();
// Print it out to serial if needed, then:
if (spo2 < SpO2_threshold) {
  digitalWrite(green_pin, LOW);
  digitalWrite(red_pin, HIGH);
} else {
  digitalWrite(red_pin, LOW);
  digitalWrite(green_pin, HIGH);
}

Более сложная версия, которая подает импульсы на один светодиод (короткое время включения, переменное время выключения) в зависимости от значения, считываемого с датчика. Он использует ту же технику, что и время считывания показаний датчика (ту, которая используется в примере "мигание без задержки").

Показания датчиков фиксируются (любое значение при spo2_min или ниже приведет к ускоренному времени мигания, при spo2_max-к самому медленному). Затем этот диапазон сопоставляется с диапазоном времени выключения светодиодов. Не используйте значения в этом примере, я не врач :-)

// сопоставление контактов
const uint8_t led_pin = LED_BUILTIN;

// показания датчика (%)
const int spo2_min = 85;
const int spo2_max = 100;

// время работы светодиода (мс)
const unsigned long led_off_min = 50;
const unsigned long led_off_max = 5000;

unsigned long led_off_time = led_off_max; // переменная времени выключения
const unsigned long led_on_time = 50;     // исправлено, короткое время

// время считывания показаний датчика (мс)
const unsigned long sensor_interval = 1000;

// состояние светодиода
uint8_t led_state = LOW;

// состояние "таймер"
unsigned long last_reading = 0;
unsigned long last_led_toggle = 0;

void setup() {
  pinMode(led_pin, OUTPUT);
  digitalWrite(led_pin, led_state);

  Serial.begin(9600);

  Serial.print("Инициализация пульсоксиметра..");
  if (!pox.begin()) {
    Serial.println("СБОЙ");
    for (;;);
  } else {
    Serial.println("УСПЕХ");
  }
}

void loop() {
  pox.update();
  unsigned long current_millis = millis();

  /* показания датчика "таймер" */
  if (current_millis - last_reading >= sensor_interval)
  {
    last_reading = current_millis;

    int spo2 = pox.getSpO2();

    // показания зажима в ожидаемом диапазоне
    int clamped = constrain(spo2, spo2_min, spo2_max);
    // отображение в диапазон нерабочего времени
    led_off_time = map(clamped,
                       spo2_min, spo2_max,
                       led_off_min, led_off_max);

    char buff[128];
    sprintf_P(buff, PSTR("reading: %d (%%) -> interval: %lu (ms)"),
              spo2, led_off_time);
    Serial.println(buff);
  }

  /* светодиод переключает "таймеры" */
  unsigned long led_elapsed = current_millis - last_led_toggle;

  if ((led_state == LOW) && (led_elapsed >= led_off_time))
  {
    last_led_toggle = current_millis;
    led_state = HIGH;
    digitalWrite(led_pin, led_state);
  }
  else if ((led_state == HIGH) && (led_elapsed >= led_on_time))
  {
    last_led_toggle = current_millis;
    led_state = LOW;
    digitalWrite(led_pin, led_state);
  }

}