Лазерный датчик ToF (VL53L0X) не работает

Чтобы включить устройство, необходимо подать на XSH высокий уровень (3,3 В) (либо через порт ввода-вывода, либо через подтягивающий резистор до 3,3 В).

Кроме того, устройство рассчитано на максимальное напряжение 3,3 В, вы можете повредить его, если подключите его к 5 В.

С уважением

У меня была такая же проблема с использованием этот датчик. Решение заключалось в подключении

• VCC -> 5 В
• Земля -> Земля
• SCL -> A5 (SCL)
• ПДД -> А4 (ПДД)
• DNC -x Не подключен
• GN2 -> GND
• XSH -> 5 В
• INT -x Не подключено

А затем использовать код, упомянутый здесь Тедом Мейерсом. Я использовал Nano с ATmega328P и Arduino IDE 1.8.5.

КОД:

#include <Wire.h>

#define VL53L0X_REG_IDENTIFICATION_MODEL_ID         0xc0
#define VL53L0X_REG_IDENTIFICATION_REVISION_ID      0xc2
#define VL53L0X_REG_PRE_RANGE_CONFIG_VCSEL_PERIOD   0x50
#define VL53L0X_REG_FINAL_RANGE_CONFIG_VCSEL_PERIOD 0x70
#define VL53L0X_REG_SYSRANGE_START                  0x00
#define VL53L0X_REG_RESULT_INTERRUPT_STATUS         0x13
#define VL53L0X_REG_RESULT_RANGE_STATUS             0x14
#define address 0x29

byte gbuf[16];

void setup() {
  // поместите сюда код установки для однократного запуска:
  Wire.begin();        // подключение к шине i2c (адрес необязателен для мастера)
  Serial.begin(9600);  // запускаем сериал для вывода
  Serial.println("VLX53LOX test started.");
}

void loop() {
  Serial.println("----- START TEST ----");
  test();
  Serial.println("----- END TEST ----");
  Serial.println("");
  delay(4000);
}

void test() {
  byte val1 = read_byte_data_at(VL53L0X_REG_IDENTIFICATION_REVISION_ID);
  Serial.print("Revision ID: "); Serial.println(val1);

  val1 = read_byte_data_at(VL53L0X_REG_IDENTIFICATION_MODEL_ID);
  Serial.print("Device ID: "); Serial.println(val1);

  val1 = read_byte_data_at(VL53L0X_REG_PRE_RANGE_CONFIG_VCSEL_PERIOD);
  Serial.print("PRE_RANGE_CONFIG_VCSEL_PERIOD="); Serial.println(val1); 
  Serial.print(" decode: "); Serial.println(VL53L0X_decode_vcsel_period(val1));

  val1 = read_byte_data_at(VL53L0X_REG_FINAL_RANGE_CONFIG_VCSEL_PERIOD);
  Serial.print("FINAL_RANGE_CONFIG_VCSEL_PERIOD="); Serial.println(val1);
  Serial.print(" decode: "); Serial.println(VL53L0X_decode_vcsel_period(val1));

  write_byte_data_at(VL53L0X_REG_SYSRANGE_START, 0x01);

  byte val = 0;
  int cnt = 0;
  while (cnt < 100) { // время ожидания не более 1 секунды
    delay(10);
    val = read_byte_data_at(VL53L0X_REG_RESULT_RANGE_STATUS);
    if (val & 0x01) break;
    cnt++;
  }
  if (val & 0x01) Serial.println("ready"); else Serial.println("not ready");

  read_block_data_at(0x14, 12);
  uint16_t acnt = makeuint16(gbuf[7], gbuf[6]);
  uint16_t scnt = makeuint16(gbuf[9], gbuf[8]);
  uint16_t dist = makeuint16(gbuf[11], gbuf[10]);
  byte DeviceRangeStatusInternal = ((gbuf[0] & 0x78) >> 3);

  Serial.print("ambient count: "); Serial.println(acnt);
  Serial.print("signal count: ");  Serial.println(scnt);
  Serial.print("distance ");       Serial.println(dist);
  Serial.print("status: ");        Serial.println(DeviceRangeStatusInternal);
}

uint16_t bswap(byte b[]) {
  // Big Endian unsigned Short в Little Endian unsigned Short
  uint16_t val = ((b[0] << 8) & b[1]);
  return val;
}

uint16_t makeuint16(int lsb, int msb) {
    return ((msb & 0xFF) << 8) | (lsb & 0xFF);
}

void write_byte_data(byte data) {
  Wire.beginTransmission(address);
  Wire.write(data);
  Wire.endTransmission();
}

void write_byte_data_at(byte reg, byte data) {
  // записываем слово данных по адресу и регистрируем
  Wire.beginTransmission(address);
  Wire.write(reg);
  Wire.write(data);
  Wire.endTransmission();
}

void write_word_data_at(byte reg, uint16_t data) {
  // записываем слово данных по адресу и регистрируем
  byte b0 = (data &0xFF);
  byte b1 = ((data >> 8) && 0xFF);

  Wire.beginTransmission(address);
  Wire.write(reg);
  Wire.write(b0);
  Wire.write(b1);
  Wire.endTransmission();
}

byte read_byte_data() {
  Wire.requestFrom(address, 1);
  while (Wire.available() < 1) delay(1);
  byte b = Wire.read();
  return b;
}

byte read_byte_data_at(byte reg) {
  //write_byte_data((byte)0x00);
  write_byte_data(reg);
  Wire.requestFrom(address, 1);
  while (Wire.available() < 1) delay(1);
  byte b = Wire.read();
  return b;
}

uint16_t read_word_data_at(byte reg) {
  write_byte_data(reg);
  Wire.requestFrom(address, 2);
  while (Wire.available() < 2) delay(1);
  gbuf[0] = Wire.read();
  gbuf[1] = Wire.read();
  return bswap(gbuf); 
}

void read_block_data_at(byte reg, int sz) {
  int i = 0;
  write_byte_data(reg);
  Wire.requestFrom(address, sz);
  for (i=0; i<sz; i++) {
    while (Wire.available() < 1) delay(1);
    gbuf[i] = Wire.read();
  }
}


uint16_t VL53L0X_decode_vcsel_period(short vcsel_period_reg) {
  // Преобразует закодированное значение регистра периода VCSEL в реальное
  // период в часах PLL
  uint16_t vcsel_period_pclks = (vcsel_period_reg + 1) << 1;
  return vcsel_period_pclks;
}

Еще один момент, который нужно проверить, так как у меня самого была эта ошибка, и это было просто потому, что я не припаял штыревые контакты устройства nano или TOF, которые я только что вставил в свою макетную плату. Я использую iHaospace VL53l0x от Amazon. Я подумал об этом только после того, как запустил проверку сканера i2C, которая не распознала (увидела) устройство, так что я думаю - (https ://gammon.com.au/i2c). Код Sketch сканера I2C для использования в IDE Arduino находится на две трети ниже этой страницы. Я также должен отметить, что вам нужно запустить последовательный монитор на скорости 115200 бод, не ниже, иначе вы можете получить абракадабру. Теперь все работает так же, как и со стандартным примером Arduino Adafruit, #include wire.h не требуется.

У меня была эта проблема. После подключения VL53L0X скрипт завис на старте. Сканирование устройств i2c тоже зависало. Помогла промывка мест пайки контактов. Видимо устройство очень чувствительно к загрязнениям на контактах.