Отправить последние 10 минутные данные по Bluetooth

Ваш код не имеет большого смысла в том виде, в каком он написан.

Вам необходимо:

Собирайте новое значение каждые 30 секунд и сохраняйте его в массив значений, увеличивая переменную "индекс текущего значения" с каждым считыванием.

Вы хотите инициировать отправку буфера, заполненного данными, когда массив заполнен, или с помощью команды с удаленного телефона? Если вы хотите запустить отправку с телефона, что бы вы сделали, если бы не было полного буфера данных? Что бы вы сделали, если буфер заполнится, а с телефона не будет отправлена команда?

Предполагая, что вы отправляете полный буфер данных каждый раз, когда он доступен, просто подождите, пока индекс массива не достигнет конца. Когда это произойдет, передайте весь буфер данных на телефон и сбросьте индекс массива, чтобы начать сбор новых данных.

Если вы хотите запустить отправку с телефона, вам придется обрабатывать крайние случаи, такие как переполнение буфера или попытка отправки до того, как у вас будет полный буфер данных. Я бы предложил создать массив больше, чем вам нужно (скажем, 100 значений), сделать его кольцевым буфером (погуглите его) и непрерывно сохранять новые значения до тех пор, пока кольцевой буфер не заполнится. Если скетч получает команду "отправить", он может проверить, есть ли у него по крайней мере 20 значений в буфере, и отправить их/удалить их из буфера, если это так, или отправить обратно сообщение "недостаточно собранных данных", если нет.

То, что вам нужно для этого проекта, называется кольцевым буфером. Прежде чем прочитать остальную часть этого ответа, я предлагаю вам остановиться и внимательно прочитать страницу Википедии, на которую я ссылаюсь.

Вы это читали? Хорошо! Теперь ваш случай несколько особенный, поскольку вам не нужно постоянно отслеживать как указатель чтения, так и указатель записи : вам нужен только указатель записи, так как чтение происходит в одном большом пакете.

Как только ваш кольцевой буфер заполнится, вы начнете перезаписывать самые старые показания, те, которым более 10 минут. Когда программе будет дано указание сбросить данные, она отправит весь буфер, начиная с ячейки, на которую указывает указатель записи (ячейка, содержащая самую старую точку данных и которая должна была быть перезаписана).

Есть один особый случай, о котором нужно позаботиться. Что делать, если программа получит команду для сброса данных, пока в ней хранится менее 20 показаний? Вы можете решить, что это ошибка пользователя, и программа может выдавать мусор. Однако я предлагаю, чтобы программа могла обнаружить эту ситуацию, а затем отправлять только действительные данные. Для этого ему необходимо сохранить логическую переменную, чтобы запомнить, был ли буфер заполнен или нет.

Вот реализация, которую я предлагаю для такого кольцевого буфера, вместе с функциями для добавления элемента и для сброса всех данных через последовательный порт:

const uint32_t READING_PERIOD = 30000;  // one reading every 30 s
const int MAX_READINGS = 20;           // 20 readings = 10 min

int readings[MAX_READINGS];  // ring buffer
uint8_t reding_index = 0;    // next available slot
bool readings_full = false;  // did we fill the ring buffer?

static void register_reading(int value) {
    readings[reding_index] = value;
    if (++reding_index >= MAX_READINGS) {
        readings_full = true;
        reding_index = 0;
    }
}

static void dump_readings() {
    // If the buffer is full, then the next avaiable slot is the oldest
    // reading in the buffer.
    if (readings_full) {
        for (int i = reding_index; i < MAX_READINGS; i++)
            Serial.println(readings[i]);
    }
    for (int i = 0; i < reding_index; i++)
        Serial.println(readings[i]);
}

Теперь основная программа довольно проста. Вы засекаете данные, полученные с помощью техники, показанной в руководстве "Мигание без задержки". Вы не хотите использовать функцию delay (), потому что, когда программа задерживается, она не может отвечать на ваши команды. Остается последний вопрос: когда он сбрасывает данные, должен ли он забыть об этом? Другими словами, если вы дважды попросите его сбросить данные с интервалом менее 10 минут, должен ли он предоставить повторные данные во второй раз или должен предоставить только свежие данные? В приведенном ниже коде я предполагаю более поздний вариант и, таким образом, сбрасываю буфер, но в конце концов это ваш выбор:

void setup() {
    Serial.begin(9600);
}

void loop() {
    // Периодически проводите чтение.
    static uint32_t last_reading_time;
    if (millis() - last_reading_time >= READING_PERIOD) {
        last_reading_time += READING_PERIOD;
        register_reading(analogRead(A0));
    }

    // Сбросьте данные по команде.
    if (Serial.read() == 't') {
        dump_readings();
        reding_index = 0;       // reset the buffer
        readings_full = false;  // ditto
    }
}