Счет времени с использованием миллисекунд

Миллис измеряет время. Вы можете сохранить эту меру и сравнить ее позже. Я не знаю, что в вашем коде представляет собой ощущение темноты/света в вашем коде (резисторы могут использоваться для повышения или понижения измеренного входа в зависимости от вашей схемы), поэтому вам придется работать следующим образом, заменяя вещи в < ;>

unsigned long lastlight;
void loop()
{
    if (<isLitSensorA>) lastlight = millis();
    if (<isLitSensorB>) lastlight = millis();
    if(millis() - lastlight > 3000){ //3 секунды с момента lastlight
        <LightsAlwaysOn>
    }
    else{
        <BlinkWithLights>
    }
}

Это один из тех случаев, когда решение состоит в том, чтобы просто реализовать конечный автомат. Рассмотрим конечный автомат с этими тремя состояния:

• СВЕТ: свет был обнаружен хотя бы одним из датчиков, Светодиоды следуют за датчиками света.
• SHORT_DARK: ни один датчик не видит свет, оба светодиода не горят
• LONG_DARK: прошло не менее трех секунд с тех пор, как ни один датчик увидел свет, оба светодиода горят.

Переходы между этими состояниями можно изобразить следующим образом. диаграмма состояний:

где «обнаружена темнота» означает, что ни один датчик не видит свет, а «свет обнаружен» означает, что по крайней мере один датчик видит свет.

Как правило, рекомендуется всегда рисовать диаграмму состояний прежде чем вы начнете писать код. Как только вы убедитесь, что ваша диаграмма описывает желаемое поведение, почти тривиально перевести его в код. Вот как я бы это закодировал:

void loop()
{
    bool light_k = analogRead(IN_K) >= 1000;
    bool light_d = analogRead(IN_D) >= 1000;

    static enum { LIGHT, SHORT_DARK, LONG_DARK } state;
    static uint32_t darkness_start;
    switch (state) {
    case LIGHT:
        digitalWrite(OUT_K, light_k ? HIGH : LOW);
        digitalWrite(OUT_D, light_d ? HIGH : LOW);
        if (!light_k && !light_d) {
            darkness_start = millis();
            state = SHORT_DARK;
        }
        break;
    case SHORT_DARK:
        if (light_k || light_d) {
            state = LIGHT;
        } else if (millis() - darkness_start >= 3000) {
            digitalWrite(OUT_K, HIGH);
            digitalWrite(OUT_D, HIGH);
            state = LONG_DARK;
        }
        break;
    case LONG_DARK:
        if (light_k || light_d) {
            state = LIGHT;
        }
        break;
    }
}

Вот более элегантный способ сделать это. Эта программа не требует, чтобы вы действительно считали, когда было темно, вместо этого она просто запоминает время, когда в последний раз видела свет (как поэтично ;). Я также добавил некоторые комментарии к коду.

// Все переменные
int k = 2;        // светодиод 1
int d = 3;        // светодиод 2
int fk = A0;      // фоторезистор 1
int fd = A1;      // фоторезистор 2
int lastLight = 0;

// Настраиваем светодиоды
void setup() {
  pinMode(k, OUTPUT);
  pinMode(d, OUTPUT);
}

void loop()
{
  // Проверяем фоторезисторы
  int a = analogRead (fk);
  int b = analogRead (fd);
  if (a > 1000 || b > 1000)
  {
    // Включаем светодиоды, если один фоторезистор чувствует свет
    digitalWrite(k, HIGH);
    digitalWrite(d, HIGH);
    // Также установить время, когда в последний раз было светло, на текущее время
    lastLight = millis();
  }
  else if (abs(millis() - lastLight) > 3000)
  {
    // Включаем светодиоды, если темно более 3 секунд (то есть 3000 миллисекунд)
    digitalWrite(k, HIGH);
    digitalWrite(d, HIGH);
  }
  else
  {
    // Выключаем светодиоды
    digitalWrite(k, LOW);
    digitalWrite(d, LOW);
  }
}