Проблемы с модулем Bluetooth(HC 05)

Ваша настройка слишком сложна! Упростите свою настройку до такой степени, чтобы она касалась только той части, которая вызывает у вас проблемы; в вашем случае связь через последовательный порт между ведущим и ведомым. Решите ТОЛЬКО ЭТУ проблему, а затем двигайтесь дальше

Существует проблема с тем, как передаются и принимаются данные, поскольку предполагается, что передача будет полностью синхронизирована в течение всего срока действия программы. Подумайте, что произойдет, если один байт будет удален из – за ошибки связи-данные x и y будут заменены для дальнейшей передачи.

Первоначальный Отправитель

void loop() {
  // put your main code here, to run repeatedly:
 Serial.write(analogRead(Xaxis)/4);
 Serial.write(analogRead(Yaxis)/4);
 delay(20);
}

Оригинальный Приемник

void loop() {
  // Значение по умолчанию - нет движения, когда джойстик остается в центре
  x = 510 / 4;
  y = 510 / 4;
  // Считывание входящих данных с джойстика или главного устройства Bluetooth
  while (Serial.available() >= 2) {
    x = Serial.read();
    Serial.print("X: ");
    Serial.println(x);
    delay(10);
    y = Serial.read();
    Serial.print("Y: ");
    Serial.println(y);
  }
  delay(10);
  . . .
}

Следовательно, должен быть способ синхронизации с первым байтом сообщения. Это может быть достигнуто с помощью пакетов сообщений, в которых начало и конец сообщения разделены уникальными символами, например { и}, аналогично формату JSON.

В качестве другого примера, стандарт GPS NMEA использует $ и \n для разделения сообщений и для разделения полей. В конце также есть контрольная сумма.

Вот неблокирующий алгоритм, который основан на примере readline() Майенко и примере мигания без задержки для чтения пакета. Функция ReadPacket() возвращает значение true, когда входящие данные были собраны в допустимый пакет. Светодиод мигает, указывая на то, что микроконтроллер не замерз.

Новый Отправитель

void loop()
{
    Serial.print("{");                  // Разделитель первого символа.
    Serial.print(analogRead(Xaxis));    // Полное разрешение. Не нужно делить на 4.
    Serial.print(",");                  // Разделитель полей.
    Serial.print(analogRead(Yaxis));    // Полное разрешение. Не нужно делить на 4.
    Serial.print("}");                  // Разделитель последних символов.
    delay(20);
}

Новый Приемник

void loop()
{
    //
    // ЗАДАЧА 1: Мигайте без задержки, чтобы указать, что микроконтроллер не завис.
    //
    const unsigned int INTERVAL = 250;
    unsigned long current_timestamp = millis();
    static unsigned long previous_timestamp = current_timestamp;
    static bool led_state = false;
    if (current_timestamp - previous_timestamp >= INTERVAL)
    {
        led_state = !led_state;
        digitalWrite(LED_BUILTIN, led_state);
        previous_timestamp += INTERVAL;
    }

    //
    // ЗАДАЧА 2: Чтение и анализ пакета данных.
    //
    static char packet[100];
    const byte NUM_FIELDS = 2;
    unsigned int fields[NUM_FIELDS];
    static unsigned int x = 512;   // Полное разрешение. Не нужно делить на 4.
    static unsigned int y = 512;   // Полное разрешение. Не нужно делить на 4.
    bool new_x = false;
    bool new_y = false;
    if (ReadPacket(Serial, packet, sizeof(packet)))
    {
        Serial.print(F("Received packet >"));
        Serial.print(packet);
        Serial.println(F("<"));

        // Проанализируйте пакет для значений x и y в полном разрешении.
        const char delimiters[] = "{,}";
        char* field;
        int i = 0;
        field = strtok(packet, delimiters);
        while (field != NULL && i < NUM_FIELDS)
        {
            Serial.print("field = ");
            Serial.println(field);
            fields[i] = atoi(field);
            Serial.print("fields[");
            Serial.print(i);
            Serial.print("] = ");
            Serial.println(fields[i]);
            field = strtok(NULL, delimiters);
            i++;
        }
        if (i == NUM_FIELDS)
        {
            if (x != fields[0])
            {
                new_x = true;
                x = fields[0];  // Полное разрешение. Нет необходимости умножать на 4.
                Serial.print("New x = ");
                Serial.println(x);
            }
            if (y != fields[1])
            {
                new_y = true;
                y = fields[1];  // Полное разрешение. Нет необходимости умножать на 4.
                Serial.print("New y = ");
                Serial.println(y);
            }
        }
    }

    Serial.print("x = ");
    Serial.println(x);
    Serial.print("y = ");
    Serial.println(y);

    //
    // ЗАДАЧА 3: Обработайте значения x и y.
    //
    if (new_x || new_y)
    {
        Serial.println("Processing new values.");
        
        . . .
    }
}

bool ReadPacket(Stream& stream, char *const packet, const unsigned int SIZE)
{
    const char FIRST = '{';
    const char LAST = '}';
    static bool read_until_last = false;
    static unsigned int i = 0;
    char ch;

    if (stream.available())
    {
        ch = stream.read();

        if (ch == FIRST)
        {
            Serial.println(F("Received FIRST."));
            i = 0;
            packet[0] = ch;
            read_until_last = true;
            return false;
        }
        if (read_until_last)
        {
            i++;
            if (i > SIZE - 2)
            {
                Serial.println(F("Buffer overrun. Resetting to look for next packet."));
                i = 0;
                read_until_last = false;
                return false;
            }
            if (ch == LAST)
            {
                Serial.println(F("Received LAST."));
                packet[i++] = ch;
                packet[i] = 0;
                read_until_last = false;
                return true;
            }
            else
            {
                Serial.print(F("Received char >"));
                Serial.print(ch);
                Serial.println("<");
                packet[i] = ch;
                return false;
            }
        }
    }
    return false;
}