Можно ли сделать несколько функций loop() с помощью Arduino Uno?

Нет, ты не можете.

Мало того, что C/C++ не имеет нескольких идентичных функций, то есть он не будет компилироваться (как предполагает комментарий jfpoilpret). Это также не соответствует идее потока программ в мире Arduino - скетчей, где у вас есть два метода на самом высоком (доступном пользователю) уровне: void setup() и void loop(). установка выполняется ровно один раз в начале вашей программы. Следующий за этим цикл зацикливается (отсюда и название) навсегда. Вам необходимо правильно реструктурировать свой код, чтобы реализовать предполагаемый поток программы, то есть вызвать свои собственные функции из цикла. Подробнее читайте на www.arduino.cc с учебниками, которые стоит изучить.

Чего вы пытаетесь достичь? Предназначены ли эти циклы для одновременного запуска (это невозможно)? Или один за другим? Вы могли бы приблизиться к "одновременному", если бы "очень быстро" было достаточно хорошо. Вам нужно будет

• Дайте каждой функции цикла новое уникальное имя;
• Разделите каждый из первых двух циклов на delay()s в общей сложности на 5 функций;
• Используйте библиотеку таймеров, такую как SimpleTimer, чтобы запускать каждую из функций с нужной вам скоростью.
• и из единственной функции loop() продолжайте вызывать функцию SimpleTimer '.run ()', чтобы все это продолжалось.

Вы можете улучшить скорость отдельных функций, заменив вызовы digitalRead() и digitalWrite() прямым чтением и записью в порт и бит, которые вы хотите прочитать или установить.

Я хочу запустить их одновременно, но в другом цикле.

Во-первых, вы можете делать только одну вещь за раз. Так что это исключено.

Во-вторых, запустить несколько циклов последовательно (по одному) довольно просто:

void loop1(void) {...}
void loop2(void) {...}
...

void loop(void) {
  loop1(); //запустить loop1
  loop2(); //запустить loop2
  ...
  loopn(); //запустить loopn
}

Будет ли это работать, будет зависеть от того, как вы закодировали эти циклы.

Чтобы использовать несколько циклов одновременно, вам нужна плата Arduino Due. Это единственная плата, совместимая с библиотекой #include <Scheduler.h>

См. Примеры > Библиотека планировщика > Несколько миганий

// Включить планировщик, так как мы хотим управлять несколькими задачами.
#include <Scheduler.h>

int led1 = 13;
int led2 = 12;
int led3 = 11;

void setup() {
  Serial.begin(9600);

  // Установите 3 контакта в качестве выхода
  pinMode(led1, OUTPUT);
  pinMode(led2, OUTPUT);
  pinMode(led3, OUTPUT);

  // Добавьте "loop2" и "loop3" в планирование.
  // "цикл" всегда запускается по умолчанию.
  Scheduler.startLoop(loop2);
  Scheduler.startLoop(loop3);
}

// Задача № 1: мигать светодиодом с задержкой в 1 секунду.
void loop() {
  digitalWrite(led1, HIGH);

  // ВАЖНО:
  // При выполнении нескольких задач "задержка" передает управление
  // другие задачи во время ожидания и гарантии их выполнения.
  delay(1000);

  digitalWrite(led1, LOW);
  delay(1000);
}

// Задача № 2: мигать светодиодом с задержкой 0,1 секунды.
void loop2() {
  digitalWrite(led2, HIGH);
  delay(100);
  digitalWrite(led2, LOW);
  delay(100);
}

// Задача № 3: принимать команды из последовательного порта
// '0' выключает светодиод
// '1' включает светодиод
void loop3() {
  if (Serial.available()) {
    char c = Serial.read();
    if (c=='0') {
      digitalWrite(led3, LOW);
      Serial.println("Led turned off!");
    }
    if (c=='1') {
      digitalWrite(led3, HIGH);
      Serial.println("Led turned on!");
    }
  }

  // ВАЖНО:
  // Мы должны регулярно вызывать "yield", чтобы пройти
  // управление другими задачами.
  yield();
}