Перезапустите последовательность NeoPixel с помощью кнопки в любое время.

Question

Перезапустите последовательность NeoPixel с помощью кнопки в любое время.

button millis neopixel

Я очень доволен своей новой штуковиной Arduino и экспериментирую со всеми этими пикселями :).

Я новичок в программировании, и мне сложно его понять, но с каждым успехом мои знания растут.

Моя последняя проблема сейчас состоит в том, чтобы перезапустить мой цикл увеличения полосы в любое время нажатием кнопки.

Я знаю, что delay(); полностью остановит код и подождет, пока истечет время, но я написал некоторый код без использования delay(); и вместо этого использовал millis();.

Пока что мои светодиоды увеличиваются через мою полосу, но я не могу перезапустить ее, пока она не пройдет полностью. Я читал, что часть while(); в моем коде работает как delay();, и это предотвратит его перезапуск до полного цикла. Я использовал код millis(); из другого примера, поэтому он не похож на код из Blink Without Delay.

Я обыскал так много сайтов и не могу написать еще один код для увеличения без промедления, поэтому, надеюсь, вы мне поможете.

#include <FastLED.h>

#define NUM_LEDS_PER_STRIP 16
CRGB ledStrip[NUM_LEDS_PER_STRIP];

const int signalButtonPin = 4;
const int ledStripPin = 8;

int buttonState = 0;
int lastButtonState = 0;

int delaySignalAnimation = 100;

unsigned long currentMillis = 0;
unsigned long previousMillis = 0;

void setup() {
  pinMode(signalButtonPin, INPUT_PULLUP);
  pinMode(ledStripPin, OUTPUT);
  FastLED.addLeds<NEOPIXEL, 8>(ledStrip, NUM_LEDS_PER_STRIP);
}

void loop() {
  buttonState = digitalRead(signalButtonPin);
  if (buttonState != lastButtonState) {
    if (buttonState == LOW) {
      fill_solid(ledStrip, NUM_LEDS_PER_STRIP, CRGB::Black);
      for (int i = 0; i < 16; i++) {
        ledStrip[i] = CRGB::Blue;
        FastLED.setBrightness(100);
        FastLED.show();
        currentMillis = previousMillis = millis();
        while (previousMillis + delaySignalAnimation >= currentMillis) {
          currentMillis = millis();
        }
      }
    } else {
      lastButtonState = buttonState;
    }
    fill_solid(ledStrip, NUM_LEDS_PER_STRIP, CRGB::Black);
    FastLED.setBrightness(0);
  }
  FastLED.show();
}

Заранее спасибо за помощь.

@Marvin, 👍0

2 ответа

@*Majenko* · Answer 1 · 2020-04-12 11:15-00:00

Во-первых, хорошо, что вы пытаетесь избежать delay().

Однако ваш цикл while в значительной степени делает то же самое, что и delay().

Вместо этого вам нужно изменить свой образ мышления. Вместо «Я хочу последовательно зажечь светодиоды от 0 до 15» вам нужно подумать «У меня горит 6 светодиодов. Теперь мне нужно зажечь 7-й».

Каждый раз в цикле, если прошло достаточно времени (см. пример BlinkWithoutDelay), загорается еще один светодиод. Как только вы зажжете все 16, вы можете перезапустить свою последовательность.

Когда вы знаете, как перезапустить последовательность в конце, вы также должны знать, как перезапустить последовательность при нажатии кнопки.

Например, loop() может выглядеть примерно так (не проверено):

void loop() {
    static uint8_t lednum = 0;
    static uint32_t animTicker = millis();

    if (millis() - animTicker >= 1000) { // Один раз в секунду
        animTicker = millis();

        lednum++;
        if (lednum > NUM_LEDS_PER_STRIP) lednum = 0; // Это сбрасывает последовательность

        // Включаем светодиоды до lednum и выключаем остальные
        for (uint8_t i = 0; i < NUM_LEDS_PER_STRIP; i++) {
            if (i < lednum) {
                ledStrip[i] = CRGB::Blue;
            } else {
                ledStrip[i] = CRGB::Black;
            }
        }

        FastLED.show();
    }

    buttonState = digitalRead(signalButtonPin);

    if (buttonState != lastButtonState) {
        lastButtonState = buttonState;
        if (buttonState == LOW) {
            lednum = 0;
        }
    }
}

Ключ здесь в том, что переменная lednum содержит количество светодиодов, которые вы хотите отобразить. Раз в секунду под управлением millis() светодиоды обновляются, чтобы отображать заданное количество светодиодов.

@*jsotola* · Answer 2 · 2020-04-15 22:49-00:00

Это не ответ, а расширение кода Маженко.

Он добавляет еще один слой между функциями нажатия кнопки и светодиодного дисплея, чтобы сделать программу более гибкой

void loop() {

    static bool     tick          = false;                 // периодический триггерный сигнал
    static bool     zap           = false;                 // включить сигнал для запуска последовательности
    static bool     buttonClicked = false;                 // кнопка переведена с "отпущена" на "нажата"

    static uint8_t  mode          = 0;                     // выбирает световую последовательность для запуска
    static uint8_t  lednum        = 0;

    static uint32_t animTicker    = millis();


    if (millis() - animTicker >= 1000) {                   // Один раз в секунду
        animTicker = millis();
        tick = true;                                       // устанавливаем тиковый флаг
    }


    if (buttonClicked) {                                   // вы можете проверить двойной щелчок здесь
        buttonClicked = false;
        zap = !zap;                                        // запуск/остановка с помощью кнопки ... zap используется для разделения функции нажатия кнопки и функции отображения
        if (zap) {
            lednum = 0;                                    // запускаем анимацию с самого начала
            mode += 1; if (mode > 2) mode = 0;             // выбор следующего режима .... это можно сделать двойным щелчком мыши
        }
    }


    if (tick && zap) {
        tick = false;                                                   // сбрасываем галочку .... zap остается установленным в течение всей последовательности анимации
        lednum++;

        if (lednum > NUM_LEDS_PER_STRIP) {
            zap = false;                                                // Это останавливает последовательность (выполняется только один раз) ... используйте счетчик, если нужны множители
        }

        else {
            switch (mode) {                                             // выбираем одну из последовательностей .... в этом примере меняются только цвета

                case 0:
                    for (uint8_t i = 0; i < NUM_LEDS_PER_STRIP; i++) {  // Включаем светодиоды до lednum и выключаем остальные
                        if (i < lednum) {
                            ledStrip[i] = CRGB::Blue;
                        } else {
                            ledStrip[i] = CRGB::Black;
                        }
                    }
                    break;

                case 1:
                    for (uint8_t i = 0; i < NUM_LEDS_PER_STRIP; i++) {
                        if (i < lednum) {
                            ledStrip[i] = CRGB::Red;
                        } else {
                            ledStrip[i] = CRGB::Black;
                        }
                    }
                    break;

                case 2:
                    for (uint8_t i = 0; i < NUM_LEDS_PER_STRIP; i++) {
                        if (i < lednum) {
                            ledStrip[i] = CRGB::Green;
                        } else {
                            ledStrip[i] = CRGB::Yellow;
                        }
                    }
                    break;
            }

            FastLED.show();
        }
    }


    buttonState = digitalRead(signalButtonPin);

    if (buttonState != lastButtonState) {        // переход состояния кнопки
        lastButtonState = buttonState;           // новое "последнее состояние"
        if (buttonState == LOW) {                // переход от "отпущено" к "нажато"
            buttonClicked = true;
        }
    }
}