я не могу работать над своим небольшим проектом

В настоящее время вы переключаетесь в состояниях кнопок и снова переключаете их непосредственно на светодиоды. Таким образом, состояние светодиодов точно соответствует состоянию кнопок.

Как объяснил jsotola в комментариях, вам нужно отделить то, что вы получаете в качестве ввода (кнопки и последовательный), от того, что вы задаете в качестве вывода. Для этого вам понадобится 1 или более переменных для хранения состояния светодиодов (вашего выхода) и состояния каждого входа (например, каждой кнопки). Последнее - это то, что у вас есть в переменной копирования. Это похоже на состояние ввода кнопок. Теперь создайте новую переменную byte ledstates;. Функция shift_out() должна вызываться с помощью этой переменной, а не с помощью copy.

Теперь, когда ввод и вывод разделены, вы можете посмотреть на желаемое поведение для ввода. Поскольку нажатие 1 кнопки (нажатие и отпускание) должно переключать состояние соответствующего светодиода, вам нужно искать переход от НИЗКОГО уровня к ВЫСОКОМУ. Распространенный способ - сохранить текущее состояние кнопок в переменной. Затем при следующем выполнении функции shift_in() вы можете проверить, выполняется ли переход от НИЗКОГО к ВЫСОКОМУ предыдущему состоянию (сохраненному в переменной) и новому измеренному состоянию (ранее НИЗКОЕ, теперь ВЫСОКОЕ). Это нажатие кнопки, которую вы можете использовать для переключения соответствующего бита светодиода во вновь созданной переменной ledstates. Сохраните новое измеренное состояние в переменной копирования. (Кстати: вам следует переименовать переменную копирования во что-то более описывающее)

Также вам нужно рассмотреть механизм, с которым вам не пришлось возиться с предыдущим кодом: отскок кнопки. Механический переключатель или кнопка не сделают ни одного чистого перехода при нажатии. Механический контакт немного отскочит, что приведет к очень быстрым переходам от ВЫСОКОГО к НИЗКОМУ, пока кнопка не будет установлена. Если вы не учтете это в своей программе, вы получите множество переходов и, таким образом, будете много раз переключать светодиод только одним нажатием кнопки. Есть много способов решить эту проблему (и все они могут быть легко прогуглены). Я бы пошел по пути "не чувствую никаких дальнейших переходов после первого в течение определенного времени". Это может быть сделано простым вызовом функции delay() в конце вашей функции shift_in () (не так элегантно, с некоторыми оговорками) или с помощью millis() для создания неблокирующего тайм-аута (в лучшем случае для каждой кнопки в отдельности) (Посмотрите на пример BlinkWithoutDelay, который поставляется с Arduino IDE. Стоит изучить этот принцип).

Итак, у вас есть что-то вроде этого (не полный код, просто некоторые подсказки):

byte copy;
byte ledstates;

void loop(){
    if (Serial.available()>0){
        message();
    }
    shift_In();
    shift_out(ledstates);
}

void shift_in(){
    digitalWrite(CLKI,HIGH);
    digitalWrite(LD,HIGH);
    digitalWrite(LD,LOW);
    digitalWrite(LD,HIGH);
    digitalWrite(CLK,HIGH);
    digitalWrite(CLKI,LOW);
    byte buttonstates = shiftIn(SO,CLK,MSBFIRST); //read button states in a local variable
    digitalWrite(CLKI,HIGH);
    for(int i=0;i<8;i++){ // loop through all 8 bits of the buttonstates
        if(!(copy & (1<<i)) && (buttonstates & (1<<i))){ // check if old button state (in copy) is zero and new buttonstate is 1 (for the currently check bit)
            ledstates ^= 1<<i; // toggle the corresponding bit in the ledstates variable (will be shifted out later in the loop() function)
        }
    }
    copy = buttonstates;
    delay(10); // delay for debouncing
}

Как упоминалось выше, мы разделили ввод и вывод. Теперь легко также реализовать подходящее управление Bluetooth. Вы хотите, чтобы соответствующий индикатор включался на последовательном входе (через Bluetooth) и автоматически гас через определенное время. Для этого лучше всего использовать millis() с меткой времени. Сначала мы возьмем функцию message (). Мы определяем 2 переменные в глобальной области (вне любой функции в начале программы) для хранения метки времени нашей последней последовательной связи и байта для хранения светодиодов, которые активируются через последовательный. В функции message() мы теперь устанавливаем соответствующий бит в этой последней переменной. Если последовательные данные были неверными, мы просто возвращаемся из функции (это делает код короче). В конце функции мы гарантируем, что каждый светодиод, установленный в нашей переменной, также будет установлен в нашей переменной ledstates, которая затем будет смещена. И, наконец, мы сохраняем метку времени с помощью функции millis (), которая возвращает количество миллисекунд с момента запуска.

unsigned long bt_leds_timestamp=0;
byte bt_leds_activated=0;

void message(){
  if(Serial.available()){      // Отправляйте данные только тогда, когда вы получаете данные:
    char data = Serial.read();        //Считывание входящих данных и сохранение в данные
    Serial.print(data);          //Значение печати внутри данных в последовательном мониторе

    switch (data){
      case 'A' :
        bt_leds_activated |= 1;
        break; 
      case 'B' :
        bt_leds_activated |= 2;
        break;
      case 'C' :
        bt_leds_activated |= 4;
        break;
      case 'D' :
        bt_leds_activated |= 8;
        break;
      case 'E' :
        bt_leds_activated |= 16;
        break;
      case 'F' :
        bt_leds_activated |= 32 ;
        break;
      case 'G' :
        bt_leds_activated |= 64;
        break;
      case 'H' :
        bt_leds_activated |= 128;
        break;
      default   : return; }    
  }
  ledstates |= bt_leds_activated;
  shift_out(ledstates);
  bt_leds_timestamp = millis();
}

Теперь соответствующие светодиоды включаются, но не выключаются. Поэтому нам нужно поместить следующий код в функцию main loop ():

if(bt_leds_activated && millis()-bt_leds_timestamp > 2000){
  ledstates &= ~bt_leds_activated;
  shift_out(ledstates);
  bt_leds_activated = 0;
}

Этот код проверяет, был ли активирован какой-либо светодиод через Bluetooth (первая часть условия if принимает значение true, если значение bt_leds_activated отличается от нуля) и прошло ли определенное время (здесь 2 секунды, или 2000 мс) с момента снятия метки времени. Когда придет время, то биты светодиодов из bt_leds_activated, которые мы установили ранее, будут очищены вledstates, чтобы выключить светодиоды. Затем это смещается, чтобы установить фактическое состояние светодиодов, чтобы мы могли видеть. Наконец, мы сбрасываемзначение bt_leds_activated` до нуля, так как у нас больше нет светодиодов, которые можно было бы автоматически включать, пока не поступят новые данные.

У этого есть 1 предостережение: когда вы отправляете новые данные по Bluetooth в течение этих 2 секунд, время ожидания для светодиодов, ранее активированных по Bluetooth, также будет сброшено, чтобы они горели дольше. Способ обойти это-использовать 1 метку времени для каждого светодиода, но я подумал, что сейчас это сложно. Не хотите этого, вы можете реализовать эту часть самостоятельно, как я сделал со всеми ними вместе.

Примечание: Я никоим образом не тестировал этот код.