Двоичная адресация и кодирование для управления матрицей мультиплексирования с 96 входами

Хорошо. Сначала о том, как работает мультиплексор. У меня есть страница о мультиплексорах, на которой есть такой пример 74HC4051:

В зависимости от «бинарного» входа A/B/C (обозначенного на схеме как S0/S1/S2) между одним из восьми входов и единственным выходом существует низкоомный путь. CD74HC4067 работает аналогично, но коммутирует 16 входов.

Таким образом, если вы устанавливаете двоичное число 2 (010) в A/B/C, то выбирается третий вход (число 02, поскольку оно относительно нуля).

В вашей схеме есть 6 микросхем CD74HC4067, которые, таким образом, могут иметь 16 x 6 входов (всего 96 входов). Выходы этих 6 микросхем подаются на 54HC4051 (2 не используются), поэтому 54HC4051 может выбрать, какая из 6 микросхем с 16 входами ему нужна в данный момент, установив число от 0 до 5 на 8-входовом мультиплексоре.

Как вы можете видеть на схеме, все четыре двоичных входа 6 x CD74HC4067 соединены вместе.

Таким образом, ваш метод будет следующим:

• Пройдите цикл от 0 до 5 на главном мультиплексоре (54HC4051). Это позволит выбрать, какой из шести 16-входовых мультиплексоров вас интересует в данный момент.

• Для каждого из них выполните цикл от 0 до 15 на S0/S1/S2/S3 так, чтобы текущий выбранный CD74HC4067 направил свой вход на свой выход.

• Прочитайте полученное значение

Эти два цикла дадут вам 96 входных данных, что вы и пытаетесь прочитать.

Для вывода двоичных чисел (3 бита плюс 4 бита) в этом методе требуется 7 выходных контактов. Также требуется один входной контакт для считывания результата.

Судя по схеме, он использует SPI (последовательные данные) для управления шестью сдвиговыми регистрами TLC5940, что позволяет включать и выключать светодиоды с помощью всего двух управляющих выводов (SCK и MOSI, на вашей схеме обозначены как SCLK и SOUT).

Чипы соединены последовательно, поэтому все TLC5940 управляются этими двумя контактами.

Поэтому этот довольно минималистичный дизайн оставил несколько запасных контактов на Arduino Pro.

В основном мне сложно визуализировать код, особенно как правильно написать 7 команд записи двоичных цифровых данных. Не могли бы вы исправить то, что я написал выше, чтобы я мог увидеть закономерность?

Я знаю, что к тому времени, как я это увидел, вы уже изменили вопрос, но код ниже иллюстрирует то, что я подразумеваю под двумя циклами:

const int MUX_CHIPS = 6;
const int LEDS_PER_CHIP = 16;
const int TOTAL_IR_INPUTS = MUX_CHIPS * LEDS_PER_CHIP;
// Контакты главного ИК-мультиплексорного датчика для Arduino Pro MINI
const byte  M_S0 = 2;
const byte  M_S1 = 4;
const byte  M_S2 = 5;
// Контакты ведомого ИК-мультиплексора
const byte  S_S0 = 6;
const byte  S_S1 = 7;
const byte  S_S2 = 8;
const byte  S_S3 = 12;
// АНАЛОГОВЫЙ ВЫВОД:
const byte INPUT_FROM_MUX = A0;

int  recv_state[TOTAL_IR_INPUTS];           // Показания ИК-приемника - ИЗ настройки мультиплексора

void setup() {
    Serial.begin(115200);

    // НАСТРОЙКА АДРЕСНЫХ ПИН-КОДОВ
    pinMode(M_S0, OUTPUT);
    pinMode(M_S1, OUTPUT);
    pinMode(M_S2, OUTPUT);

    pinMode(S_S0, OUTPUT);
    pinMode(S_S1, OUTPUT);
    pinMode(S_S2, OUTPUT);
    pinMode(S_S3, OUTPUT);
    pinMode(INPUT_FROM_MUX, INPUT); 

    // установить предделитель АЦП на 32
    ADCSRA &= ~(bit (ADPS0) | bit (ADPS1) | bit (ADPS2)); // очистить биты предварительного делителя
    ADCSRA |= bit (ADPS0) | bit (ADPS2);                 // 32
} // конец настройки


void loop() {

  unsigned long start = micros ();

  // считывание с ИК-диодов

  int whichLED = 0;
  for (byte master = 0; master < MUX_CHIPS; master++)
    {
    // выбрать соответствующий ведомый на главном MUX
    digitalWrite(M_S2, (master & 0b100) ? HIGH : LOW);
    digitalWrite(M_S1, (master & 0b010) ? HIGH : LOW);    
    digitalWrite(M_S0, (master & 0b001) ? HIGH : LOW);

    // считываем показания каждого подчиненного устройства
    for (byte slave = 0; slave < LEDS_PER_CHIP; slave++)
      {
      digitalWrite(S_S3, (slave & 0b1000) ? HIGH : LOW);       
      digitalWrite(S_S2, (slave & 0b0100) ? HIGH : LOW);
      digitalWrite(S_S1, (slave & 0b0010) ? HIGH : LOW);
      digitalWrite(S_S0, (slave & 0b0001) ? HIGH : LOW);

      // сохранить это показание
      recv_state [whichLED++] = analogRead (INPUT_FROM_MUX);

      } // конец для каждого подчиненного
    } // конец для каждого мастера

  // отобразить результаты здесь ...

} // цикла

Точный код выше потребовал 5148 мкс (около 5 мс) для выполнения цикла на моём Uno. Если убрать ускорение АЦП (analogRead), то это займёт 13252 мкс (13 мс).

Чтобы обеспечить точное подключение, вам нужно игнорировать младший бит на главном мультиплексоре, поскольку вы не используете вход A0_13; в этом случае вам нужно добавить 2 к главному значению во внешнем цикле:

    // выбрать соответствующий ведомый узел на главном MUX
    byte master_plus_2 = master + 2;  // разрешить не использовать вход A0
    digitalWrite(M_S2, (master_plus_2 & 0b100) ? HIGH : LOW);
    digitalWrite(M_S1, (master_plus_2 & 0b010) ? HIGH : LOW);    
    digitalWrite(M_S0, (master_plus_2 & 0b001) ? HIGH : LOW);