Как считать показания датчика звука и включить датчик с датчиком воды, если показания выше порогового значения и при обнаружении воды в течение 2 минут?

На самом деле это намного сложнее, чем может показаться на первый взгляд.

Ваш «датчик звука» — это не что иное, как микрофон и усилитель. Он дает вам форму звукового сигнала, тогда как вас интересует пиковая мощность.

Аудиосигнал бывает как положительным, так и отрицательным:

Пик сигнала может быть как положительным (над линией), так и отрицательным (ниже линии).

Чтобы получить этот пик, вам нужно быстро выполнить выборку за короткий период времени и найти как максимальное, так и минимальное значения, а также получить разницу между ними.

Однако Arduino не может видеть отрицательные значения на АЦП, поэтому вы получаете только верхнюю часть сигнала, что не идеально. На самом деле вам следует добавить смещение постоянного тока к выходу звукового датчика, чтобы довести сигнал до середины диапазона АЦП (добавление делителя напряжения 10 кОм + 10 кОм на входном контакте к +5 В/GND сделает эту работу). /п>

Если вы не добавляете смещение постоянного тока, вы можете быстро выполнить выборку в течение короткого периода времени и определить максимальное значение:

uint16_t getMaximum(uint8_t pin, uint32_t t) {
    uint16_t maximum = 0;
    uint32_t ts = millis();
    while (millis() - ts < t) {
        uint16_t sample = analogRead(pin);
        if (sample > maximum) {
            maximum = sample;
        }
    }
    return maximum;
}

Теперь, чтобы получить максимум за период, скажем, 10 мс, вы можете:

uint16_t maximum = getMaximum(A0, 10);

Однако, если вы добавите смещение постоянного тока, это станет немного сложнее, но результат будет лучше:

uint16_t getMaximum(uint8_t pin, uint32_t t) {
    int16_t maximum = 0;
    int16_t minimum = 0;
    uint32_t ts = millis()
    while (millis() - ts < t) {
        // Здесь -512 удаляет смещение постоянного тока из показаний. 512 это половина
        // диапазон АЦП.
        int16_t sample = analogRead(pin) - 512;
        if (sample > maximum) {
            maximum = sample;
        }
        if (sample < minimum) {
            minimum = sample;
        }
    }

    // Теперь у нас есть положительное значение как максимальное и отрицательное
    // как минимум или ноль, если ни один из них не достиг максимума или минимума
    // область сигнала. Вычесть негатив из позитива
    // это похоже на добавление позитива к позитиву. Но мы хотим только
    // положительный результат, поэтому мы получим абсолютное значение.
    return abs(maximum - minimum);
}

Теперь, когда у вас действительно есть пиковое значение вашей формы сигнала за короткий период, вы можете использовать его, чтобы определить, когда звук превышает пороговое значение, а когда он опускается ниже, а также как долго он находился выше этого порога. Основной метод:

• Звук выше порога?
  • Да: раньше было выше порогового значения?
  • Нет: установите временную метку и флаг, указывающие на превышение порогового значения.
  • Да: прошло ли более 2 минут?
    • Да: зажгите светодиод.
  • Нет. Было ли это раньше выше порогового значения?
  • Да: прошло ли более 2 минут?
    • Да: погасить светодиод.

Здесь важно знать, что вы ищете изменения в состоянии «выше порога», чтобы начать отсчет времени. Простая реализация может выглядеть так:

static uint32_t wentAbove = 0;
static bool isAbove = false;
const uint16_t threshold = 300;

uint16_t maxval = getMaximum(A0, 10);

if (maxval > threshold) {
    if (!isAbove) {
        isAbove = true;
        wentAbove = millis();
    } else {
        if (millis() - wentAbove > 120000) {
            digitalWrite(13, HIGH);
        }
    }
} else {
    if (isAbove) {
        isAbove = false;
        digitalWrite(13, LOW);
    }
}

_{Примечание: весь код не тестировался.}