разместить данные из узла mcu в базе данных sql

Question

разместить данные из узла mcu в базе данных sql

nodemcu

#include <ESP8266WiFi.h>

const char* ssid = "xxxx";
const char* password = "xxxxxxxxxx";

const char* host = "192.168.43.18";
const int ldr = A0;
int val = 0;

void setup()
{
  Serial.begin(9600);
  Serial.println();

  Serial.printf("Connecting to %s ", ssid);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED)
  {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" connected");
}


void loop()
{
  val = analogRead(ldr);
  WiFiClient client;

  Serial.printf("\n[Connecting to %s ... ", host);
  if (client.connect(host, 80))
  {
    Serial.println("connected]");
    client.println("POST /past.php HTTP/1.1");
    client.println("Host: 192.168.43.10");
    client.print(val);
    Serial.println(val);
    Serial.println("\n[Disconnected]");
  }
  else
  {
    Serial.println("connection failed!]");
    client.stop();
  }
  delay(5000);
}

Я загрузил этот код в node mcu, но он работает, но загруженные данные в моей базе данных не отображаются. Пожалуйста, кто-нибудь, помогите мне.

@vathsalhari, 👍0

Обсуждение

Я бы ожидал одну пустую строку после заголовков, а также заголовок Content-Length с фактической длиной val (его строковое представление, а не sizeof int!)., @KIIV

и остановить клиент после запроса, @Juraj

@Juraj В этом случае я бы ожидал, что деструктор позаботится об этом. Если нет, то это определенно ошибка в библиотеке., @KIIV

да, деструктор закрывает соединение. А зачем вы закрываете его в else? :-), @Juraj

IP-адреса не совпадают, @Juraj

3 ответа

@*Code Gorilla* · Answer 1 · 2018-06-07 11:48-00:00

Вы используете WIFIClient для отправки данных на HTTP-сервер. Я не думаю, что WiFiClient умеет правильно форматировать HTTP-запросы, поэтому вам нужно это сделать. Я думаю, что есть HTTPClient, который может сделать для вас больше.

Между заголовком и телом сообщения есть пустая строка, а также пустая строка в конце тела. Вам нужна строка с надписью `client.println();

Принимает ли "SQL-сервер" сообщение, содержащее только число? Откуда он знает, к чему относится число? Если у вас есть какой-то PHP-сайт на фронте DBS, который всем этим занимается, то, пожалуйста, проигнорируйте этот вопрос.

Возможно, вы захотите проверить, можете ли вы запустить Wireshark (или аналогичный) на своем ПК и посмотреть, что отправляет MCU, вы также можете взглянуть на надстройки Chrome. Я думаю, что есть некоторые, с помощью которых вы можете создавать необработанные пакеты и отправлять их на свой сервер, чтобы убедиться, что он отвечает так, как ожидается.

В качестве последнего средства вы, вероятно, могли бы набросать очень быструю и грязную программу C# с помощью Visual Studio Community Edition (бесплатно ) и заставить ее отправлять пакет на сервер. Использование этого в сочетании с Wireshark может быть проще, чем использование MCU, пока вы не поймете, что вам следует делать.

@*Brian Moreau* · Answer 2 · 2018-06-07 12:03-00:00

На самом деле вы не публикуете никаких данных. После client.println("POST /past.php HTTP/1.1"); Добавьте еще одну(ые) строку(и), например... клиент.println("?myvar=65dcsagh&anothervar=ghsadjkj78");

Также страница на сервере (past.php) должна иметь возможность получать и обрабатывать отправленные данные. Если использовать PHP, то это будет что-то вроде... $data = $_GET[myvar]; А затем PHP-код должен подключиться к вашей базе данных SQL и вставить ее с помощью mySQL

@*vathsalhari* · Answer 3 · 2018-06-08 18:53-00:00

Мой исправленный код, рабочий код:

#include <ESP8266WiFi.h>

const char* ssid = "vathsal";
const char* password = "1234567890";

const char* host = "wwwkprstaffcom.000webhostapp.com";
const int ldr = A0;
int val = 0;
String data;
void setup()
{
  Serial.begin(9600);
  Serial.println();

  Serial.printf("Connecting to %s ", ssid);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED)
  {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" connected");
}


void loop()
{
  val = analogRead(ldr);
  data = "ldr=";

  data.concat(val);
  WiFiClient client;

  Serial.printf("\n[Connecting to %s ... ", host);
  if (client.connect(host, 80))
  {
    Serial.println("connected]");
    client.println("POST /add.php HTTP/1.1");
    client.println("Host: wwwkprstaffcom.000webhostapp.com");
    client.println("Content-Type: application/x-www-form-urlencoded");
    client.print("Content-Length: ");
    client.println(data.length());
    client.println();
    client.print(data);
    Serial.println(val);
    Serial.println("\n[Disconnected]");
  }
  else
  {
    Serial.println("connection failed!]");
    client.stop();
  }
  delay(5000);
}