Проблема с увеличением ШИМ с течением времени

float pwmDelta=((255/100)*(highLim-lowLim))/(tLim);

Эта строка должна быть:

float pwmDelta=((255.0/100)*(highLim-lowLim))/(tLim);

Добавление .0 сообщает компилятору, что нужно выполнить эту математику, используя числа с плавающей запятой, и вы получите 2,55. Без него математика выполняется с помощью int, и результат равен 1, что вам не нужно.

analogWrite(motor1, 53.55); 

Просто напишите 54. AnalogWrite принимает только целые значения.

analogWrite(motor1, motorPWM=165.75);

Вы действительно должны сделать это двумя строками, заданием и аналоговой записью. Такой способ приводит к запутанному коду. Кроме того, AnalogWrite принимает только целые значения, поэтому ваши десятичные числа также бесполезны.

Вы пытаетесь плавно увеличить значение ШИМ с 21 % до 65 % в течение 30 секунд с интервалом в 1 секунду, что не очень хорошо работает, поскольку значение ШИМ должно быть байтом.

Это означает, что значение, записанное в регистр ШИМ, изменится с 21*255/100 на 65*255/100, то есть с 53,55 на 165,75.

Используйте значения 53 и 166, что даст разницу в 113.

Ваш код написан для обновления значения ШИМ каждые 1000 мс, что дает 30 шагов, большинство из которых не являются целыми числами.

Вместо этого увеличьте значение ШИМ на 113 шагов. Каждый шаг будет целым числом, и каждый шаг будет иметь длину 265 486 мкс.

В предыдущих ответах уже была указана основная проблема с программой. Здесь я предлагаю несколько предложений, которые, надеюсь, еще можно улучшить. это:

• Вместо использования delay() вы можете управлять временем с помощью millis(). Это сделает рампу более плавной, и вы сможете добавьте код в цикл, если это необходимо, который не будет заблокирован задержки.
• Сохранение времени в миллисекундах и значения ШИМ в естественном виде. единицы (а не проценты) упрощают код.
• Удалите лишние переменные, такие как motorDelta, которые одинаковы как MotorPWM.
• Последовательный отступ и удаление лишних скобок помогают читабельность.

Вот моя попытка реализовать эти предложения:

const int motor1 = 3;  // контакт для выхода ШИМ на двигатель
const unsigned long tLim = 30000;  // продолжительность рампы ШИМ
const float PWM_unit = 255.0/100;  // преобразовать проценты в шкалу ШИМ
const float lowLim = PWM_unit * 21;
const float highLim = PWM_unit * 65;
const float PWM_rate = (highLim-lowLim) / tLim;

unsigned long start_time;  // начало рампы
int previousPWM = 0;

void setup() {
    pinMode(motor1, OUTPUT);
    analogWrite(motor1, round(lowLim));
    delay(20000);
    Serial.begin(9600);
    Serial.println(" t   PWM");
    Serial.println("--------");
    start_time = millis();
}

void loop() {
    unsigned long t = millis() - start_time;

    if (t >= tLim) {  // мы закончили
        analogWrite(motor1, round(highLim));
        delay(60000);  // держать на highLim в течение 60 с
        analogWrite(motor1, 0);  // затем останавливаемся
        exit(0);
    }

    int motorPWM = round(lowLim + t * PWM_rate);
    if (motorPWM != previousPWM) {
        analogWrite(motor1, motorPWM);
        Serial.print(t / 1000.0);
        Serial.print("  ");
        Serial.println(motorPWM);
        previousPWM = motorPWM;
    }
}

Происходит следующее: вы записали дробь таким образом, что компилятор интерпретирует ее как целочисленную математику. C/C++ усекает дроби, поэтому 255/100 — это всего лишь 2 (и если какие-либо из остальных являются целыми числами, они также вызывают усечение). Что вам нужно сделать, так это сделать какое-то число в этом вычислении десятичным — не имеет значения, какое именно — или преобразовать входные данные в число с плавающей запятой с (float) somevariable.

Пока все это находится в одной строке, все задействованные вычисления (за исключением порядка операций, поэтому приведите одну из разделяемых переменных к числу с плавающей запятой, если они указаны в отдельных терминах в скобках) будут быть с плавающей запятой. Обратите внимание, что если вы зададите здесь значение целого числа, оно будет усечено только после точных математических вычислений, так что это более правильно.

float pwmDelta = ((255/100)*(highLim-lowLim))/(tLim);

Должно быть:

float pwmDelta = 2,55*(highLim-lowLim)/(float)tLim; (Это также делает все это одним термином.)