Включить светодиодный индикатор, если значение датчика влажности >= MaxDryness в течение более 20 минут.

Ниже приведен пример того, как это можно закодировать.

Помните, что почва сухая, установив DrySoil = true.

Зарегистрируйте время начала засушливого периода в DrySoilBegin.

Проверяйте при каждом «сухом» показателе, было ли значение DrySoil верным в течение более 20 минут.

Устанавливайте DrySoil = false при каждом показании «не сухости».

ul после константы 1200000 делает ее длинным значением без знака. Это потому, что millis() возвращает результат unsigned long. Я не уверен на 100%, что это необходимо (возможно, компилятор позаботится об этом автоматически).

Поскольку у меня нет системы полива растений, я не смог проверить ее работу.

#define WATERPIN 10
#define READSOILPIN A0
#define LEDPIN 13

// чем больше число, тем суше
#define MAXDRYNESS 700

#define WATERDELAY 10000
#define WATERPOSTDELAY 5000

bool DrySoil = false; // Состояние почвы
unsigned long DrySoilBegin; // Время, когда DrySoil стал правдой

void setup() {
  Serial.begin(9600);
  pinMode(READSOILPIN, INPUT);
  pinMode(WATERPIN, OUTPUT);
  pinMode(LEDPIN, OUTPUT);
}

void loop() {
  int SensorValue = analogRead(READSOILPIN); //взять образец
  Serial.print(SensorValue);
  Serial.print(" ־ ");

  if(SensorValue >= MAXDRYNESS) {
    // Почва слишком сухая
    // Проверяем, была ли почва уже в сухом состоянии
    if(DrySoil){
      // Если уже в сухом состоянии, проверьте продолжительность
      if((millis()-DrySoilBegin) > 1200000ul){
        // Если продолжительность превышает 20 минут, включаем светодиод
        // или оставить светодиод включенным
        digitalWrite(LEDPIN, HIGH);
      }
    }
    else{
      // Первый «сухой» результат после «мокрых» результатов
      DrySoil = true; // Устанавливаем DrySoil в истинное состояние
      DrySoilBegin = millis(); // Устанавливаем начало периода DrySoil
    }
    // начинаем поливать в течение 10 секунд, затем
    // ждем 5 секунд перед повторным мониторингом
    Serial.println("Soil dry start watering");
    digitalWrite(WATERPIN, HIGH);
    delay(WATERDELAY); // ждем, пока пройдет WATERDELAY миллисекунд
    digitalWrite(WATERPIN, LOW);
    delay(WATERPOSTDELAY); // ждем, пока пройдут миллисекунды WATERPOSTDELAY
  }
  else{
    // Почва не слишком сухая
    DrySoil = false; // Устанавливаем или сохраняем DrySoil в состоянии false
    digitalWrite(LEDPIN, LOW); // Выключаем светодиод или оставляем его выключенным
    delay(50); // Подождите 50 мс перед следующей выборкой
  }
}

Вот небольшой пример, как это сделать. Адаптируйтесь таким образом (если хотите) самостоятельно.

// ГЛОБАЛЬНЫЕ ПЕРЕМЕННЫЕ
unsigned long lowSensorTick = 0;
bool dry = false;

void loop()
{
    if (analogRead(/* PIN */) > /* THRESHOLD VALUE */)
    {
        // СУХОЙ
        if (dry == false)
        {
            lowSensorTick = millis();
            dry = true;
        }
        else
        {
            if (millis() - lowSensorTick > 720000) // 720000мс = 12мин * 60000мс (1с = 1000мс)
            {
                digitalWrite(LED_PIN, HIGH); // СВЕТОДИОД ЗАГОРИТСЯ/ВКЛ.
            }
        }
    }
    else
    {
        // ВЛАЖНЫЙ
        dry = false;
        digitalWrite(LED_PIN, LOW); // СВЕТОДИОД ГОРИТ/ВЫКЛЮЧАЕТСЯ
    }
}