Кнопка с таймером переключения и функцией сброса времени + светодиод обратной связи

Question

Кнопка с таймером переключения и функцией сброса времени + светодиод обратной связи

arduino-nano timers button millis switch

Новичок здесь.

Я пытался реализовать таймер функции кнопки, работающий с millis() вместо задержки, так как я хочу, чтобы кнопка реагировала во время работы таймера.

На данный момент мне удалось запустить счетчик изменения состояния кнопки и дать ему время ожидания. К сожалению, из моего скетча вытекает все странное поведение, и я еще не понял, почему.

Помощь приветствуется.

Это желаемое поведение таймера:

При запуске Arduino готов принять нажатие кнопки. Реле выключено (HIGH).
После нажатия кнопки:
• Состояние реле изменяется на НИЗКИЙ, чтобы включить его
• Загорается зеленый светодиод.
• Включен таймер на базе millis().
Если пользователь нажимает кнопку, когда переключатель включен, таймер сбрасывается на 0 и продолжает отсчет.
Если время включения подходит к концу, начинает мигать красный светодиод. Скажем, в последнюю минуту.
Как только таймер достигнет указанного времени включения:
• Зеленый светодиод гаснет
• Реле выключается • Система возвращается к шагу 1 и ожидает нажатия.

В моем примере кода красный мигающий светодиод еще не реализован. Следующий код включает переключатель и зеленый светодиод, но больше не выключает их.

//КОНСТАНТЫ

#define BUTTON_PIN        2  // Кнопка
int in1 = 7;
int greenLED = 4;
int redLED = 9;


//ПЕРЕМЕННЫЕ

int buttonPushCounter = 0;   // счетчик количества нажатий кнопок
int buttonState = 0;         // текущее состояние кнопки
int lastButtonState = 0;     // предыдущее состояние кнопки

// МИЛЛИС
unsigned long previousMillis = 0;
const long interval = 10000;


void setup()
{
  pinMode(BUTTON_PIN, INPUT);
  digitalWrite(BUTTON_PIN, HIGH); // остановить
  Serial.begin(9600);

  pinMode(greenLED, OUTPUT);
  pinMode(redLED, OUTPUT);

  //ОБРАБОТЧИКИ ПЕРЕКЛЮЧЕНИЯ
  pinMode(in1, OUTPUT);
  digitalWrite(in1, HIGH);

}


void loop(){

    // прочитать входной контакт кнопки:
    buttonState = digitalRead(BUTTON_PIN);
    unsigned long currentMillis = millis();

    // сравниваем состояние кнопки с предыдущим состоянием
    if (buttonState != lastButtonState) {

        buttonState = digitalRead(BUTTON_PIN);

        if (currentMillis - previousMillis < interval){
        // ВКЛЮЧЕНИЕ, СВЕТОДИОД ВКЛЮЧЕН
          digitalWrite(in1, LOW);
          digitalWrite(greenLED, HIGH);
        }

        if (currentMillis - previousMillis >= interval) {
            previousMillis = currentMillis;
            digitalWrite(in1, HIGH);
            digitalWrite(greenLED, LOW);
        } 


        // Небольшая задержка, чтобы избежать подпрыгивания
        delay(50);


        // Сбросить состояние кнопки:
        lastButtonState = buttonState;
   }
}

@ifthisthenthat, 👍2

Обсуждение

Во-первых, вы запускаете код, когда кнопка нажата, а также когда кнопка отпускается (хотя я не думаю, что здесь это на что-то влияет). Во-вторых, код, проверяющий, прошло ли достаточно времени, запускается только при нажатии (или отпускании) кнопки. В-третьих, предыдущий Millis не обновляется при нажатии кнопки., @Gerben

1 ответ

Лучший ответ:

@*Gerben* · Accepted Answer · 2017-11-28 16:03-00:00

Написано и протестировано. Я также включил красный мигающий светодиод.

//КОНСТАНТЫ

const int BUTTON_PIN = 2; // Кнопка
const int in1 = 7;
const int greenLED = 4;
const int redLED = 9;


//ПЕРЕМЕННЫЕ

int buttonPushCounter = 0;   // счетчик количества нажатий кнопок
int buttonState = 0;         // текущее состояние кнопки
int lastButtonState = 0;     // предыдущее состояние кнопки
bool relayOn = false;

// МИЛЛИС
unsigned long previousMillis = 0;
const unsigned long interval = 10000;
const unsigned long redLedInterval = 2000;


void setup()
{
  pinMode(BUTTON_PIN, INPUT);
  digitalWrite(BUTTON_PIN, HIGH); // остановить
  Serial.begin(9600);

  pinMode(greenLED, OUTPUT);
  pinMode(redLED, OUTPUT);

  //ОБРАБОТЧИКИ ПЕРЕКЛЮЧЕНИЯ
  pinMode(in1, OUTPUT);
  digitalWrite(in1, HIGH);

}


void loop(){

    // прочитать входной контакт кнопки:
    buttonState = digitalRead(BUTTON_PIN);
    unsigned long currentMillis = millis();

    // если кнопка нажата, включить реле (если оно еще не было включено) и сбросить таймер
    if( buttonState==LOW ) // нет необходимости проверять предыдущее состояние, в этом конкретном случае
    {
        previousMillis = currentMillis;
        digitalWrite(in1, LOW);
        digitalWrite(greenLED, HIGH);
        digitalWrite(redLED, LOW);
        relayOn = true;
    }

    // если реле в данный момент включено...
    if( relayOn )
    {
        // включить красный светодиод, если близко к отключению реле
        if (currentMillis - previousMillis >= interval-redLedInterval )
            digitalWrite(redLED, (millis()/300)%2);//мигает красный светодиод; 300 мс включено; 300 мс выкл.

        // если прошло достаточно времени, включаем реле
        if (currentMillis - previousMillis >= interval) 
        {
            // .. поворот реле
            digitalWrite(in1, HIGH);
            digitalWrite(greenLED, LOW);
            digitalWrite(redLED, LOW);
            relayOn = false;
        }
    } 
}

Дополнительным преимуществом здесь является то, что таймер никогда не истечет, если кнопка будет нажата постоянно.