ШИМ частотного сигнала?

Ваша несущая 14 кГц может быть сгенерирована функцией tone(), которая является частью ядра Arduino. Затем вы можете использовать библиотеку TimerOne для включения и выключения звукового сигнала.

Вот непроверенный пример скетча, демонстрирующий использование:

#include <TimerOne.h>

const uint8_t outpin=4;

void setup() {
  // поместите сюда свой код установки для однократного запуска:
  pinMode(outpin, OUTPUT);
  Timer1.initialize(1000);  // 1000 микросекунд на полупериод
  Timer1.attachInterrupt(toggleCarrier);
}

void loop() {
  // поместите сюда свой основной код для повторного запуска:

}

void toggleCarrier() {
  static uint8_t isPlaying;
  if (isPlaying) {
    noTone(outpin);
    isPlaying=0;
  } else {
    tone(outpin, 14000);
    isPlaying=1;
  }
}

На Arduino Mega (или Uno с заменой ATmega328P на ATmega328PB, но тогда вам придется немного адаптировать код) это можно сделать с помощью модулятора сравнения выходов:

void setup() {
  // CTC, OC0A переключение на совпадение сравнения, предварительный масштаб 1/8
  TCCR0A = _BV(COM0A0)|_BV(WGM01);
  TCCR0B = _BV(CS01);

  // переключение каждые 35,5 мкс при частоте 16 МГц и масштабе 1/8
  OCR0A = 70;

  // ШИМ с корректировкой фазы и частоты, TOP — OCR1A, OC1C очищается при повышении и установке при понижении, без предварительного масштабирования
  TCCR1A = _BV(COM1C1)|_BV(WGM10);
  TCCR1B = _BV(WGM13)|_BV(CS10);

  // период 2 мс при 16 МГц и без предварительного масштабирования
  OCR1A = 16000;

  // время включения 1 мс на частоте 16 МГц и без предварительного масштабирования
  OCR1C = 8000;

  // нет прерываний от таймеров
  TIMSK0 = 0;
  TIMSK1 = 0;

  // выводим 1 только тогда, когда оба таймера выдают 1
  PORTB &= ~_BV(PORTB7);

  // останавливаем таймеры и сбрасываем прескалер
  GTCCR |= _BV(TSM);
  GTCCR |= _BV(PSRSYNC);

  // сбрасываем оба таймера
  TCNT0 = 0;
  TCNT1 = 0;

  // включаем вывод
  DDRB |= _BV(DDB7);

  // позволяем таймерам работать
  GTCCR &= ~_BV(TSM);
}

void loop() {
  // Просто отрегулируйте частоты и рабочий цикл, как требуется здесь.
  // Все обрабатывается аппаратно и вступает в силу сразу после записи в регистр.
  // OCR1A: желаемый период более медленного сигнала, в 8-х микросекундах. Может быть до 65535.
  // OCR1C: желаемое время включения более медленного сигнала в 8-х микросекундах. Может быть до 65535.
  // OCR0A: на 1 меньше желаемого периода более быстрого сигнала в микросекундах. Может быть до 255.
  // Время включения более быстрого сигнала всегда равно половине периода.
  // При необходимости вы можете обменять точность на больший диапазон для любого из вышеуказанных значений, настроив прескалер.
}

В этом скетче контакт 13 на Mega будет иметь желаемую форму сигнала. У этого метода есть два больших преимущества. Во-первых, после настройки он вообще не требует никаких ресурсов ЦП (никаких циклов или прерываний), поэтому вы можете посвятить весь loop чтению потенциометра и настройке рабочего цикла, не беспокоясь о сбоях. на выходе. Во-вторых, полностью аппаратное управление означает, что его выходной сигнал будет точным и абсолютно последовательным (компонент 500 Гц идеален, а компонент 14 кГц составляет примерно 14085 Гц). Однако единственным недостатком является то, что millis и все остальное в библиотеке Arduino, использующее внутренние таймеры, не будет работать правильно, поскольку мы используем те же аппаратные таймеры, от которых они зависят.