Определение того, была ли нажата и отпущена кнопка

Я согласен с Majenko, хотя ваш код будет работать, код блокирующий, то есть ваш код останавливается в этой точке, пока кнопка не будет отпущена снова. Оставшийся код в вашем цикле не выполняется, пока кнопка не будет разрешена.

Гораздо лучший метод — проверять состояние кнопки при каждом прохождении цикла. Если состояние меняется (т. е. становится низким), вы можете установить флаг. Затем, когда вы считываете, что кнопка снова находится в высоком состоянии и флаг был установлен, вы выполняете соответствующий код. Например:

const int buttonPin = 2;     // номер контакта кнопки
boolean buttonWasLow = false;         // переменный флаг для случая, когда кнопка переходит в состояние низкого уровня

void setup() {
    pinMode(buttonPin, INPUT);    // инициализируем вывод кнопки как вход:
}

void loop() {
    // считываем состояние кнопки и устанавливаем флаг, если оно низкое:
    if (digitalRead(buttonPin) == LOW)  {
        buttonWasLow = true;
    }

    // Этот оператор if сработает только по переднему фронту сигнала нажатия кнопки
    if (digitalRead(buttonPin) == HIGH && buttonWasLow)  {
        // сбросить флаг низкого уровня кнопки
        buttonWasLow = false;

        // Событие кнопки здесь
    }
}

Мой любимый способ обнаружения нарастающего фронта входного сигнала на самом деле гораздо проще:

void loop() {
    button = digitalRead(buttonPin);

    // Если кнопка нажата
    if (button && !buttonLast)
    {
        // Событие кнопки здесь
    }

    // Обновить флаг кнопки
    buttonLast = button;
}

user8886193 поднимает очень хорошую тему о устранении дребезга кнопок.

Дрожание — это тенденция любых двух металлических контактов в электронном устройстве генерировать несколько сигналов при замыкании или размыкании контактов; устранение дребезга — это любой вид аппаратного устройства или программного обеспечения, который гарантирует, что только один сигнал будет обработан при одном размыкании или замыкании контакта.

Я предпочитаю устранять дребезг входов кнопок аппаратно, добавляя 100 нФ (или больше) от входного контакта к земле. Обратите внимание, что для этого требуется сопротивление 10 кОм (или больше) последовательно с цепью кнопки, чтобы конденсатор заряжался/разряжался.

В качестве альтернативы, в программном обеспечении наиболее распространенным способом устранения дребезга для новичков является добавление задержки, например delay(100);, которая будет выглядеть примерно так:

void loop() {
    button = digitalRead(buttonPin);

    // Если кнопка нажата
    if (button && !buttonLast)
    {
        // Событие кнопки здесь
        delay(100);  // <---- Задержка вставлена после события кнопки
    }

    // Обновить флаг кнопки
    buttonLast = button;
} 

Недостатком этого является то, что он блокируется на 100 мс, пока выполняется задержка. Лучший метод — устранить дребезг без задержки. Один из встроенных примеров демонстрирует устранение дребезга кнопки. Основной цикл показан ниже:

void loop() {
    // считываем состояние переключателя в локальную переменную:
    int reading = digitalRead(buttonPin);

    // проверьте, нажали ли вы только что кнопку
    // (т.е. входной сигнал перешел из LOW в HIGH), и вы ждали достаточно долго
    // с момента последнего нажатия, чтобы игнорировать любой шум:

    // Если переключатель изменился из-за шума или нажатия:
    if (reading != lastButtonState) {
        // сбросить таймер устранения дребезга
        lastDebounceTime = millis();
    }

    if ((millis() - lastDebounceTime) > debounceDelay) {
        // независимо от показаний, они существуют дольше, чем дребезг
        // задержка, поэтому принимаем ее как фактическое текущее состояние:

        // если состояние кнопки изменилось:
        if (reading != buttonState) {
            buttonState = reading;

            // переключать светодиод только если новое состояние кнопки HIGH
            if (buttonState == HIGH) {
                ledState = !ledState;
            }
        }
    }

    // устанавливаем светодиод:
    digitalWrite(ledPin, ledState);

    // сохранить показания. В следующий раз в цикле это будет lastButtonState:
    lastButtonState = reading;
}

«Я обычно ставлю конденсатор рядом с кнопкой»

Конденсатор емкостью 1 мкФ на кнопке — это просто, дешево и не нужно возиться с кодами устранения дребезга. См. отличное руководство по переключателям Ника Гэммона, которое охватывает практически любую мыслимую ситуацию при использовании переключателей с Arduino и клонами (высокий или низкий уровень, GND или +5 В, внутренняя подтяжка вверх или вниз, устранение дребезга конденсатора или программное устранение дребезга и т. д.). В любом случае, у Ника Гэммона есть много замечательных пояснительных примеров на его сайте и в других местах, где он комментирует в сети.