Хочу критики моего кода

if(digitalRead(greenLeft1) == LOW) {
    motorSpeed_left = 200;
    spinMotor_left(motorSpeed_left);
    delay(200);
    motorSpeed_left = 0;
    spinMotor_left(motorSpeed_left);
}
else if(digitalRead(greenLeft2) == LOW) {
    motorSpeed_left = -200;
    spinMotor_left(motorSpeed_left);
    delay(200);
    motorSpeed_left = 0;
    spinMotor_left(motorSpeed_left);
}

Не совсем то, что нужно.

Вместо этого вам нужно что-то вроде:

if(digitalRead(greenLeft1) == LOW) {
    motorSpeed_left = 200;
    spinMotor_left(motorSpeed_left);

} else if(digitalRead(greenLeft2) == LOW) {
    motorSpeed_left = -200;
    spinMotor_left(motorSpeed_left);
} else {
    motorSpeed_left = 0;
    spinMotor_left(motorSpeed_left);
}

Однако, поскольку вам также нужен главный выключатель и управление через последовательный порт, вы можете вынести тесты каждой кнопки в переменную, а затем заставить главный выключатель переопределять их:

int motor_left = 0;
if(digitalRead(greenLeft1) == LOW) {
    motor_left = 1;
} else if(digitalRead(greenLeft2) == LOW) {
    motor_left = -1;
} else {
    motor_left = 0;
}

//...

if(digitalRead(blueAll1) == LOW){
    motor_left   = 1;
    motor_center = 1;
    motor_right  = 1;
} else if(digitalRead(greenLeft2) == LOW) {
    motor_left   = -1;
    motor_center = -1;
    motor_right  = -1;
} 

if(motor_left > 0) {
    motorSpeed_left = 200;
    spinMotor_left(motorSpeed_left);

} else if(motor_left < 0) {
    motorSpeed_left = -200;
    spinMotor_left(motorSpeed_left);
} else {
    motorSpeed_left = 0;
    spinMotor_left(motorSpeed_left);
}

Кроме того, номер контакта — это просто int, поэтому вы можете вывести его как параметр и иметь только одну копию функции spinMotor.

void spinMotor(int motor_pin1, int motor_pin2, int motorSpeed)
{
  if (motorSpeed > 0)
  {
    digitalWrite(motor_pin1, HIGH);
    digitalWrite(motor_pin2, LOW);
  }
  else if (motorSpeed < 0)
  {
    digitalWrite(motor_pin1, LOW);
    digitalWrite(motor_pin2, HIGH);
  }
  else
  {
    digitalWrite(motor_pin1, LOW);
    digitalWrite(motor_pin2, LOW);
  }
  analogWrite(PWMA, abs(motorSpeed));
}

Чтобы сократить количество глобальных переменных, вы можете сгруппировать состояние каждого двигателя в структуру и инициализировать их в init():

struct motorState {
   int motor_pin1, motor_pin2;
   int pwm_pin;
   int button1, button2;
   int direction;
   int speed;
}

motorState motor_left;
motorState motor_center;
motorState motor_right;

затем передайте глобальные переменные по указателю или ссылке в функции, выполняющие ввод и вывод.

void readMotorButton(motorState *motor){
    if(digitalRead(motor->button1) == LOW) {
        motor->direction = 1;
        motor->speed = 200;
    } else if(digitalRead(motor->button2) == LOW) {
        motor->direction = -1;
        motor->speed = 200;
    } else {
        motor->direction = 0;
        motor->speed = 0;
    }
}

void spinMotor(motorState *motor)
{
  if (motor->direction > 0)
  {
    digitalWrite(motor->motor_pin1, HIGH);
    digitalWrite(motor->motor_pin2, LOW);
  }
  else if (motor->direction < 0)
  {
    digitalWrite(motor->motor_pin1, LOW);
    digitalWrite(motor->motor_pin2, HIGH);
  }
  else
  {
    digitalWrite(motor->motor_pin1, LOW);
    digitalWrite(motor->motor_pin2, LOW);
  }
  analogWrite(motor->pwm_pin, abs(motor->speed));
}

Здесь есть группа по обзору кода, где вы можете получить более общий обзор кода, если захотите.

Первое, что я заметил, — отсутствие комментариев. Вы написали абзац, объясняющий, что делает код, но это должно быть в самом коде, где вы сможете его прочитать, когда найдёте его через 12 месяцев.

Rachet Freak рассмотрел множество хороших моментов, но я не согласен с тем, что глобальные переменные передаются в функции через указатели. Я бы вместо этого использовал ссылки. Единственная причина для этого — если вы допустите ошибку, ссылки не могут быть равны NULL, поэтому вам не нужно проверять внутри функции, равны ли они NULL. Конечно, этого никогда не произойдёт, вы никогда не передадите NULL-указатель ни одной из этих функций, но по мере роста размера кода вероятность того, что вы это сделаете, будет увеличиваться. И если вы когда-нибудь напишете библиотеку, вероятность того, что кто-то другой передаст NULL-указатель в вашу библиотеку, очень высока, и тогда у вас возникнет «проблема в вашей библиотеке».

Дальше, если значение параметра не будет изменяться в течение жизненного цикла функции, передайте его как ссылку const. Основная причина этого в том, что это объясняет читателю, что значение не изменится в функции. Это простой способ задокументировать ваше намерение без необходимости писать комментарий. Итак,

void spinMotor(int motor_pin1, int motor_pin2, int motorSpeed){...}

стал бы

void spinMotor(const int& motor_pin1, const int& motor_pin2, const int& motorSpeed) {...}

Лично я бы всегда добавлял конструктор к структурам. Так вы будете уверены, что каждое поле изначально имеет правильное значение. (Я думаю, компилятор Arduino всё инициализирует, но не все компиляторы такие добрые.) Кроме того, это позволяет писать более аккуратный код, например,

struct motorState {
   int motor_pin1;
   int motor_pin2;
   int button1;
   int button2;
   int direction;

  // Параметризованный конструктор можно вызвать либо:
  // motorState mState;
  // motorState mState2 = motorState (2, 3, 4, 5, -1);
  motorState (const int& pin1 = 5, const int& pin2 = 6, const int& b1 = 7, const int& b2 = 8, const int& dir = 1)
  : motor_pin1(pin1)
  , motor_pin2(pin2)
  , button1(b1)
  , button2(b2)
  , direction(dir)
{}

}

Наконец, мне всегда говорили никогда не размещать два заявления на одной строке.

int motor_pin1, motor_pin2;

С точки зрения компилятора разницы между вышеизложенным и этим нет.

int motor_pin1; 
int motor_pin2;

Это сделано исключительно для удобства чтения, вы не осознаете, что делаете это, и чтение первого случая заняло больше времени, чем второго, поскольку ваш мозг более настроен на восприятие типа, имени переменной и необязательного значения.

int 
motor_pin1,
motor_pin2;

Вышеуказанное допустимо, но какой тип использовать в motor_pin2? Это просто широко распространённое соглашение, которое упрощает чтение кода, хотя и затрудняет его написание, подобно тому, как здесь нужно делать отступ в 4 пробела. Без отступа текст будет таким же, но читать его будет практически невозможно.

Наконец, если вы копируете и вставляете строки, вероятно, это должна быть функция или массив, или и то, и другое.